[gentoo-commits] repo/gentoo:master commit in: media-sound/amarok/

[Andreas Sturmlechner]

commit:     b3e5c28c145f7d089be2829f48e39567328ca6f0
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Dec  9 21:28:23 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Dec  9 21:28:23 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b3e5c28c

media-sound/amarok: Drop mysteriously broken -r4

Package-Manager: Portage-2.3.17, Repoman-2.3.6

 media-sound/amarok/amarok-2.8.90-r4.ebuild | 132 -----------------------------
 1 file changed, 132 deletions(-)

diff --git a/media-sound/amarok/amarok-2.8.90-r4.ebuild b/media-sound/amarok/amarok-2.8.90-r4.ebuild
deleted file mode 100644
index 4ea07c89b53..00000000000
--- a/media-sound/amarok/amarok-2.8.90-r4.ebuild
+++ /dev/null
@@ -1,132 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-KDE_REQUIRED="never"
-KDE_HANDBOOK="optional"
-SQL_REQUIRED="always"
-VIRTUALX_REQUIRED="test"
-VIRTUALDBUS_TEST="true"
-inherit flag-o-matic kde4-base pax-utils
-
-DESCRIPTION="Advanced audio player based on KDE framework"
-HOMEPAGE="https://amarok.kde.org/"
-if [[ ${PV} != *9999* ]]; then
-	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.xz"
-	KEYWORDS="amd64 x86"
-fi
-
-LICENSE="GPL-2"
-SLOT="4"
-IUSE="debug +embedded ipod lastfm mp3tunes mtp ofa test +utils"
-
-if [[ ${KDE_BUILD_TYPE} == live ]]; then
-	RESTRICT+=" test"
-fi
-
-# ipod requires gdk enabled and also gtk compiled in libgpod
-COMMONDEPEND="
-	$(add_kdeapps_dep kdebase-kioslaves)
-	app-crypt/qca:2[qt4]
-	>=dev-qt/qtcore-4.8:4
-	>=dev-qt/qtdbus-4.8:4
-	>=dev-qt/qtscript-4.8:4
-	>=kde-frameworks/kdelibs-4.14.37:4[plasma]
-	>=media-libs/taglib-1.7[asf(+),mp4(+)]
-	>=media-libs/taglib-extras-1.0.1
-	sys-libs/zlib
-	>=virtual/mysql-5.1[embedded?]
-	>=x11-libs/qtscriptgenerator-0.1.0
-	ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
-	lastfm? ( >=media-libs/liblastfm-1.0.3[qt4] )
-	mp3tunes? (
-		dev-libs/glib:2
-		dev-libs/libxml2
-		dev-libs/openssl:0
-		>=dev-qt/qtcore-4.8.4:4[glib]
-		net-libs/loudmouth
-		net-misc/curl
-	)
-	mtp? ( >=media-libs/libmtp-1.0.0 )
-	ofa? ( >=media-libs/libofa-0.9.0 )
-"
-DEPEND="${COMMONDEPEND}
-	dev-util/automoc
-	virtual/pkgconfig
-	test? ( dev-cpp/gmock )
-"
-RDEPEND="${COMMONDEPEND}
-	!media-sound/amarok-utils
-	$(add_kdeapps_dep phonon-kde)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.8.0-taglib110.patch"
-	"${FILESDIR}/${P}-mysql-embedded.patch"
-	"${FILESDIR}/${P}-mysqld-rpath.patch"
-	"${FILESDIR}/${P}-scriptconsole.patch"
-	"${FILESDIR}/${P}-gcc6.patch"
-	"${FILESDIR}/${P}-ffmpeg3.patch"
-	"${FILESDIR}/${P}-no-webkit.patch"
-)
-
-src_prepare() {
-	kde4-base_src_prepare
-
-	# requires qtwebkit
-	sed -i -e "s/wikipedia,//" data/amarok_homerc || die
-}
-
-src_configure() {
-	# Append minimal-toc cflag for ppc64, see bug 280552 and 292707
-	use ppc64 && append-flags -mminimal-toc
-
-	local mycmakeargs=(
-		-DWITH_PLAYER=ON
-		-DWITH_Libgcrypt=OFF
-		-DWITH_SPECTRUM_ANALYZER=OFF
-		-DWITH_NepomukCore=OFF
-		-DWITH_Soprano=OFF
-		-DWITH_MYSQL_EMBEDDED=$(usex embedded)
-		-DWITH_IPOD=$(usex ipod)
-		-DWITH_GDKPixBuf=$(usex ipod)
-		-DWITH_LibLastFm=$(usex lastfm)
-		-DWITH_MP3Tunes=$(usex mp3tunes)
-		-DWITH_Mtp=$(usex mtp)
-		-DWITH_LibOFA=$(usex ofa)
-		-DWITH_UTILITIES=$(usex utils)
-	)
-
-	# bug 581554: add libmysqld location for rpath patch
-	use embedded && mycmakeargs+=( -DMYSQLD_DIR="${EPREFIX}/usr/$(get_libdir)/mysql" )
-
-	kde4-base_src_configure
-}
-
-src_install() {
-	kde4-base_src_install
-
-	# bug 481592
-	pax-mark m "${ED}"/usr/bin/amarok
-}
-
-pkg_postinst() {
-	kde4-base_pkg_postinst
-
-	if ! use embedded; then
-		echo
-		elog "You've disabled the amarok support for embedded mysql DBs."
-		elog "You'll have to configure amarok to use an external db server."
-		echo
-		elog "Please read http://amarok.kde.org/wiki/MySQL_Server for details on how"
-		elog "to configure the external db and migrate your data from the embedded database."
-		echo
-
-		if has_version "virtual/mysql[minimal]"; then
-			elog "You built mysql with the minimal use flag, so it doesn't include the server."
-			elog "You won't be able to use the local mysql installation to store your amarok collection."
-			echo
-		fi
-	fi
-}