[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

[Sam James]

commit:     d3aed95067fe7ae0fbe0eac317042a2a76557b6c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  9 06:28:03 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Oct  9 06:28:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d3aed950

dev-util/diffoscope: add 187

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-187.ebuild | 109 ++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 24b8ca3914c..38ba3e48d24 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -3,3 +3,4 @@ DIST diffoscope-180.tar.gz 1600542 BLAKE2B 0cc34106f039e0682b32de284b3ce1be90e86
 DIST diffoscope-184.tar.gz 2684969 BLAKE2B 8b7fd3e4e85f372f2c45cd1f9ed82d5c6c2771044535063398e23b94a069c73d4fbc89fe0fa7393ea188a107cd4912d189a3566cc0701b1f3253761480b40080 SHA512 ae4f1e929ada57706b8ed28b03be264fb65e6b1692da9e212bf60ac40a56fb5f488bb5dd162d3436e832ba245edd0a7383f794ce38541cb4295d10f2cc1de50e
 DIST diffoscope-185.tar.gz 2684950 BLAKE2B 53ae0ec8b3402811639de7a6ed3dd6b436c6a4d75ce2c415c66b28fd32ceb136766ee42711bca47578e5303be354c514e6f9d82843f11b266a05b77f1196fb13 SHA512 ce66cdb64c23434671e40f4c51ac6c9f1da524e92618792d2cd8e2e7fb044340e03c9438b3450cc2a66e2dc327a25850a421b32c0aad493781291645e65eb775
 DIST diffoscope-186.tar.gz 2685030 BLAKE2B b9fcb05fbdd939ece3727f232777c56119aa5df837699dcdc752a816bb656aa09c4cce99e225425e09d55914523a6456587bf232877fa22924c623f854016712 SHA512 13d42ba600cc9c5e716162a73f42d8453358f689f4148b138121e1f2190b1334a66a01fd0e227bc9e7190d3229c286be91d6ccbdd21c13694fc2edab8e5019cd
+DIST diffoscope-187.tar.gz 2699208 BLAKE2B 193eb0575814df7ee1d0a0e989a936782a52d4c8dc3e56d47db7ff5d631776559a604755e1d1be6687c1168ef7bb9d899f3b5ea8cab9506ef5b2da195485d7e0 SHA512 b3ba6743c9c4e0460f56a0830801f72e00bf7500c54dd9392e6e1de470a3b7348d900a8b9012f17b509abbc59575c7b9ee8e1048b3b23e5813a5ddabeadb1be4

diff --git a/dev-util/diffoscope/diffoscope-187.ebuild b/dev-util/diffoscope/diffoscope-187.ebuild
new file mode 100644
index 00000000000..de3d809fe6a
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-187.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local exclude=(
+		# test seems to use different tarball
+		tests/test_presenters.py::test_text_proper_indentation
+
+		# needs triage
+		tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+
+		# needs triage
+		tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+		# img2txt based failures, bug #797688
+		tests/comparators/test_ico_image.py::test_diff
+		tests/comparators/test_ico_image.py::test_diff_meta
+		tests/comparators/test_ico_image.py::test_diff_meta2
+		tests/comparators/test_ico_image.py::test_has_visuals
+		tests/comparators/test_jpeg_image.py::test_diff
+		tests/comparators/test_jpeg_image.py::test_compare_non_existing
+		tests/comparators/test_jpeg_image.py::test_diff_meta
+		tests/comparators/test_jpeg_image.py::test_has_visuals
+
+		# docx2txt based falures, bug #797688
+		tests/comparators/test_docx.py::test_diff
+	)
+	epytest ${exclude[@]/#/--deselect }
+}