[gentoo-commits] gentoo-x86 commit in mail-mta/ssmtp: ChangeLog ssmtp-2.62-r4.ebuild

[Tobias Scherbaum (dertobi123)]

dertobi123    08/11/29 20:27:51

  Modified:             ChangeLog
  Added:                ssmtp-2.62-r4.ebuild
  Log:
  Revision bump, comment rewriteDomain (#243364), re-add mailbase dep (#249269), fix AuthPass with '=' or ':' in it (#238724), setgid on ssmtp binary (#239197)
  (Portage version: 2.2_rc16/cvs/Linux 2.6.25-gentoo-r7 x86_64)

Revision  Changes    Path
1.67                 mail-mta/ssmtp/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-mta/ssmtp/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-mta/ssmtp/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-mta/ssmtp/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	21 Sep 2008 08:43:56 -0000	1.66
+++ ChangeLog	29 Nov 2008 20:27:51 -0000	1.67
@@ -1,6 +1,14 @@
 # ChangeLog for mail-mta/ssmtp
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ChangeLog,v 1.66 2008/09/21 08:43:56 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ChangeLog,v 1.67 2008/11/29 20:27:51 dertobi123 Exp $
+
+*ssmtp-2.62-r4 (29 Nov 2008)
+
+  29 Nov 2008; Tobias Scherbaum <dertobi123@g.o>
+  +files/ssmtp-2.62-authpass.patch, +ssmtp-2.62-r4.ebuild:
+  Revision bump, comment rewriteDomain (#243364), re-add mailbase dep
+  (#249269), fix AuthPass with '=' or ':' in it (#238724), setgid on ssmtp
+  binary (#239197)
 
   21 Sep 2008; Tobias Scherbaum <dertobi123@g.o>
   ssmtp-2.62-r3.ebuild:



1.1                  mail-mta/ssmtp/ssmtp-2.62-r4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-mta/ssmtp/ssmtp-2.62-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-mta/ssmtp/ssmtp-2.62-r4.ebuild?rev=1.1&content-type=text/plain

Index: ssmtp-2.62-r4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ssmtp-2.62-r4.ebuild,v 1.1 2008/11/29 20:27:51 dertobi123 Exp $

inherit eutils toolchain-funcs autotools

DESCRIPTION="Extremely simple MTA to get mail off the system to a Mailhub"
HOMEPAGE="ftp://ftp.debian.org/debian/pool/main/s/ssmtp/"
SRC_URI="mirror://debian/pool/main/s/ssmtp/${P/-/_}.orig.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="ssl ipv6 md5sum maxsysuid"

DEPEND="ssl? ( dev-libs/openssl )"
RDEPEND="${DEPEND}
	net-mail/mailbase
	!net-mail/mailwrapper
	!virtual/mta"
PROVIDE="virtual/mta"

S="${WORKDIR}/${PN}"

pkg_setup() {
	enewgroup ssmtp
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Allow to specify the last used system user id, bug #231866
	if use maxsysuid; then
		epatch "${FILESDIR}"/${P}-maxsysuid.patch
		epatch "${FILESDIR}"/${P}-maxsysuid-conf.patch
	fi

	# CVE-2008-3962
	epatch "${FILESDIR}/CVE-2008-3962.patch"

	# Fix AuthPass parsing (bug #238724)
	epatch "${FILESDIR}/${P}-authpass.patch"

	epatch "${FILESDIR}/${P}-strndup.patch"
	eautoreconf

	# Respect LDFLAGS (bug #152197)
	sed -i -e 's:$(CC) -o:$(CC) @LDFLAGS@ -o:' Makefile.in
}

src_compile() {
	tc-export CC LD

	econf \
		--sysconfdir=/etc/ssmtp \
		$(use_enable ssl) \
		$(use_enable ipv6 inet6) \
		$(use_enable md5sum md5auth) \
		|| die
	make clean || die
	make etcdir=/etc || die
}

src_install() {
	dodir /usr/bin /usr/sbin /usr/lib
	dosbin ssmtp || die
	fperms 755 /usr/sbin/ssmtp

	doman ssmtp.8
	dodoc INSTALL README TLS CHANGELOG_OLD
	newdoc ssmtp.lsm DESC

	insinto /etc/ssmtp
	doins ssmtp.conf revaliases

	local conffile="${D}etc/ssmtp/ssmtp.conf"

	# Sorry about the weird indentation, I couldn't figure out a cleverer way
	# to do this without having horribly >80 char lines.
	sed -i -e "s:^hostname=:\n# Gentoo bug #47562\\
# Commenting the following line will force ssmtp to figure\\
# out the hostname itself.\n\\
# hostname=:" \
		"${conffile}" || die "sed failed"

	# Comment rewriteDomain (bug #243364)
	sed -i -e "s:^rewriteDomain=:#rewriteDomain=:" ${conffile}

	# Set restrictive perms on ssmtp.conf as per #187841, #239197
	# Protect the ssmtp configfile from being readable by regular users as it
	# may contain login/password data to auth against a the mailhub used.
	fowners root:ssmtp /etc/ssmtp/ssmtp.conf
	fperms 640 /etc/ssmtp/ssmtp.conf

	fowners root:ssmtp /usr/sbin/ssmtp
	fperms 2711 /usr/sbin/ssmtp

	dosym /usr/sbin/ssmtp /usr/lib/sendmail
	dosym /usr/sbin/ssmtp /usr/bin/sendmail
	dosym /usr/sbin/ssmtp /usr/sbin/sendmail
	dosym /usr/sbin/ssmtp /usr/bin/mailq
	dosym /usr/sbin/ssmtp /usr/bin/newaliases
}