[gentoo-commits] gentoo-x86 commit in net-proxy/dansguardian: dansguardian-2.12.0.3-r1.ebuild ChangeLog

[Tom Wijsman (tomwij)]

tomwij      13/04/01 10:28:30

  Modified:             ChangeLog
  Added:                dansguardian-2.12.0.3-r1.ebuild
  Log:
  Revision bump. Package was forcing debug on everyone, resolved by only passing debug parameter to econf when USE="debug". Reported by Tomas Mozen. Fixes bug #463978.
  
  (Portage version: 2.1.11.59/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.55                 net-proxy/dansguardian/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/dansguardian/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/dansguardian/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/dansguardian/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	4 Mar 2013 12:13:11 -0000	1.54
+++ ChangeLog	1 Apr 2013 10:28:30 -0000	1.55
@@ -1,6 +1,13 @@
 # ChangeLog for net-proxy/dansguardian
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/ChangeLog,v 1.54 2013/03/04 12:13:11 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/ChangeLog,v 1.55 2013/04/01 10:28:30 tomwij Exp $
+
+*dansguardian-2.12.0.3-r1 (01 Apr 2013)
+
+  01 Apr 2013; Tom Wijsman <TomWij@g.o> +dansguardian-2.12.0.3-r1.ebuild:
+  Revision bump. Package was forcing debug on everyone, resolved by only passing
+  debug parameter to econf when USE="debug". Reported by Tomas Mozen. Fixes bug
+  #463978.
 
 *dansguardian-2.12.0.3 (04 Mar 2013)
 



1.1                  net-proxy/dansguardian/dansguardian-2.12.0.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/dansguardian/dansguardian-2.12.0.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/dansguardian/dansguardian-2.12.0.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: dansguardian-2.12.0.3-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/dansguardian-2.12.0.3-r1.ebuild,v 1.1 2013/04/01 10:28:30 tomwij Exp $

EAPI="5"

inherit eutils

DESCRIPTION="Web content filtering via proxy"
HOMEPAGE="http://www.${PN}.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="avast backtrace clamav commandline debug email +fancydm icap kaspersky +lfs logrotate ntlm orig-ip +pcre static-libs trickledm"

RDEPEND="sys-libs/zlib
	clamav? ( app-antivirus/clamav )
	logrotate? ( app-admin/logrotate )
	ntlm? ( virtual/libiconv )
	pcre? ( dev-libs/libpcre )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

WIKI="http://contentfilter.futuragts.com/wiki/doku.php"

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /dev/null ${PN}
}

src_configure() {
	local debug
	if use debug ; then
		debug="$(use_with debug dgdebug)"
	fi

	econf \
		$(use_enable avast avastd) \
		$(use_enable backtrace segv-backtrace) \
		$(use_enable clamav clamd) \
		$(use_enable commandline) \
		${debug} \
		$(use_enable email) \
		$(use_enable fancydm) \
		$(use_enable icap) \
		$(use_enable kaspersky kavd) \
		$(use_enable lfs) \
		--with-logdir=/var/log/${PN} \
		$(use_enable ntlm) \
		$(use_enable orig-ip) \
		$(use_enable pcre) \
		--with-piddir=/var/run \
		--with-proxygroup=${PN} \
		--with-proxyuser=${PN} \
		$(use_enable static-libs static-zlib) \
		$(use_enable trickledm)
}

src_install() {
	default

	# Edit config files for virus scanners chosen based on USE flags.
	if use avast; then
		sed -r -i -e 's/^#( *contentscanner *=.*avastdscan[.]conf.*)/\1/' "${D}/etc/${PN}/${PN}.conf"
	fi

	if use clamav; then
		sed -r -i -e 's/[ \t]+use dns/& clamd/' "${D}/etc/init.d/${PN}"
		sed -r -i -e 's/^#( *contentscanner *=.*clamdscan[.]conf.*)/\1/' "${D}/etc/${PN}/${PN}.conf"
	fi

	if use commandline; then
		sed -r -i -e 's/^#( *contentscanner *=.*commandlinescan[.]conf.*)/\1/' "${D}/etc/${PN}/${PN}.conf"
	fi

	if use icap; then
		sed -r -i -e 's/^#( *contentscanner *=.*icapscan[.]conf.*)/\1/' "${D}/etc/${PN}/${PN}.conf"
	fi

	if use kaspersky; then
		sed -r -i -e 's/^#( *contentscanner *=.*kavdscan[.]conf.*)/\1/' "${D}/etc/${PN}/${PN}.conf"
	fi

	# Install Gentoo init script
	newinitd "${FILESDIR}/${PN}.init" ${PN}

	# Install log rotation file.
	if use logrotate; then
		insinto /etc/logrotate.d
		newins "${FILESDIR}/${PN}.logrotate" ${PN}
	else
		exeinto /etc/cron.weekly
		newexe data/scripts/logrotation ${PN}.cron
	fi

	keepdir /var/log/${PN}
	fperms o-rwx /var/log/${PN}
}

pkg_postinst() {
	local runas="${PN}:${PN}"

	if [ -d "${ROOT}/var/log/${PN}" ] ; then
		chown -R ${runas} "${ROOT}/var/log/${PN}"
		chmod o-rwx "${ROOT}/var/log/${PN}"
	fi

	einfo "For assistance configuring ${PN}, visit the wiki at ${WIKI}"
}