[gentoo-commits] repo/gentoo:master commit in: media-plugins/audacious-plugins/

[Andreas Sturmlechner]

commit:     da77f0cb61e36745e10568ff759d92ceda517293
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  2 09:56:00 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jun  2 11:26:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da77f0cb

media-plugins/audacious-plugins: 4.0.4 version bump

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-plugins/audacious-plugins/Manifest           |   1 +
 .../audacious-plugins-4.0.4.ebuild                 | 165 +++++++++++++++++++++
 2 files changed, 166 insertions(+)

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index e94486fe61e..24ad2ffb45a 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1,2 +1,3 @@
 DIST audacious-plugins-3.10.1.tar.bz2 1715477 BLAKE2B fda3940e6c06aadd93a3e1538be747083fcc969cf3118cf3e942787906b9ee0a13bd3c30d15ba19cb713559cdf8f7b71d7b961173b1619f0aafbdea5deb75ac3 SHA512 454e9ce4061e92a0ecda40f562d4cc7453fc0019fd76b25dbe9e319319fa37c22f9785cb29563e8074de8a88e6130106aca1e431790297e1b4636dc974fde565
 DIST audacious-plugins-4.0.3.tar.bz2 1759123 BLAKE2B 7a389a1d8f1bc17ce53e4e8c2560291c00b305ca0988f7ee27ce8a15d4be200d380a3525d43d1c04f6de9d7653f73c91721ba985801dc49dfa64b56309145f9b SHA512 6aaf9ca1d70e211e779baa65de844118f2e3c5ecef2ce6342429748e64437ddc67286ea286fbd7b0282304747dab31972f73ccb0aa312968c19d832ac0e0a6fc
+DIST audacious-plugins-4.0.4.tar.bz2 1761281 BLAKE2B 36f77d19e2cac461cd5649589bc4cb19a76577c30d5de4015688da5bf21efe1c835e1160534bc377e9a6f495fc9c2650544cc6c7bafac61c2f7187991a4d7935 SHA512 d0b435658f5aff9318e521e85d335444e089f80a267c2b9391123365b1c95b535bfa668ea772d9c437ad2611288ec7961a2ecf1d8cf8687f3b32a3cb1e14ddf8

diff --git a/media-plugins/audacious-plugins/audacious-plugins-4.0.4.ebuild b/media-plugins/audacious-plugins/audacious-plugins-4.0.4.ebuild
new file mode 100644
index 00000000000..32544b9a66f
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-4.0.4.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
+else
+	SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth gme http jack lame
+	libnotify libsamplerate lirc mms modplug mp3 nls opengl pulseaudio qtmedia
+	scrobbler sdl sid sndfile soxr speedpitch streamtuner vorbis wavpack"
+REQUIRED_USE="
+	|| ( alsa jack pulseaudio qtmedia sdl )
+	ampache? ( http ) streamtuner? ( http )"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )
+"
+DEPEND="
+	app-arch/unzip
+	dev-libs/dbus-glib
+	dev-libs/glib
+	dev-libs/libxml2:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	~media-sound/audacious-${PV}
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	ampache? ( =media-libs/ampache_browser-1* )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia:=
+		>=media-libs/libcddb-1.2.1
+	)
+	cue? ( media-libs/libcue:= )
+	ffmpeg? ( >=media-video/ffmpeg-0.7.3 )
+	flac? (
+		>=media-libs/flac-1.2.1-r1
+		>=media-libs/libvorbis-1.0
+	)
+	fluidsynth? ( media-sound/fluidsynth:= )
+	http? ( >=net-libs/neon-0.26.4 )
+	jack? (
+		>=media-libs/bio2jack-0.4
+		virtual/jack
+	)
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	libsamplerate? ( media-libs/libsamplerate:= )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	opengl? ( dev-qt/qtopengl:5 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl2[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	soxr? ( media-libs/soxr )
+	speedpitch? ( media-libs/libsamplerate:= )
+	streamtuner? ( dev-qt/qtnetwork:5 )
+	vorbis? (
+		>=media-libs/libogg-1.1.3
+		>=media-libs/libvorbis-1.2.0
+	)
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+}
+
+src_prepare() {
+	default
+	if ! use nls; then
+		sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+	fi
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-mpris2
+		--enable-qt
+		--enable-songchange
+		--disable-adplug # not packaged
+		--disable-gtk
+		--disable-openmpt # not packaged
+		--disable-oss4
+		--disable-coreaudio
+		--disable-sndio
+		$(use_enable aac)
+		$(use_enable alsa)
+		$(use_enable ampache)
+		$(use_enable bs2b)
+		$(use_enable cdda cdaudio)
+		$(use_enable cue)
+		$(use_enable flac)
+		$(use_enable flac filewriter)
+		$(use_enable fluidsynth amidiplug)
+		$(use_enable gme console)
+		$(use_enable http neon)
+		$(use_enable jack)
+		$(use_enable lame filewriter_mp3)
+		$(use_enable libnotify notify)
+		$(use_enable libsamplerate resample)
+		$(use_enable lirc)
+		$(use_enable mms)
+		$(use_enable modplug)
+		$(use_enable mp3 mpg123)
+		$(use_enable nls)
+		$(use_enable opengl qtglspectrum)
+		$(use_enable pulseaudio pulse)
+		$(use_enable qtmedia qtaudio)
+		$(use_enable scrobbler scrobbler2)
+		$(use_enable sdl sdlout)
+		$(use_enable sid)
+		$(use_enable sndfile)
+		$(use_enable soxr)
+		$(use_enable speedpitch)
+		$(use_enable streamtuner)
+		$(use_enable vorbis)
+		$(use_enable wavpack)
+		$(use_with ffmpeg ffmpeg ffmpeg)
+	)
+
+	econf "${myeconfargs[@]}"
+}