[gentoo-commits] gentoo-x86 commit in sys-apps/groff: groff-1.20.1-r1.ebuild ChangeLog

[Matsuu Takuto (matsuu)]

matsuu      09/01/20 00:10:39

  Modified:             ChangeLog
  Added:                groff-1.20.1-r1.ebuild
  Log:
  Fixed japanese patch, bug #255292. Changed cjk USE flag to LINGUAS="ja".
  (Portage version: 2.1.6.6/cvs/Linux 2.6.28-gentoo x86_64)

Revision  Changes    Path
1.87                 sys-apps/groff/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/groff/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/groff/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/groff/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/groff/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	18 Jan 2009 16:30:15 -0000	1.86
+++ ChangeLog	20 Jan 2009 00:10:39 -0000	1.87
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/groff
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/ChangeLog,v 1.86 2009/01/18 16:30:15 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/ChangeLog,v 1.87 2009/01/20 00:10:39 matsuu Exp $
+
+*groff-1.20.1-r1 (20 Jan 2009)
+
+  20 Jan 2009; MATSUU Takuto <matsuu@g.o> +groff-1.20.1-r1.ebuild:
+  Fixed japanese patch, bug #255292. Changed cjk USE flag to LINGUAS="ja".
 
   18 Jan 2009; Markus Meier <maekke@g.o> groff-1.19.2-r3.ebuild:
   amd64/x86 stable, bug #255280



1.1                  sys-apps/groff/groff-1.20.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/groff/groff-1.20.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/groff/groff-1.20.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: groff-1.20.1-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/groff-1.20.1-r1.ebuild,v 1.1 2009/01/20 00:10:39 matsuu Exp $

inherit eutils toolchain-funcs autotools

DESCRIPTION="Text formatter used for man pages"
HOMEPAGE="http://www.gnu.org/software/groff/groff.html"
SRC_URI="mirror://gnu/groff/${P}.tar.gz
	linguas_ja? ( mirror://gentoo/${P}-japanese.patch.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="X linguas_ja"

DEPEND=">=sys-apps/texinfo-4.7-r1
	X? (
		x11-libs/libX11
		x11-libs/libXt
		x11-libs/libXmu
		x11-libs/libXaw
		x11-libs/libSM
		x11-libs/libICE
	)"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${PN}-1.19.2-man-unicode-dashes.patch #16108 #17580 #121502

	# Make sure we can cross-compile this puppy
	if tc-is-cross-compiler ; then
		sed -i \
			-e '/^GROFFBIN=/s:=.*:=/usr/bin/groff:' \
			-e '/^TROFFBIN=/s:=.*:=/usr/bin/troff:' \
			-e '/^GROFF_BIN_PATH=/s:=.*:=:' \
			contrib/mom/Makefile.sub \
			doc/Makefile.in \
			doc/Makefile.sub || die "cross-compile sed failed"
	fi

	if use linguas_ja ; then
		epatch "${WORKDIR}"/${P}-japanese.patch #255292
		eautoconf
	fi
}

src_compile() {
	# Fix problems with not finding g++
#	tc-export CC CXX
	local myconf="--with-appresdir=/usr/share/X11/app-defaults"

	use linguas_ja && myconf="${myconf} --enable-japanese"

	econf \
		$(use_with X x) \
		${myconf} || die
	emake || die
}

src_install() {
	emake install DESTDIR="${D}" || die

	# The following links are required for man #123674
	dosym eqn /usr/bin/geqn
	dosym tbl /usr/bin/gtbl

	dodoc BUG-REPORT ChangeLog MORE.STUFF NEWS \
		PROBLEMS PROJECTS README REVISION TODO VERSION
}