[gentoo-commits] gentoo-x86 commit in sci-visualization/scidavis: scidavis-0.2.2.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     09/06/01 12:50:06

  Modified:             ChangeLog
  Added:                scidavis-0.2.2.ebuild
  Log:
  Bump to 0.2.2. Closes #267994 #267218. Thanks to Michelangelo Scopelliti for testing and patching the ebuild.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  sci-visualization/scidavis/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/scidavis/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/scidavis/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/scidavis/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/scidavis/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	14 Apr 2009 18:29:26 -0000	1.4
+++ ChangeLog	1 Jun 2009 12:50:06 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for sci-visualization/scidavis
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/scidavis/ChangeLog,v 1.4 2009/04/14 18:29:26 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/scidavis/ChangeLog,v 1.5 2009/06/01 12:50:06 patrick Exp $
+
+*scidavis-0.2.2 (01 Jun 2009)
+
+  01 Jun 2009; Patrick Lauer <patrick@g.o> +scidavis-0.2.2.ebuild:
+  Bump to 0.2.2. Closes #267994 #267218. Thanks to Michelangelo Scopelliti
+  for testing and patching the ebuild.
 
 *scidavis-0.2.1-r1 (14 Apr 2009)
 



1.1                  sci-visualization/scidavis/scidavis-0.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/scidavis/scidavis-0.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/scidavis/scidavis-0.2.2.ebuild?rev=1.1&content-type=text/plain

Index: scidavis-0.2.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/scidavis/scidavis-0.2.2.ebuild,v 1.1 2009/06/01 12:50:06 patrick Exp $

EAPI=2
inherit eutils qt4 fdo-mime

DESCRIPTION="Scientific Data Analysis and Visualization"
HOMEPAGE="http://scidavis.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="python"

LANGS="de es fr ja ru sv"
for l in ${LANGS}; do
	IUSE="${IUSE} linguas_${l}"
done

CDEPEND="sys-libs/zlib
	=x11-libs/qwt-5.1*[svg]
	>=x11-libs/qwtplot3d-0.2.7
	x11-libs/qt-assistant:4
	>=dev-cpp/muParser-1.30
	>=sci-libs/gsl-1.8"
# remove because unsupported for now
#	sci-libs/liborigin:2"

DEPEND="${CDEPEND}
	dev-util/pkgconfig
	python? ( >=dev-python/sip-4.7 )"

RDEPEND="${CDEPEND}
	python? ( >=dev-python/PyQt4-4.4
		dev-python/pygsl
		sci-libs/scipy )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.2.1-profile.patch
	sed -i -e '/lgsl/d' fitPlugins/*/*.pro || die "sed gsl link failed"
	sed -i \
		-e "s:doc/${PN}:doc/${PF}:g" \
		${PN}/${PN}.pro || die "sed doc dir failed"
	# the libsuff thingy does not work
	sed -i \
		-e "s|/usr/lib\$\${libsuff}|/usr/$(get_libdir)|g" \
		-i fit*/*/*.pro || die "sed plugins failed"

	if use python; then
		sed -i \
			-e '/^include( python.pri )$/d' \
			${PN}/${PN}.pro || die "sed python failed"
	fi
}

src_configure() {
	eqmake4
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die 'emake install failed'
	dodoc README CHANGES
	doicon scidavis/icons/hicolor-48/scidavis.png
	cd ${PN}/translations
	insinto /usr/share/${PN}/translations
	for l in ${LANGS}; do
		if use linguas_${l}; then
			doins ${PN}_${l}.qm
		fi
	done
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}