[gentoo-commits] gentoo-x86 commit in app-arch/rar: rar-5.0.0_beta8.ebuild ChangeLog

[Jeff Horelick (jdhore)]

jdhore      13/09/01 22:26:30

  Modified:             ChangeLog
  Added:                rar-5.0.0_beta8.ebuild
  Log:
  Version bump to latest 5.0 beta (bug #469212)
  
  (Portage version: 2.2.1/cvs/Linux i686, unsigned Manifest commit)

Revision  Changes    Path
1.88                 app-arch/rar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?rev=1.88&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?rev=1.88&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?r1=1.87&r2=1.88

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v
retrieving revision 1.87
retrieving revision 1.88
diff -u -r1.87 -r1.88
--- ChangeLog	3 Mar 2013 15:47:15 -0000	1.87
+++ ChangeLog	1 Sep 2013 22:26:30 -0000	1.88
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/rar
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v 1.87 2013/03/03 15:47:15 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v 1.88 2013/09/01 22:26:30 jdhore Exp $
+
+*rar-5.0.0_beta8 (01 Sep 2013)
+
+  01 Sep 2013; Jeff Horelick <jdhore@g.o> +rar-5.0.0_beta8.ebuild:
+  Version bump to latest 5.0 beta (bug #469212)
 
   03 Mar 2013; Pacho Ramos <pacho@g.o> metadata.xml:
   Drop from metadata as talked with him



1.1                  app-arch/rar/rar-5.0.0_beta8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/rar-5.0.0_beta8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/rar-5.0.0_beta8.ebuild?rev=1.1&content-type=text/plain

Index: rar-5.0.0_beta8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/rar-5.0.0_beta8.ebuild,v 1.1 2013/09/01 22:26:30 jdhore Exp $
EAPI=4
MY_PV="${PV/0_beta/b}"
DESCRIPTION="RAR compressor/uncompressor"
HOMEPAGE="http://www.rarsoft.com/"
URI_x86="http://www.rarlab.com/rar/rarlinux-${MY_PV}.tar.gz"
URI_amd64="http://www.rarlab.com/rar/rarlinux-x64-${MY_PV}.tar.gz"
URI_w64="http://www.rarlab.com/rar/winrar-x64-${MY_PV//.}.exe"
SRC_URI="x86? ( ${URI_x86} )
	amd64? ( ${URI_amd64} )
	all_sfx? (
		${URI_x86}
		${URI_amd64}
		${URI_w64}
	)"

LICENSE="RAR"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="all_sfx static"

DEPEND="all_sfx? ( app-arch/unrar )"
RDEPEND="sys-libs/glibc"

S=${WORKDIR}/${PN}

QA_FLAGS_IGNORED="opt/rar/default.sfx
	opt/rar/default-elf32.sfx
	opt/rar/default-elf64.sfx
	opt/rar/default-win32.sfx
	opt/rar/default-win64.sfx
	opt/rar/WinCon.SFX
	opt/rar/WinCon64.SFX
	opt/rar/Zip.SFX
	opt/rar/Zip64.SFX
	opt/rar/unrar
	opt/rar/rar"
QA_PRESTRIPPED=${QA_FLAGS_IGNORED}

src_unpack() {
	use x86 && unpack ${URI_x86##*/}
	use amd64 && unpack ${URI_amd64##*/}
	rm -f "${S}"/license.txt
	if use all_sfx ; then
		mkdir sfx
		cd sfx
		unpack ${URI_x86##*/}
		mv rar/default.sfx default-elf32.sfx || die
		unpack ${URI_amd64##*/}
		mv rar/default.sfx default-elf64.sfx || die
		ln -s "${DISTDIR}"/${URI_w64##*/} w64.rar
		unpack ./w64.rar
		mv Default.SFX default-win32.sfx || die
		mv Default64.SFX default-win64.sfx || die
	fi
}

src_compile() { :; }

src_install() {
	exeinto /opt/rar
	doexe rar unrar || die
	use static && { newexe rar_static rar || die ; }

	dodir /opt/bin
	dosym ../rar/rar /opt/bin/rar || die
	dosym ../rar/unrar /opt/bin/unrar || die

	insinto /opt/rar
	if use all_sfx ; then
		doins "${WORKDIR}"/sfx/*.{sfx,SFX} || die
	else
		doins default.sfx || die
	fi
	doins rarfiles.lst || die
	dodoc *.txt
}