[gentoo-commits] proj/qt:master commit in: dev-qt/qtwebengine/, dev-qt/qtwebchannel/, dev-qt/qtpositioning/, ...

[Jimi Huotari]

commit:     d268c99c3b0d0d8498981e7a3ca3e673a282b31c
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  1 14:36:07 2021 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Wed Dec  1 19:06:58 2021 +0000
URL:        https://gitweb.gentoo.org/proj/qt.git/commit/?id=d268c99c

dev-qt: add version 6.2.2

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 dev-qt/qtbase/Manifest                          |   1 +
 dev-qt/qtbase/qtbase-6.2.2.ebuild               | 184 +++++++++++++++++++++++
 dev-qt/qtdeclarative/Manifest                   |   1 +
 dev-qt/qtdeclarative/qtdeclarative-6.2.2.ebuild |  20 +++
 dev-qt/qtmultimedia/Manifest                    |   1 +
 dev-qt/qtmultimedia/qtmultimedia-6.2.2.ebuild   |  40 +++++
 dev-qt/qtpositioning/Manifest                   |   1 +
 dev-qt/qtpositioning/qtpositioning-6.2.2.ebuild |  18 +++
 dev-qt/qtshadertools/Manifest                   |   1 +
 dev-qt/qtshadertools/qtshadertools-6.2.2.ebuild |  17 +++
 dev-qt/qtsvg/Manifest                           |   1 +
 dev-qt/qtsvg/qtsvg-6.2.2.ebuild                 |  19 +++
 dev-qt/qttools/Manifest                         |   1 +
 dev-qt/qttools/qttools-6.2.2.ebuild             |  18 +++
 dev-qt/qtwebchannel/Manifest                    |   1 +
 dev-qt/qtwebchannel/qtwebchannel-6.2.2.ebuild   |  18 +++
 dev-qt/qtwebengine/Manifest                     |   1 +
 dev-qt/qtwebengine/qtwebengine-6.2.2.ebuild     | 192 ++++++++++++++++++++++++
 18 files changed, 535 insertions(+)

diff --git a/dev-qt/qtbase/Manifest b/dev-qt/qtbase/Manifest
index dc12e1cb..9af966f1 100644
--- a/dev-qt/qtbase/Manifest
+++ b/dev-qt/qtbase/Manifest
@@ -1 +1,2 @@
 DIST qtbase-everywhere-src-6.2.1.tar.xz 46641424 BLAKE2B 2c60afc31d5cde123c140eafabb4372c39c5b152cc3332d514a0d3bd92b2696b331adee1ad847dcb05eb642d242704fa5fd26f9a8298269f60ab64c3bd95e08c SHA512 9c1c3db8589ce085e1e895dfe6346f2f7a1928defb19e5ea87829f05138f4ceb78e8390c70bda86f430f5c059c4ab73a28e230f792be3cccf38951bdc1ee5dc2
+DIST qtbase-everywhere-src-6.2.2.tar.xz 46649016 BLAKE2B ae14ed74e06e2de2798b6b1d95dc4c4c2c61c839aabf7f5271ce1f6f6320d21c02f933974badbe94d882465ebe9cb43396305fa74d11445b50f3329590c57a15 SHA512 769dbf2b271083cfb9c72e6bd99cd52cdfd7d9d303d88d05175e4f0da5e8da5df9724bd48ad664e1d8e829a3529fa166654138c48cb36636f4787d0b26ff4b3b

