[gentoo-commits] proj/kde:master commit in: kde-apps/lokalize/

[Andreas Sturmlechner]

commit:     7e3aba091c1a89ea7a97eb6e0e26200f8f074a07
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  1 09:03:19 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Mar  1 09:03:19 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=7e3aba09

kde-apps/lokalize: 21.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/lokalize/lokalize-21.12.3.ebuild | 69 +++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/kde-apps/lokalize/lokalize-21.12.3.ebuild b/kde-apps/lokalize/lokalize-21.12.3.ebuild
new file mode 100644
index 0000000000..c1a8d22cc4
--- /dev/null
+++ b/kde-apps/lokalize/lokalize-21.12.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit python-single-r1 ecm kde.org optfeature
+
+DESCRIPTION="Localization tool for KDE software and other free and open source software"
+HOMEPAGE="https://apps.kde.org/lokalize/ https://l10n.kde.org/tools/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test" # tests are broken, bug 739734
+
+DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.2.8:=
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/translate-toolkit[${PYTHON_USEDEP}]
+	')
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_install() {
+	ecm_src_install
+	rm "${ED}"/usr/share/lokalize/scripts/msgmerge.{py,rc} || die
+	python_fix_shebang "${ED}"/usr/share/${PN}
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "autofetch kde.org translations in new project wizard" dev-vcs/subversion
+		optfeature "spell and grammar checking" app-text/languagetool
+	fi
+	ecm_pkg_postinst
+}