[gentoo-commits] gentoo-x86 commit in app-arch/zpaq-extras: ChangeLog zpaq-extras-0_p20110106.ebuild zpaq-extras-0_p20100426.ebuild

[Michal Gorny (mgorny)]

mgorny      11/01/06 16:10:22

  Modified:             ChangeLog
  Added:                zpaq-extras-0_p20110106.ebuild
  Removed:              zpaq-extras-0_p20100426.ebuild
  Log:
  Bump to install standard ZPAQ configurations as well as they are not installed stand-alone anymore in >=app-arch/zpaq-2.03 (and the built-in variants don't accept arguments).
  
  (Portage version: 2.2.0_alpha12_p8/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  app-arch/zpaq-extras/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq-extras/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq-extras/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq-extras/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	5 Jan 2011 23:30:36 -0000	1.2
+++ ChangeLog	6 Jan 2011 16:10:21 -0000	1.3
@@ -1,6 +1,14 @@
 # ChangeLog for app-arch/zpaq-extras
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/ChangeLog,v 1.2 2011/01/05 23:30:36 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/ChangeLog,v 1.3 2011/01/06 16:10:21 mgorny Exp $
+
+*zpaq-extras-0_p20110106 (06 Jan 2011)
+
+  06 Jan 2011; Michał Górny <mgorny@g.o>
+  -zpaq-extras-0_p20100426.ebuild, +zpaq-extras-0_p20110106.ebuild:
+  Bump to install standard ZPAQ configurations as well as they are not
+  installed stand-alone anymore in >=app-arch/zpaq-2.03 (and the built-in
+  variants don't accept arguments).
 
   05 Jan 2011; Michał Górny <mgorny@g.o>
   zpaq-extras-0_p20100426.ebuild:



1.1                  app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild?rev=1.1&content-type=text/plain

Index: zpaq-extras-0_p20110106.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/zpaq-extras/zpaq-extras-0_p20110106.ebuild,v 1.1 2011/01/06 16:10:21 mgorny Exp $

EAPI=3
inherit base toolchain-funcs

DESCRIPTION="A set of additional compression profiles for app-arch/zpaq"
HOMEPAGE="http://mattmahoney.net/dc/zpaq.html"
SRC_URI="http://mattmahoney.net/dc/bwt_j3.zip
	http://mattmahoney.net/dc/bwt_slowmode1.zip
	http://mattmahoney.net/dc/bmp_j4.zip
	http://mattmahoney.net/dc/exe_j1.zip
	http://mattmahoney.net/dc/jpg_test2.zip
	http://mattmahoney.net/dc/min.zip
	http://mattmahoney.net/dc/fast.cfg -> zpaq-fast.cfg
	http://mattmahoney.net/dc/mid.cfg -> zpaq-mid.cfg
	http://mattmahoney.net/dc/max.cfg -> zpaq-max.cfg"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

DEPEND="app-arch/unzip"
RDEPEND="!<app-arch/zpaq-2.03"

S=${WORKDIR}

src_unpack() {
	local x
	for x in ${A}; do
		if [[ ${x} == *.cfg ]]; then
			cp "${DISTDIR}"/${x} ${x#zpaq-} || die
		fi
	done

	default
}

src_configure() {
	sed \
		-e "s:^pcomp zpaq r:pcomp ${EPREFIX}/usr/bin/zpaq r${EPREFIX}/usr/share/zpaq/:" \
		-e "s:^pcomp \([^/]\):pcomp ${EPREFIX}/usr/libexec/zpaq/\1:" \
		-i *.cfg || die

	local sources=( *.cpp )
	# (the following assignment flattens the array)
	progs=${sources[@]%.cpp}
}

src_compile() {
	tc-export CXX
	emake ${progs} || die
}

src_install() {
	exeinto /usr/libexec/zpaq
	doexe ${progs} || die

	insinto /usr/share/zpaq
	doins *.cfg || die
}