[gentoo-commits] gentoo-x86 commit in net-analyzer/cacti: cacti-0.8.7h.ebuild ChangeLog

[Peter Volkov (pva)]

pva         11/10/02 11:44:35

  Modified:             ChangeLog
  Added:                cacti-0.8.7h.ebuild
  Log:
  Version bump, bug #384627 thank Martin Samek for report.
  
  (Portage version: 2.1.10.20/cvs/Linux x86_64)

Revision  Changes    Path
1.180                net-analyzer/cacti/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/ChangeLog?rev=1.180&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/ChangeLog?rev=1.180&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/ChangeLog?r1=1.179&r2=1.180

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/cacti/ChangeLog,v
retrieving revision 1.179
retrieving revision 1.180
diff -u -r1.179 -r1.180
--- ChangeLog	1 Apr 2011 16:06:30 -0000	1.179
+++ ChangeLog	2 Oct 2011 11:44:35 -0000	1.180
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/cacti
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti/ChangeLog,v 1.179 2011/04/01 16:06:30 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti/ChangeLog,v 1.180 2011/10/02 11:44:35 pva Exp $
+
+*cacti-0.8.7h (02 Oct 2011)
+
+  02 Oct 2011; Peter Volkov <pva@g.o> +cacti-0.8.7h.ebuild:
+  Version bump, bug #384627 thank Martin Samek for report.
 
   01 Apr 2011; Peter Volkov <pva@g.o> -cacti-0.8.7e-r2.ebuild,
   -cacti-0.8.7e-r3.ebuild:



1.1                  net-analyzer/cacti/cacti-0.8.7h.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/cacti-0.8.7h.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/cacti-0.8.7h.ebuild?rev=1.1&content-type=text/plain

Index: cacti-0.8.7h.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti/cacti-0.8.7h.ebuild,v 1.1 2011/10/02 11:44:35 pva Exp $

EAPI="2"

inherit eutils webapp depend.php

# Support for _p* in version.
MY_P=${P/_p*/}
UPSTREAM_PATCHES=""

DESCRIPTION="Cacti is a complete frontend to rrdtool"
HOMEPAGE="http://www.cacti.net/"
SRC_URI="http://www.cacti.net/downloads/${MY_P}.tar.gz"

# patches
if [[ -n ${UPSTREAM_PATCHES} ]]; then
	for i in ${UPSTREAM_PATCHES}; do
		SRC_URI="${SRC_URI} http://www.cacti.net/downloads/patches/${PV/_p*}/${i}.patch"
	done
fi

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="snmp doc"

DEPEND=""

need_httpd

RDEPEND="snmp? ( >=net-analyzer/net-snmp-5.1.2 )
	net-analyzer/rrdtool
	dev-php/adodb
	virtual/mysql
	virtual/cron
	dev-lang/php[cli,mysql,xml,session,sockets]
	|| ( <dev-lang/php-5.3[pcre] >=dev-lang/php-5.3 )"

src_unpack() {
	unpack ${MY_P}.tar.gz
	if [[ -n ${UPSTREAM_PATCHES} ]]; then
		[ ! ${MY_P} == ${P} ] && mv ${MY_P} ${P}
	fi
}

src_prepare() {
	if [[ -n ${UPSTREAM_PATCHES} ]]; then
		for i in ${UPSTREAM_PATCHES} ; do
			EPATCH_OPTS="-p1 -d ${S} -N" epatch "${DISTDIR}"/${i}.patch
		done ;
	fi

	sed -i -e \
		's:$config\["library_path"\] . "/adodb/adodb.inc.php":"adodb/adodb.inc.php":' \
		"${S}"/include/global.php || die

	rm -rf lib/adodb || die # don't use bundled adodb
}

src_compile() { :; }

src_install() {
	webapp_src_preinst

	rm LICENSE README || die
	dodoc docs/{CHANGELOG,CONTRIB,README,txt/manual.txt} || die
	use doc && dohtml -r docs/html/
	rm -rf docs

	edos2unix `find -type f -name '*.php'`

	dodir ${MY_HTDOCSDIR}
	cp -r . "${D}"${MY_HTDOCSDIR}

	webapp_serverowned ${MY_HTDOCSDIR}/rra
	webapp_serverowned ${MY_HTDOCSDIR}/log/cacti.log
	webapp_configfile ${MY_HTDOCSDIR}/include/config.php
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt

	webapp_src_install
}