[gentoo-commits] gentoo-x86 commit in net-p2p/tribler: tribler-5.5.19.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    12/03/01 13:27:34

  Modified:             ChangeLog
  Added:                tribler-5.5.19.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  net-p2p/tribler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/tribler/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	28 Feb 2012 16:46:59 -0000	1.7
+++ ChangeLog	1 Mar 2012 13:27:34 -0000	1.8
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/tribler
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/tribler/ChangeLog,v 1.7 2012/02/28 16:46:59 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/tribler/ChangeLog,v 1.8 2012/03/01 13:27:34 blueness Exp $
+
+*tribler-5.5.19 (01 Mar 2012)
+
+  01 Mar 2012; Anthony G. Basile <blueness@g.o> +tribler-5.5.19.ebuild:
+  Version bump
 
   28 Feb 2012; Anthony G. Basile <blueness@g.o> -tribler-5.5.10.ebuild:
   Remove older ebuild



1.1                  net-p2p/tribler/tribler-5.5.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/tribler-5.5.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/tribler/tribler-5.5.19.ebuild?rev=1.1&content-type=text/plain

Index: tribler-5.5.19.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/tribler/tribler-5.5.19.ebuild,v 1.1 2012/03/01 13:27:34 blueness Exp $

EAPI="4"
PYTHON_DEPEND="2:2.5"

inherit eutils python

MY_PV="${PN}_${PV}-1ubuntu1_all"

DESCRIPTION="Bittorrent client that does not require a website to discover content"
HOMEPAGE="http://www.tribler.org/"
SRC_URI="http://dl.tribler.org/${MY_PV}.deb"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="vlc"

RDEPEND=">=dev-lang/python-2.5[sqlite]
	>=dev-python/m2crypto-0.16
	>=dev-python/wxpython-2.8
	>=dev-python/apsw-3.6
	>=dev-libs/openssl-0.9.8
	vlc? ( >=media-video/vlc-1.0.1 )"

# Skipping for now:
# xulrunner-sdk >= 1.9.1.5 < 1.9.2 (optional, to run SwarmTransport)
# 7-Zip >= 4.6.5 (optional, to build SwarmTransport)

DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_unpack() {
	unpack ${A}
	unpack ./data.tar.gz
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-fix-global-declarations.patch"
	epatch "${FILESDIR}/${PN}-log2homedir.patch"

	python_convert_shebangs -r 2 .
}

src_compile() { :; }

src_install() {
	#Rename the doc dir properly
	mv usr/share/doc/${PN} usr/share/doc/${P}

	#Move the readme to the doc dir
	mv usr/share/${PN}/Tribler/readme.txt usr/share/doc/${P}

	#Remove the licenses scattered throughout
	rm usr/share/doc/${P}/copyright
	rm usr/share/${PN}/Tribler/*.txt
	rm usr/share/${PN}/Tribler/Core/DecentralizedTracking/pymdht/{LGPL-2.1.txt,LICENSE.txt}

	#Copy the rest over
	cp -pPR usr/ "${ED}"/
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"usr/share/${PN}
}

pkg_postrm() {
	python_mod_cleanup "${ROOT}"usr/share/${PN}
}