[gentoo-commits] gentoo-x86 commit in sys-devel/prelink: ChangeLog prelink-20111012.ebuild prelink-20101123.ebuild

[Ryan Hill (dirtyepic)]

dirtyepic    11/11/24 04:49:28

  Modified:             ChangeLog
  Added:                prelink-20111012.ebuild
  Removed:              prelink-20101123.ebuild
  Log:
  Version bump (bug #390125 by Matt Summers), fix testsuite breakage from
  binutils-2.22 enabling --copy-dt-needed-entries by default.  Remove old.
  
  (Portage version: 2.2.0_alpha77/cvs/Linux x86_64)

Revision  Changes    Path
1.81                 sys-devel/prelink/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/prelink/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/prelink/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/prelink/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/prelink/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- ChangeLog	15 Jun 2011 03:54:24 -0000	1.80
+++ ChangeLog	24 Nov 2011 04:49:28 -0000	1.81
@@ -1,6 +1,13 @@
 # ChangeLog for sys-devel/prelink
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/prelink/ChangeLog,v 1.80 2011/06/15 03:54:24 dirtyepic Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/prelink/ChangeLog,v 1.81 2011/11/24 04:49:28 dirtyepic Exp $
+
+*prelink-20111012 (24 Nov 2011)
+
+  24 Nov 2011; Ryan Hill <dirtyepic@g.o> -prelink-20101123.ebuild,
+  +prelink-20111012.ebuild:
+  Version bump (bug #390125 by Matt Summers), fix testsuite breakage from
+  binutils-2.22 enabling --copy-dt-needed-entries by default.  Remove old.
 
 *prelink-20110511 (15 Jun 2011)
 



1.1                  sys-devel/prelink/prelink-20111012.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/prelink/prelink-20111012.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/prelink/prelink-20111012.ebuild?rev=1.1&content-type=text/plain

Index: prelink-20111012.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/prelink/prelink-20111012.ebuild,v 1.1 2011/11/24 04:49:28 dirtyepic Exp $

EAPI="2"

inherit eutils flag-o-matic

DESCRIPTION="Modifies ELFs to avoid runtime symbol resolutions resulting in faster load times"
HOMEPAGE="http://people.redhat.com/jakub/prelink"

#SRC_URI="mirror://gentoo/${P}.tar.bz2"
SRC_URI="http://people.redhat.com/jakub/prelink/${P}.tar.bz2"
#
# if not available rip the distfile with rpm2targz from
# http://mirrors.kernel.org/fedora/development/rawhide/source/SRPMS/prelink-[ver].src.rpm

# track http://pkgs.fedoraproject.org/gitweb/?p=prelink.git;a=summary for
# version bumps

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 -arm ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE=""

DEPEND=">=dev-libs/elfutils-0.100
	!dev-libs/libelf
	>=sys-libs/glibc-2.8"
RDEPEND="${DEPEND}
	>=sys-devel/binutils-2.18"

S=${WORKDIR}/${PN}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-20061201-prelink-conf.patch

	sed -i -e 's:undosyslibs.sh::' testsuite/Makefile.in #254201
	sed -i -e '/^CC=/s: : -Wl,--disable-new-dtags :' testsuite/functions.sh #100147
	# >=binutils-2.22 --no-copy-dt-needed-entries is the default
	# --copy-dt-needed-entries was renamed from --add-needed in 2.21, use the
	# former so we don't have to bump the dep
	sed -i \
		-e '/CCLINK=/s:\(CCLINK="$(CC)\):\1 -Wl,--add-needed :' \
		-e '/CXXLINK=/s:\(CXXLINK="$(CXX)\):\1 -Wl,--add-needed :' \
		testsuite/Makefile.in

	# older GCCs don't support this flag
	sed -i -e 's:-Wno-pointer-sign::' src/Makefile.in #325269
	append-cflags -Wno-pointer-sign
	strip-unsupported-flags
}

src_install() {
	emake DESTDIR="${D}" install || die "Install Failed"

	insinto /etc
	doins doc/prelink.conf || die

	exeinto /etc/cron.daily
	newexe "${FILESDIR}"/prelink.cron prelink
	newconfd "${FILESDIR}"/prelink.confd prelink

	dodir /var/{lib/misc,log}
	touch "${D}/var/lib/misc/prelink.full"
	touch "${D}/var/lib/misc/prelink.quick"
	touch "${D}/var/lib/misc/prelink.force"
	touch "${D}/var/log/prelink.log"

	dodoc TODO ChangeLog
}

pkg_postinst() {
	echo
	elog "You may wish to read the Gentoo Linux Prelink Guide, which can be"
	elog "found online at:"
	elog
	elog "    http://www.gentoo.org/doc/en/prelink-howto.xml"
	elog
	elog "Please edit /etc/conf.d/prelink to enable and configure prelink"
	echo
	touch "${ROOT}/var/lib/misc/prelink.force"
}