[gentoo-commits] gentoo-x86 commit in app-crypt/mit-krb5: mit-krb5-1.11-r1.ebuild ChangeLog

[Eray Aslan (eras)]

eras        12/12/28 07:29:59

  Modified:             ChangeLog
  Added:                mit-krb5-1.11-r1.ebuild
  Log:
  Do not output LDFLAGS in krb5-config --libs output - bug #448778
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 0x77F1F175586A3B1F)

Revision  Changes    Path
1.348                app-crypt/mit-krb5/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/ChangeLog?rev=1.348&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/ChangeLog?rev=1.348&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/ChangeLog?r1=1.347&r2=1.348

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v
retrieving revision 1.347
retrieving revision 1.348
diff -u -r1.347 -r1.348
--- ChangeLog	24 Dec 2012 17:43:24 -0000	1.347
+++ ChangeLog	28 Dec 2012 07:29:59 -0000	1.348
@@ -1,6 +1,12 @@
 # ChangeLog for app-crypt/mit-krb5
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v 1.347 2012/12/24 17:43:24 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v 1.348 2012/12/28 07:29:59 eras Exp $
+
+*mit-krb5-1.11-r1 (28 Dec 2012)
+
+  28 Dec 2012; Eray Aslan <eras@g.o>
+  +files/mit-krb5_krb5-config_LDFLAGS.patch, +mit-krb5-1.11-r1.ebuild:
+  Do not output LDFLAGS in krb5-config --libs output - bug #448778
 
   24 Dec 2012; Eray Aslan <eras@g.o> -files/2011-006-patch-r18.patch,
   -files/CVE-2010-1322.patch, -files/CVE-2010-1323.1324.4020.patch,



1.1                  app-crypt/mit-krb5/mit-krb5-1.11-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.11-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.11-r1.ebuild?rev=1.1&content-type=text/plain

Index: mit-krb5-1.11-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.11-r1.ebuild,v 1.1 2012/12/28 07:29:59 eras Exp $

EAPI="4"
inherit eutils flag-o-matic versionator

MY_P="${P/mit-}"
P_DIR=$(get_version_component_range 1-2)
DESCRIPTION="MIT Kerberos V"
HOMEPAGE="http://web.mit.edu/kerberos/www/"
SRC_URI="http://web.mit.edu/kerberos/dist/krb5/${P_DIR}/${MY_P}-signed.tar"

LICENSE="openafs-krb5-a BSD MIT OPENLDAP BSD-2 HPND BSD-4 ISC RSA CCPL-Attribution-ShareAlike-3.0 || ( BSD-2 GPL-2+ )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~x86"
IUSE="doc +keyutils openldap +pkinit +threads test xinetd"

RDEPEND="!!app-crypt/heimdal
	>=sys-libs/e2fsprogs-libs-1.41.0
	dev-libs/libverto
	keyutils? ( sys-apps/keyutils )
	openldap? ( net-nds/openldap )
	pkinit? ( dev-libs/openssl )
	xinetd? ( sys-apps/xinetd )"
DEPEND="${RDEPEND}
	virtual/yacc
	doc? ( virtual/latex-base )
	test? ( dev-lang/tcl
			dev-lang/python
			dev-util/dejagnu )"

S=${WORKDIR}/${MY_P}/src

src_unpack() {
	unpack ${A}
	unpack ./"${MY_P}".tar.gz
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.11_uninitialized.patch"
	epatch "${FILESDIR}/${PN}_krb5-config_LDFLAGS.patch"
}

src_configure() {
	append-cppflags "-I${EPREFIX}/usr/include/et"
	# QA
	append-flags -fno-strict-aliasing
	append-flags -fno-strict-overflow

	use keyutils || export ac_cv_header_keyutils_h=no
	econf \
		$(use_with openldap ldap) \
		"$(use_with test tcl "${EPREFIX}/usr")" \
		$(use_enable pkinit) \
		$(use_enable threads thread-support) \
		--without-hesiod \
		--enable-shared \
		--with-system-et \
		--with-system-ss \
		--enable-dns-for-realm \
		--enable-kdc-lookaside-cache \
		--with-system-verto \
		--disable-rpath
}

src_compile() {
	emake -j1
}

src_install() {
	emake \
		DESTDIR="${D}" \
		EXAMPLEDIR="${EPREFIX}/usr/share/doc/${PF}/examples" \
		install

	# default database dir
	keepdir /var/lib/krb5kdc

	cd ..
	dodoc README

	if use doc; then
		dohtml -r doc/html/*
		docinto pdf
		dodoc doc/pdf/*.pdf
	fi

	newinitd "${FILESDIR}"/mit-krb5kadmind.initd-r1 mit-krb5kadmind
	newinitd "${FILESDIR}"/mit-krb5kdc.initd-r1 mit-krb5kdc
	newinitd "${FILESDIR}"/mit-krb5kpropd.initd-r1 mit-krb5kpropd

	insinto /etc
	newins "${ED}/usr/share/doc/${PF}/examples/krb5.conf" krb5.conf.example
	insinto /var/lib/krb5kdc
	newins "${ED}/usr/share/doc/${PF}/examples/kdc.conf" kdc.conf.example

	if use openldap ; then
		insinto /etc/openldap/schema
		doins "${S}/plugins/kdb/ldap/libkdb_ldap/kerberos.schema"
	fi

	if use xinetd ; then
		insinto /etc/xinetd.d
		newins "${FILESDIR}/kpropd.xinetd" kpropd
	fi
}

pkg_preinst() {
	if has_version "<${CATEGORY}/${PN}-1.8.0" ; then
		elog "MIT split the Kerberos applications from the base Kerberos"
		elog "distribution.  Kerberized versions of telnet, rlogin, rsh, rcp,"
		elog "ftp clients and telnet, ftp deamons now live in"
		elog "\"app-crypt/mit-krb5-appl\" package."
	fi
}