[gentoo-commits] gentoo-x86 commit in sys-apps/kexec-tools: ChangeLog kexec-tools-2.0.7.ebuild

[Justin Lecher (jlec)]

jlec        14/07/10 06:11:16

  Modified:             ChangeLog
  Added:                kexec-tools-2.0.7.ebuild
  Log:
  sys-apps/kexec-tools: Version Bump, #516778
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.62                 sys-apps/kexec-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	28 Dec 2013 20:27:31 -0000	1.61
+++ ChangeLog	10 Jul 2014 06:11:15 -0000	1.62
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/kexec-tools
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/ChangeLog,v 1.61 2013/12/28 20:27:31 jlec Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/ChangeLog,v 1.62 2014/07/10 06:11:15 jlec Exp $
+
+*kexec-tools-2.0.7 (10 Jul 2014)
+
+  10 Jul 2014; Justin Lecher <jlec@g.o> +kexec-tools-2.0.7.ebuild:
+  Version Bump, #516778
 
   28 Dec 2013; Justin Lecher <jlec@g.o> kexec-tools-9999.ebuild,
   files/kexec.init-9999:



1.1                  sys-apps/kexec-tools/kexec-tools-2.0.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/kexec-tools-2.0.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kexec-tools/kexec-tools-2.0.7.ebuild?rev=1.1&content-type=text/plain

Index: kexec-tools-2.0.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kexec-tools/kexec-tools-2.0.7.ebuild,v 1.1 2014/07/10 06:11:15 jlec Exp $

EAPI=5

inherit autotools-utils flag-o-matic linux-info systemd

DESCRIPTION="Load another kernel from the currently executing Linux kernel"
HOMEPAGE="http://kernel.org/pub/linux/utils/kernel/kexec/"
SRC_URI="mirror://kernel/linux/utils/kernel/kexec/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="booke lzma xen zlib"

REQUIRED_USE="lzma? ( zlib )"

DEPEND="
	lzma? ( app-arch/xz-utils )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}"

CONFIG_CHECK="~KEXEC"

PATCHES=(
		"${FILESDIR}"/${PN}-2.0.4-disable-kexec-test.patch
		"${FILESDIR}"/${PN}-2.0.4-out-of-source.patch
	)

pkg_setup() {
	# GNU Make's $(COMPILE.S) passes ASFLAGS to $(CCAS), CCAS=$(CC)
	export ASFLAGS="${CCASFLAGS}"
	# to disable the -fPIE -pie in the hardened compiler
	if gcc-specs-pie ; then
		filter-flags -fPIE
		append-ldflags -nopie
	fi
}

src_configure() {
	local myeconfargs=(
		$(use_with booke)
		$(use_with lzma)
		$(use_with xen)
		$(use_with zlib)
		)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	dodoc "${FILESDIR}"/README.Gentoo

	newinitd "${FILESDIR}"/kexec.init-2.0.4-r2 kexec
	newconfd "${FILESDIR}"/kexec.conf-2.0.4 kexec

	insinto /etc
	doins "${FILESDIR}"/kexec.conf

	insinto /etc/kernel/postinst.d
	doins "${FILESDIR}"/90_kexec

	systemd_dounit "${FILESDIR}"/kexec.service
}

pkg_postinst() {
	if systemd_is_booted || has_version sys-apps/systemd; then
		elog "For systemd support the new config file is"
		elog "   /etc/kexec.conf"
		elog "Please adopt it to your needs as there is no autoconfig anymore"
	fi
}