[gentoo-commits] gentoo-x86 commit in dev-python/mwlib-rl: mwlib-rl-0.14.4.ebuild ChangeLog

[Tiziano Mueller (dev-zero)]

dev-zero    13/11/27 21:37:16

  Modified:             ChangeLog
  Added:                mwlib-rl-0.14.4.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key 0x1E0CA85F!)

Revision  Changes    Path
1.3                  dev-python/mwlib-rl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib-rl/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib-rl/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib-rl/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	1 Jul 2013 11:42:39 -0000	1.2
+++ ChangeLog	27 Nov 2013 21:37:16 -0000	1.3
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/mwlib-rl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/ChangeLog,v 1.2 2013/07/01 11:42:39 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/ChangeLog,v 1.3 2013/11/27 21:37:16 dev-zero Exp $
+
+*mwlib-rl-0.14.4 (27 Nov 2013)
+
+  27 Nov 2013; Tiziano Müller <dev-zero@g.o> +mwlib-rl-0.14.4.ebuild:
+  Version bump.
 
   01 Jul 2013; Tiziano Müller <dev-zero@g.o> mwlib-rl-0.14.3.ebuild:
   Only tested with pillow, remove imaging.



1.1                  dev-python/mwlib-rl/mwlib-rl-0.14.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib-rl/mwlib-rl-0.14.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/mwlib-rl/mwlib-rl-0.14.4.ebuild?rev=1.1&content-type=text/plain

Index: mwlib-rl-0.14.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/mwlib-rl-0.14.4.ebuild,v 1.1 2013/11/27 21:37:16 dev-zero Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="xml"

inherit distutils-r1

MY_PN="${PN/-/.}"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Generate pdfs from mediawiki markup"
HOMEPAGE="http://code.pediapress.com/wiki/wiki http://pypi.python.org/pypi/mwlib.rl"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test pdftk"

RDEPEND=">=dev-python/mwlib-0.15.8-r1[${PYTHON_USEDEP}]
	>=dev-python/mwlib-ext-0.12.4-r1[${PYTHON_USEDEP}]
	>=dev-python/pygments-1.4[${PYTHON_USEDEP}]
	dev-python/simplejson[${PYTHON_USEDEP}]
	dev-python/pillow[${PYTHON_USEDEP}]
	media-fonts/freefont
	|| ( media-gfx/graphicsmagick[imagemagick] media-gfx/imagemagick )
	pdftk? ( app-text/pdftk )"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	app-arch/unzip
	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"

S="${WORKDIR}/${MY_P}"

PATCHES=( "${FILESDIR}/0.14.3-use-system-fonts.patch" )
DOCS=( example-mwlib.config README.rst )

python_prepare_all() {
	rm -r mwlib/fonts/freefont || die "removing bundled fonts failed"
	distutils-r1_python_prepare_all
}

python_test() {
	py.test || die
}

pkg_postinst() {
	elog "If you need extended/non-lating rendering support, please install the"
	elog "corresponding font packages:"
	elog " - media-fonts/libertine-ttf"
	elog " - media-fonts/sil-ezra"
	elog " - media-fonts/farsi-fonts"
	elog " - media-fonts/arphicfonts"
	elog " - media-fonts/unfonts"
	# TODO: need the following packages as well:
	# ttf-indic-fonts ttf-gfs-artemisia  ttf-thai-arundina
}