diff --git a/dev-qt/qtbase/qtbase-6.2.2.ebuild b/dev-qt/qtbase/qtbase-6.2.2.ebuild
new file mode 100644
index 00000000..c0867b42
--- /dev/null
+++ b/dev-qt/qtbase/qtbase-6.2.2.ebuild
@@ -0,0 +1,184 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Cross-platform application development framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+# Qt Modules
+IUSE="+concurrent +dbus +gui +network +sql opengl +widgets +xml"
+REQUIRED_USE="
+	opengl? ( gui ) widgets? ( gui )
+	X? ( || ( evdev libinput ) )
+"
+
+QTGUI_IUSE="accessibility egl eglfs evdev +gif gles2-only +ico +jpeg +libinput tslib tuio vulkan +X"
+QTNETWORK_IUSE="gssapi libproxy sctp +ssl vnc"
+QTSQL_IUSE="freetds mysql oci8 odbc postgres +sqlite"
+IUSE+=" ${QTGUI_IUSE} ${QTNETWORK_IUSE} ${QTSQL_IUSE} cups gtk icu systemd +udev"
+# QtPrintSupport = QtGui + QtWidgets enabled.
+# ibus = xkbcommon + dbus, and xkbcommon needs either libinput or X
+# moved vnc logically to QtNetwork as that is upstream condition for it
+REQUIRED_USE+="
+	$(printf '%s? ( gui ) ' ${QTGUI_IUSE//+/})
+	$(printf '%s? ( network ) ' ${QTNETWORK_IUSE//+/})
+	$(printf '%s? ( sql ) ' ${QTSQL_IUSE//+/})
+	accessibility? ( dbus X )
+	cups? ( gui widgets )
+	eglfs? ( egl )
+	gtk? ( widgets )
+	gui? ( || ( eglfs X ) || ( libinput X ) )
+	libinput? ( udev )
+	sql? ( || ( freetds mysql oci8 odbc postgres sqlite ) )
+	X? ( gles2-only? ( egl ) )
+"
+
+# TODO:
+# qtimageformats: mng not done yet, qtimageformats.git upstream commit 9443239c
+# qtnetwork: connman, networkmanager
+DEPEND="
+	app-arch/brotli:=
+	app-arch/libarchive[zstd]
+	app-arch/zstd:=
+	app-crypt/libb2
+	dev-libs/double-conversion:=
+	dev-libs/glib:2
+	dev-libs/libpcre2:=[pcre16,unicode]
+	dev-util/gtk-update-icon-cache
+	media-libs/fontconfig
+	>=media-libs/freetype-2.6.1:2
+	>=media-libs/harfbuzz-1.6.0:=
+	media-libs/tiff:0
+	>=sys-apps/dbus-1.4.20
+	sys-libs/zlib:=
+	virtual/opengl
+	egl? ( media-libs/mesa[egl] )
+	evdev? ( sys-libs/mtdev )
+	freetds? ( dev-db/freetds )
+	gles2-only? ( media-libs/mesa[gles2] )
+	gssapi? ( virtual/krb5 )
+	gtk? (
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+	gui? ( media-libs/libpng:0= )
+	icu? ( dev-libs/icu:= )
+	!icu? ( virtual/libiconv )
+	jpeg? ( virtual/jpeg:0 )
+	libinput? (
+		dev-libs/libinput:=
+		>=x11-libs/libxkbcommon-0.5.0
+	)
+	libproxy? ( net-libs/libproxy )
+	mysql? ( dev-db/mysql-connector-c:= )
+	oci8? ( dev-db/oracle-instantclient:=[sdk] )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:* )
+	sctp? ( kernel_linux? ( net-misc/lksctp-tools ) )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? ( dev-libs/openssl:0= )
+	systemd? ( sys-apps/systemd:= )
+	tslib? ( >=x11-libs/tslib-1.21 )
+	udev? ( virtual/libudev:= )
+	vulkan? ( dev-util/vulkan-headers )
+	X? (
+		x11-libs/libdrm
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		>=x11-libs/libxcb-1.12:=[xkb]
+		>=x11-libs/libxkbcommon-0.5.0[X]
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-keysyms
+		x11-libs/xcb-util-renderutil
+		x11-libs/xcb-util-wm
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	# TODO: fails without QtGui
+	sed -e "/androiddeployqt/s/^/#DONT/" -e "/androidtestrunner/s/^/#DONT/" \
+		-i src/tools/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_BINDIR=${QT6_BINDIR}
+		-DINSTALL_INCLUDEDIR=${QT6_HEADERDIR}
+		-DINSTALL_LIBDIR=${QT6_LIBDIR}
+		-DINSTALL_ARCHDATADIR=${QT6_ARCHDATADIR}
+		-DINSTALL_PLUGINSDIR=${QT6_PLUGINDIR}
+		-DINSTALL_LIBEXECDIR=${QT6_LIBEXECDIR}
+		-DINSTALL_QMLDIR=${QT6_QMLDIR}
+		-DINSTALL_DATADIR=${QT6_DATADIR}
+		-DINSTALL_DOCDIR=${QT6_DOCDIR}
+		-DINSTALL_TRANSLATIONSDIR=${QT6_TRANSLATIONDIR}
+		-DINSTALL_SYSCONFDIR=${QT6_SYSCONFDIR}
+		-DINSTALL_MKSPECSDIR=${QT6_ARCHDATADIR}/mkspecs
+		-DINSTALL_EXAMPLESDIR=${QT6_EXAMPLESDIR}
+		-DQT_FEATURE_zstd=ON
+		$(qt_feature concurrent)
+		$(qt_feature dbus)
+		$(qt_feature gui)
+		$(qt_feature icu)
+		$(qt_feature network)
+		$(qt_feature sql)
+		$(qt_feature systemd journald)
+		-DQT_FEATURE_testlib=ON # TODO: install QtTest by default?
+		$(qt_feature udev libudev)
+		$(qt_feature xml)
+	)
+	use gui && mycmakeargs+=(
+		$(qt_feature accessibility accessibility_atspi_bridge)
+		$(qt_feature egl)
+		$(qt_feature eglfs eglfs_egldevice)
+		$(qt_feature eglfs eglfs_gbm)
+		$(qt_feature evdev)
+		$(qt_feature evdev mtdev)
+		$(qt_feature gif)
+		$(qt_feature jpeg)
+		$(qt_feature opengl)
+		$(qt_feature gles2-only opengles2)
+		$(qt_feature libinput)
+		$(qt_feature tslib)
+		$(qt_feature tuio tuiotouch)
+		$(qt_feature vulkan)
+		$(qt_feature widgets)
+		$(qt_feature X xcb)
+		$(qt_feature X xcb_xlib)
+	)
+	use widgets && mycmakeargs+=(
+		$(qt_feature cups)
+		$(qt_feature gtk gtk3)
+	)
+	if use libinput || use X; then
+		mycmakeargs+=( -DQT_FEATURE_xkbcommon=ON )
+	fi
+	use network && mycmakeargs+=(
+		$(qt_feature gssapi)
+		$(qt_feature libproxy)
+		$(qt_feature sctp)
+		$(qt_feature ssl openssl)
+		$(qt_feature vnc)
+	)
+	use sql && mycmakeargs+=(
+		$(qt_feature freetds sql_tds)
+		$(qt_feature mysql sql_mysql)
+		$(qt_feature oci8 sql_oci)
+		$(qt_feature odbc sql_odbc)
+		$(qt_feature postgres sql_psql)
+		$(qt_feature sqlite sql_sqlite)
+		$(qt_feature sqlite system_sqlite)
+	)
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtdeclarative/Manifest b/dev-qt/qtdeclarative/Manifest
index 1d293487..b08805c1 100644
--- a/dev-qt/qtdeclarative/Manifest
+++ b/dev-qt/qtdeclarative/Manifest
@@ -1 +1,2 @@
 DIST qtdeclarative-everywhere-src-6.2.1.tar.xz 29764804 BLAKE2B 1d738a04ad18661b3483321771a5ba0559ed73c84640bc5b07d236f527a1068c8d143c76fbb66768d52bb96e0417fa38e0a4875a0ba6729ab647181d5ec5a962 SHA512 b581718823de27915e4a59284a522fc1d2b869167d92af2ea20caba9f4e43f2fadb83f5bf6aaeda42f5f316c976cd9a3a313437c99f2a0eba1cff55ba7735cbe
+DIST qtdeclarative-everywhere-src-6.2.2.tar.xz 29455560 BLAKE2B 30b439d4dcc563ea6dc1f101d5bff87aae13cf5f2a16d330af9d5e51be6926abeaf2243b8881645686354c62697ef8c8010ce9dff0dd58f039eba6e00197fcad SHA512 2cfa9814a104e7e046d73a0c3ca191c8c94410e5d28bcb62c3a816c188514fd3d857d35d5f71d06aa902523e2210a3818756b15ac98fecf9a35f624a89ee2e86

diff --git a/dev-qt/qtdeclarative/qtdeclarative-6.2.2.ebuild b/dev-qt/qtdeclarative/qtdeclarative-6.2.2.ebuild
new file mode 100644
index 00000000..66011c10
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-6.2.2.ebuild
@@ -0,0 +1,20 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Declarative (Quick 2)"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtshadertools-${PV}*
+"
+RDEPEND="${DEPEND}"
+
+# TODO: qml/quick automagic

diff --git a/dev-qt/qtmultimedia/Manifest b/dev-qt/qtmultimedia/Manifest
index 787e47a3..7ed9ed05 100644
--- a/dev-qt/qtmultimedia/Manifest
+++ b/dev-qt/qtmultimedia/Manifest
@@ -1 +1,2 @@
 DIST qtmultimedia-everywhere-src-6.2.1.tar.xz 3710324 BLAKE2B 8d0275d525a449fc734af56a781bdad759feb612d7eb794a94a3c9e22eae20c71d2a07b76abf8492f9e20b589492abc6a121c407a5e6d158217e8d3ba1d1ae07 SHA512 6e6fba8c059106b99ccd94ce87f6df17d56de24ccafdd8e3e4d42e312895166c52492dfe425bbb1851e37a49636a560383982580fe184b7a345048e93e8ee05c
+DIST qtmultimedia-everywhere-src-6.2.2.tar.xz 3771836 BLAKE2B eb19531f9068462f45994eab15a478a91eb4123a08954d48b53338ba5a29d64bc1bf780b2c92ead08f7793499afc671fab2ea0dea0b72188eb17ad94b1421607 SHA512 70eaa88742f0fe5b4106e6ec0ed864fca439b8c4e8c2478894c4f550410b57eee829b2fecf2d199d4892073f0d4754b0acbbea8b8c6ab897ed480730cd9cac15

diff --git a/dev-qt/qtmultimedia/qtmultimedia-6.2.2.ebuild b/dev-qt/qtmultimedia/qtmultimedia-6.2.2.ebuild
new file mode 100644
index 00000000..4c0400d1
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-6.2.2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Multimedia"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="gstreamer"
+
+RDEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtshadertools-${PV}*
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+src_configure() {
+	# TODO: linux_v4l automagic
+	local mycmakeargs=(
+		-DQT_FEATURE_alsa=off
+		-DQT_FEATURE_pulseaudio=off
+		$(qt_feature gstreamer)
+	)
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtpositioning/Manifest b/dev-qt/qtpositioning/Manifest
new file mode 100644
index 00000000..ce00b4ee
--- /dev/null
+++ b/dev-qt/qtpositioning/Manifest
@@ -0,0 +1 @@
+DIST qtpositioning-everywhere-src-6.2.2.tar.xz 1490532 BLAKE2B 4971b21e87b4cc0a8430c886b25a3b1aa2cde6af32c9e705ef76722df403456910909ea9a58b91cee6a40bf94c95713fa25852b3ce1ebb8a797080bd8e412ea3 SHA512 0e0fdffe01637e29af2ad7c717413adeb613156ce8cd9311e52629b410b9dc8278a75c2002643345b5db3833bc05735e20a638ef8df5e655349c72a17386d9c4

diff --git a/dev-qt/qtpositioning/qtpositioning-6.2.2.ebuild b/dev-qt/qtpositioning/qtpositioning-6.2.2.ebuild
new file mode 100644
index 00000000..4f2eb63e
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-6.2.2.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Physical position determination library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtshadertools/Manifest b/dev-qt/qtshadertools/Manifest
index 7cfcf189..7f27b9d9 100644
--- a/dev-qt/qtshadertools/Manifest
+++ b/dev-qt/qtshadertools/Manifest
@@ -1 +1,2 @@
 DIST qtshadertools-everywhere-src-6.2.1.tar.xz 986656 BLAKE2B c7bb167986167373766a242b4e69413b3cc61aedd865779c1c3ba4268a74e70b0df8b796329a1df204834e0e7fc6f75bef8afdec2962212c5c905799d1a0e1e0 SHA512 94e6bab0211e38e72cbd970b3c69da04a0c78fd51bb3539ad6c7cd39e9573d22cf59cb7155a7e77ea64ea434d877da17fa593d230ecf0cc72785aa4b4b7d0e3f
+DIST qtshadertools-everywhere-src-6.2.2.tar.xz 986604 BLAKE2B 771c1f8fb407855c0ab75d070934864f695bad6df066a388372c5d5dce0d7eab1b29a5f57bafadf898d7bc45070366771f3c46ed3438f24860c785356a6eca73 SHA512 ff05db03bd0bee5226d03b64299d0afd63ea84dd0b6545ccb41e965f2354f01b867b3ff7ff1f2e80f18f16cc6ae597c22fe028d278d85e23167bee03a3b245c7

diff --git a/dev-qt/qtshadertools/qtshadertools-6.2.2.ebuild b/dev-qt/qtshadertools/qtshadertools-6.2.2.ebuild
new file mode 100644
index 00000000..44a0d914
--- /dev/null
+++ b/dev-qt/qtshadertools/qtshadertools-6.2.2.ebuild
@@ -0,0 +1,17 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt APIs and Tools for Graphics Pipelines"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtsvg/Manifest b/dev-qt/qtsvg/Manifest
index 2ff15335..7dad246e 100644
--- a/dev-qt/qtsvg/Manifest
+++ b/dev-qt/qtsvg/Manifest
@@ -1 +1,2 @@
 DIST qtsvg-everywhere-src-6.2.1.tar.xz 1717684 BLAKE2B 0e5dee2741d80f5d4d72f3b8e385100db123598bf823673c8523fb590cc9b4034e23b9c6778f39629b3fe8fc010b161ecc9ceacdda5c5b96ccd5237e48007fd8 SHA512 807357ea22042788cb573b5132ac3f0caeb011d3a20f338aaf87f229625da26d7aab2bce87174ded33f2a668c2046855c06ff5169af0e30e400219efc8e00964
+DIST qtsvg-everywhere-src-6.2.2.tar.xz 1718020 BLAKE2B 2629bc1d1971dd11d793e2462f72de767e4d679edec0261fba8a570f4787673468b106a8fd5d31b30930751de09da6f3fef6fef2e55598390e9928df9e3cdfa0 SHA512 2a1361d2b1fa5eb2cf1bfb6f3beeb765d144043e12eda5f002ddae3c89d110d1b4e55a7c4be55985c5613c2f22e5d57dd2d7bbf0cbdc2f7bbe58403efedcba1a

diff --git a/dev-qt/qtsvg/qtsvg-6.2.2.ebuild b/dev-qt/qtsvg/qtsvg-6.2.2.ebuild
new file mode 100644
index 00000000..4857ed61
--- /dev/null
+++ b/dev-qt/qtsvg/qtsvg-6.2.2.ebuild
@@ -0,0 +1,19 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="SVG rendering library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	sys-libs/zlib:=
+
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qttools/Manifest b/dev-qt/qttools/Manifest
index 4413cdd7..07d6c052 100644
--- a/dev-qt/qttools/Manifest
+++ b/dev-qt/qttools/Manifest
@@ -1 +1,2 @@
 DIST qttools-everywhere-src-6.2.1.tar.xz 8668512 BLAKE2B 45605dde132713c5f80f5d2aac1c4beb267d241880299a5c21b5cc1ddc2ec1d278379d7924d0bd65cc29416848230b40ea91fc3839a4016b800dee14e0cdfbb8 SHA512 2d64cd8e3feaa29314e3d80aa46ab5f4b58fe94c29fd0521a5fa4a238764a578aff2cd0901c91d36172f5da53d610159c6cfe90007e5a68f63b2ae6cde78780e
+DIST qttools-everywhere-src-6.2.2.tar.xz 8622800 BLAKE2B 47ba23c6e45080bb33e551104a856bd0205a58f1e4c61d8947b42dd162e183d14912723321b87da0d7b2f8e638a26aa5caf86d3898bc3b2377b628b3a772f982 SHA512 bce7ce96e64f423eed3f3655dd53d58588093287a6879da86067c4313962afd43d6f514d776c77f5b9462df31ce5801ab42a3232ebc8ef49209da6812fa9a304

diff --git a/dev-qt/qttools/qttools-6.2.2.ebuild b/dev-qt/qttools/qttools-6.2.2.ebuild
new file mode 100644
index 00000000..53ce00a4
--- /dev/null
+++ b/dev-qt/qttools/qttools-6.2.2.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Tools"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtwebchannel/Manifest b/dev-qt/qtwebchannel/Manifest
index ee928c7c..e1c3fdee 100644
--- a/dev-qt/qtwebchannel/Manifest
+++ b/dev-qt/qtwebchannel/Manifest
@@ -1 +1,2 @@
 DIST qtwebchannel-everywhere-src-6.2.1.tar.xz 211188 BLAKE2B 5be9e1917996fd192b1a49c4868b0eaa1be065b61bf8b2b4d8571a00c2da9b271d046422f3b36e6040aa7204da05d0db39a173b31d2f5ed68875a75feba67384 SHA512 3bf57b86e0c88776d9bb3c223f7f9d5a4785047da757a2fc8d5dcc241dbfd09395fce53beb03b5fb4106c29234825987116735375cf8ab8ad0173e5c09d747f1
+DIST qtwebchannel-everywhere-src-6.2.2.tar.xz 211088 BLAKE2B ea9abec4b6a2343ff6d5a206c15c25301b75462d9bf21241d3735994ad0286e8a02a163b0c907b3300f8efb5292ea9c267a5906ed7a88548d081308529a3062a SHA512 0b2b3faf52126589cbf9a1072d68be60fcb0936e4fe52804a070aa15a248d9c4acf261ead42e119dfffdb33902a125a27cfe8611e5c047646d9a32e15f2b6bde

diff --git a/dev-qt/qtwebchannel/qtwebchannel-6.2.2.ebuild b/dev-qt/qtwebchannel/qtwebchannel-6.2.2.ebuild
new file mode 100644
index 00000000..719f560d
--- /dev/null
+++ b/dev-qt/qtwebchannel/qtwebchannel-6.2.2.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt WebChannel"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtwebengine/Manifest b/dev-qt/qtwebengine/Manifest
index 29d93b25..b1f83ed2 100644
--- a/dev-qt/qtwebengine/Manifest
+++ b/dev-qt/qtwebengine/Manifest
@@ -1,2 +1,3 @@
 DIST qtwebengine-5.15.2-chromium87-ppc64le.tar.xz 28536 BLAKE2B 98f8e01e7026d9df1d30ae453d4394d3c4ad04c0620a2496235d45f5f1080c2280e040826cde7f72d9771bfc80d0c3df56c9dcbe4f763cec432ad56de37d64c5 SHA512 c90a76f44a9d720624016fd082ab3036f12e13b9789e869ebaf5e4774afca7d4187faf187f365f696d1a7eda05ca75516556ee9d291cdb3408d57cc4b23e2654
 DIST qtwebengine-everywhere-src-6.2.1.tar.xz 369758400 BLAKE2B ddbc533be3b51dc4c8503a5107f74c540cde7825bfe3401e7a74deebcd6db46453b05be4538dca4c2618960e29b691ad656c1b13e52aeac6991e8ae93ea97158 SHA512 ff7d766889f982b8a87ac5f804d38827e457079fefbee5e992368d4cff9c9fee58add02779c8c123c1bc8da30513169cb5c028e76f209ec699093f0493c44bc1
+DIST qtwebengine-everywhere-src-6.2.2.tar.xz 369695600 BLAKE2B 93affc7039e45429060ba35db10131a8873f19fa1188fecf3f28e83afc0e6f25f6ac5b6ad8e3dd6a65216a9e5f7b831ea21b431d652db16d7aff62bb26c365e0 SHA512 7bc7a6ada9125d02995a71a962ae464ae3f452e30b409a004aed245c4636af4b6e6736fbeb9349ecc4ecfeec7328ac96bc9193ed53221de322ebc913ea2a833f

diff --git a/dev-qt/qtwebengine/qtwebengine-6.2.2.ebuild b/dev-qt/qtwebengine/qtwebengine-6.2.2.ebuild
new file mode 100644
index 00000000..ee95eff6
--- /dev/null
+++ b/dev-qt/qtwebengine/qtwebengine-6.2.2.ebuild
@@ -0,0 +1,192 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml(+)"
+CHROMIUM_VER="90.0.4430.228"
+CHROMIUM_PATCHES_VER="94.0.4606.61"
+
+inherit estack flag-o-matic multiprocessing python-any-r1 qt6-build
+
+DESCRIPTION="Library for rendering dynamic web content in Qt6 C++ and QML applications"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="
+	alsa bindist designer geolocation +jumbo-build kerberos pipewire pulseaudio
+	+system-ffmpeg +system-icu widgets
+"
+REQUIRED_USE="designer? ( widgets )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-util/gn-0.1807
+	dev-util/gperf
+	dev-util/ninja
+	dev-util/re2c
+	net-libs/nodejs[ssl]
+	sys-devel/bison
+	sys-devel/flex
+"
+RDEPEND="
+	app-arch/snappy:=
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/expat
+	dev-libs/libevent:=
+	dev-libs/libxml2[icu]
+	dev-libs/libxslt
+	dev-libs/re2:=
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtwebchannel-${PV}*
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	media-libs/lcms:2
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:0=
+	>=media-libs/libvpx-1.5:=[svc(+)]
+	media-libs/libwebp:=
+	media-libs/opus
+	sys-apps/dbus
+	sys-apps/pciutils
+	sys-libs/zlib[minizip]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libxcb:=
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libXtst
+	alsa? ( media-libs/alsa-lib )
+	geolocation? ( =dev-qt/qtpositioning-${PV}* )
+	kerberos? ( virtual/krb5 )
+	pipewire? ( media-video/pipewire )
+	pulseaudio? ( media-sound/pulseaudio:= )
+	system-ffmpeg? ( media-video/ffmpeg:0= )
+	system-icu? ( >=dev-libs/icu-69.1:= )
+	widgets? (
+		=dev-qt/qtbase-${PV}*[widgets]
+	)
+"
+DEPEND="${RDEPEND}
+	media-libs/libglvnd
+"
+
+pkg_preinst() {
+	elog "This version of Qt WebEngine is based on Chromium version ${CHROMIUM_VER}, with"
+	elog "additional security fixes up to ${CHROMIUM_PATCHES_VER}. Extensive as it is, the"
+	elog "list of backports is impossible to evaluate, but always bound to be behind"
+	elog "Chromium's release schedule."
+	elog "In addition, various online services may deny service based on an outdated"
+	elog "user agent version (and/or other checks). Google is already known to do so."
+	elog
+	elog "tldr: Your web browsing experience will be compromised."
+}
+
+src_unpack() {
+	# bug 307861
+	eshopts_push -s extglob
+	if is-flagq '-g?(gdb)?([1-9])'; then
+		ewarn
+		ewarn "You have enabled debug info (probably have -g or -ggdb in your CFLAGS/CXXFLAGS)."
+		ewarn "You may experience really long compilation times and/or increased memory usage."
+		ewarn "If compilation fails, please try removing -g/-ggdb before reporting a bug."
+		ewarn
+	fi
+	eshopts_pop
+
+	default
+}
+
+src_prepare() {
+	# bug 620444 - ensure local headers are used
+	find "${S}" -type f -name "*.pr[fio]" | \
+		xargs sed -i -e 's|INCLUDEPATH += |&$${QTWEBENGINE_ROOT}_build/include $${QTWEBENGINE_ROOT}/include |' || die
+
+	if use system-icu; then
+		# Sanity check to ensure that bundled copy of ICU is not used.
+		# Whole src/3rdparty/chromium/third_party/icu directory cannot be deleted because
+		# src/3rdparty/chromium/third_party/icu/BUILD.gn is used by build system.
+		# If usage of headers of bundled copy of ICU occurs, then lists of shim headers in
+		# shim_headers("icui18n_shim") and shim_headers("icuuc_shim") in
+		# src/3rdparty/chromium/third_party/icu/BUILD.gn should be updated.
+		local file
+		while read file; do
+			echo "#error This file should not be used!" > "${file}" || die
+		done < <(find src/3rdparty/chromium/third_party/icu -type f "(" -name "*.c" -o -name "*.cpp" -o -name "*.h" ")" 2>/dev/null)
+	fi
+
+	qt6-build_src_prepare
+}
+
+src_configure() {
+	export NINJA_PATH=/usr/bin/ninja
+	export NINJAFLAGS="${NINJAFLAGS:--j$(makeopts_jobs) -l$(makeopts_loadavg "${MAKEOPTS}" 0) -v}"
+
+	local mycmakeargs=(
+#		-DQT_FEATURE_accessibility=off
+#		-DQT_FEATURE_force_asserts=off
+#		-DQT_FEATURE_opengl=off
+#		-DQT_FEATURE_printer=off
+		-DQT_FEATURE_qtpdf_build=off
+		-DQT_FEATURE_qtpdf_quick_build=off
+		-DQT_FEATURE_qtpdf_widgets_build=off
+		-DQT_FEATURE_qtwebengine_build=on
+		-DQT_FEATURE_qtwebengine_quick_build=on
+		-DQT_FEATURE_qtwebengine_widgets_build=on
+#		-DQT_FEATURE_ssl=off
+#		-DQT_FEATURE_static=off
+#		-DQT_FEATURE_system_zlib=off
+#		-DQT_FEATURE_system_png=off
+#		-DQT_FEATURE_system_jpeg=off
+#		-DQT_FEATURE_system_freetype=off
+#		-DQT_FEATURE_system_harfbuzz=off
+#		-DQT_FEATURE_use_gold_linker=off
+#		-DQT_FEATURE_use_lld_linker=off
+		-DQT_FEATURE_webengine_embedded_build=off
+		-DQT_FEATURE_webengine_extensions=on
+#		-DQT_FEATURE_webengine_full_debug_info=$(usex debug)
+		-DQT_FEATURE_webengine_geolocation=$(usex geolocation on off)
+		-DQT_FEATURE_webengine_jumbo_build=$(usex jumbo-build)
+#		-DQT_FEATURE_webengine_jumbo_file_merge_limit
+		-DQT_FEATURE_webengine_kerberos=$(usex kerberos on off)
+		-DQT_FEATURE_webengine_native_spellchecker=off
+		-DQT_FEATURE_webengine_ozone_x11=on
+		-DQT_FEATURE_webengine_pepper_plugins=on
+		-DQT_FEATURE_webengine_proprietary_codecs=$(usex bindist off on)
+		-DQT_FEATURE_webengine_printing_and_pdf=on
+		-DQT_FEATURE_webengine_sanitizer=on
+		-DQT_FEATURE_webengine_spellchecker=on
+		-DQT_FEATURE_webengine_system_opus=on
+		-DQT_FEATURE_webengine_system_libwebp=on
+		-DQT_FEATURE_webengine_system_alsa=$(usex alsa on off)
+		-DQT_FEATURE_webengine_system_ffmpeg=$(usex system-ffmpeg)
+		-DQT_FEATURE_webengine_system_gn=on
+		-DQT_FEATURE_webengine_system_icu=$(usex system-icu)
+		-DQT_FEATURE_webengine_system_libevent=on
+		-DQT_FEATURE_webengine_system_libpci=on
+		-DQT_FEATURE_webengine_system_libpng=on
+		-DQT_FEATURE_webengine_system_pulseaudio=$(usex pulseaudio on off)
+		-DQT_FEATURE_webengine_system_zlib=on
+		-DQT_FEATURE_webengine_webchannel=on
+		-DQT_FEATURE_webengine_webrtc=on
+		-DQT_FEATURE_webengine_webrtc_pipewire=$(usex pipewire on off)
+#		-DQT_FEATURE_xcb=off
+	)
+
+	qt6-build_src_configure
+}