[gentoo-commits] gentoo-x86 commit in net-print/cups-filters: cups-filters-9999.ebuild cups-filters-1.0.41.ebuild ChangeLog

[Andreas HAttel (dilfridge)]

dilfridge    13/11/04 23:21:09

  Modified:             cups-filters-9999.ebuild ChangeLog
  Added:                cups-filters-1.0.41.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

Revision  Changes    Path
1.42                 net-print/cups-filters/cups-filters-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?r1=1.41&r2=1.42

Index: cups-filters-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- cups-filters-9999.ebuild	27 Aug 2013 15:27:57 -0000	1.41
+++ cups-filters-9999.ebuild	4 Nov 2013 23:21:09 -0000	1.42
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.41 2013/08/27 15:27:57 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.42 2013/11/04 23:21:09 dilfridge Exp $
 
 EAPI=5
 
@@ -92,15 +92,14 @@
 	prune_libtool_files --all
 
 	cp "${FILESDIR}"/cups-browsed.init.d "${T}"/cups-browsed || die
-	cp "${FILESDIR}/cups-browsed.service" "${T}"/ || die
 
 	if ! use zeroconf ; then
 		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
-		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${T}"/cups-browsed.service || die
+		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
 	fi
 
 	doinitd "${T}"/cups-browsed
-	systemd_dounit "${T}/cups-browsed.service"
+	systemd_dounit "${S}/utils/cups-browsed.service"
 }
 
 pkg_postinst() {



1.86                 net-print/cups-filters/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	3 Nov 2013 06:23:01 -0000	1.85
+++ ChangeLog	4 Nov 2013 23:21:09 -0000	1.86
@@ -1,6 +1,12 @@
 # ChangeLog for net-print/cups-filters
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.85 2013/11/03 06:23:01 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.86 2013/11/04 23:21:09 dilfridge Exp $
+
+*cups-filters-1.0.41 (04 Nov 2013)
+
+  04 Nov 2013; Andreas K. Huettel <dilfridge@g.o>
+  +cups-filters-1.0.41.ebuild, cups-filters-9999.ebuild:
+  Version bump
 
   03 Nov 2013; Agostino Sarubbo <ago@g.o> cups-filters-1.0.36-r1.ebuild:
   Stable for ppc64, wrt bug #489720



1.1                  net-print/cups-filters/cups-filters-1.0.41.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.41.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.41.ebuild?rev=1.1&content-type=text/plain

Index: cups-filters-1.0.41.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-1.0.41.ebuild,v 1.1 2013/11/04 23:21:09 dilfridge Exp $

EAPI=5

GENTOO_DEPEND_ON_PERL=no

inherit base eutils perl-module autotools systemd

if [[ "${PV}" == "9999" ]] ; then
	inherit bzr
	EBZR_REPO_URI="http://bzr.linuxfoundation.org/openprinting/cups-filters"
	KEYWORDS=""
else
	SRC_URI="http://www.openprinting.org/download/${PN}/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~s390 ~x86 ~amd64-fbsd"
fi
DESCRIPTION="Cups PDF filters"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/openprinting/pdfasstandardprintjobformat"

LICENSE="MIT GPL-2"
SLOT="0"
IUSE="jpeg perl png static-libs tiff zeroconf"

RDEPEND="
	>=app-text/ghostscript-gpl-9.09
	app-text/poppler:=[cxx,jpeg?,lcms,tiff?,xpdf-headers(+)]
	>=app-text/qpdf-3.0.2:=
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/lcms:2
	>net-print/cups-1.5.9999
	!<=net-print/cups-1.5.9999
	sys-devel/bc
	sys-libs/zlib
	jpeg? ( virtual/jpeg:0 )
	perl? ( dev-lang/perl )
	png? ( media-libs/libpng:0= )
	tiff? ( media-libs/tiff )
	zeroconf? ( net-dns/avahi[dbus] )
"
DEPEND="${RDEPEND}"

src_prepare() {
	base_src_prepare
	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
	eautoreconf
}

src_configure() {
	econf \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		$(use_enable zeroconf avahi) \
		$(use_enable static-libs static) \
		--with-fontdir="fonts/conf.avail" \
		--with-pdftops=pdftops \
		--enable-imagefilters \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with tiff) \
		--with-rcdir=no \
 		--with-browseremoteprotocols=DNSSD,CUPS \
		--without-php
}

src_compile() {
	default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_prep
		perl-module_src_compile
		popd > /dev/null
	fi
}

src_install() {
	default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_install
		fixlocalpod
		popd > /dev/null
	fi

	# workaround: some printer drivers still require pstoraster and pstopxl, bug #383831
	dosym /usr/libexec/cups/filter/gstoraster /usr/libexec/cups/filter/pstoraster
	dosym /usr/libexec/cups/filter/gstopxl /usr/libexec/cups/filter/pstopxl

	prune_libtool_files --all

	cp "${FILESDIR}"/cups-browsed.init.d "${T}"/cups-browsed || die

	if ! use zeroconf ; then
		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
	fi

	doinitd "${T}"/cups-browsed
	systemd_dounit "${S}/utils/cups-browsed.service"
}

pkg_postinst() {
	perl-module_pkg_postinst

	elog "This version of cups-filters includes cups-browsed, a daemon that autodiscovers"
	elog "remote queues via avahi or cups-1.5 browsing protocol and adds them to your cups"
	elog "configuration. You may want to add it to your default runlevel."
}