[gentoo-commits] gentoo-x86 commit in net-libs/nodejs: nodejs-0.10.15.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     13/08/01 04:21:25

  Modified:             ChangeLog
  Added:                nodejs-0.10.15.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.0_alpha191/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.95                 net-libs/nodejs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	19 Jul 2013 06:52:01 -0000	1.94
+++ ChangeLog	1 Aug 2013 04:21:25 -0000	1.95
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/nodejs
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v 1.94 2013/07/19 06:52:01 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v 1.95 2013/08/01 04:21:25 patrick Exp $
+
+*nodejs-0.10.15 (01 Aug 2013)
+
+  01 Aug 2013; Patrick Lauer <patrick@g.o> +nodejs-0.10.15.ebuild:
+  Bump
 
 *nodejs-0.11.4 (19 Jul 2013)
 *nodejs-0.10.13 (19 Jul 2013)



1.1                  net-libs/nodejs/nodejs-0.10.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.10.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.10.15.ebuild?rev=1.1&content-type=text/plain

Index: nodejs-0.10.15.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/nodejs-0.10.15.ebuild,v 1.1 2013/08/01 04:21:25 patrick Exp $

EAPI=5

# has known failures. sigh.
RESTRICT="test"

PYTHON_COMPAT=( python2_{5,6,7} )

inherit python-any-r1 pax-utils

DESCRIPTION="Evented IO for V8 Javascript"
HOMEPAGE="http://nodejs.org/"
SRC_URI="http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz"

LICENSE="Apache-1.1 Apache-2.0 BSD BSD-2 MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
IUSE="+npm"

RDEPEND="dev-libs/openssl"
DEPEND="${RDEPEND}
	virtual/python-json"

S=${WORKDIR}/node-v${PV}

src_prepare() {
	# fix compilation on Darwin
	# http://code.google.com/p/gyp/issues/detail?id=260
	sed -i -e "/append('-arch/d" tools/gyp/pylib/gyp/xcode_emulation.py || die

	# make sure we use python2.* while using gyp
	sed -i -e  "s/python/python2/" deps/npm/node_modules/node-gyp/gyp/gyp || die

	# less verbose install output (stating the same as portage, basically)
	sed -i -e "/print/d" tools/install.py || die
}

src_configure() {
	local myconf=""
	! use npm && myconf="--without-npm"

	"${PYTHON}" configure --prefix="${EPREFIX}"/usr \
		--openssl-use-sys --shared-zlib --without-dtrace ${myconf} || die
}

src_compile() {
	emake out/Makefile
	emake -C out mksnapshot
	pax-mark m out/Release/mksnapshot
	emake
}

src_install() {
	"${PYTHON}" tools/install.py install "${D}"

	use npm && dohtml -r "${ED}"/usr/lib/node_modules/npm/html/*
	rm -rf "${ED}"/usr/lib/node_modules/npm/doc "${ED}"/usr/lib/node_modules/npm/html
	rm -rf "${ED}"/usr/lib/dtrace

	pax-mark -m "${ED}"/usr/bin/node
}

src_test() {
	"${PYTHON}" tools/test.py --mode=release simple message || die
}