[gentoo-commits] gentoo-x86 commit in sys-power/iasl: iasl-20130117-r1.ebuild ChangeLog iasl-20130117.ebuild

[Patrick Lauer (patrick)]

patrick     13/03/05 04:36:19

  Modified:             ChangeLog
  Added:                iasl-20130117-r1.ebuild
  Removed:              iasl-20130117.ebuild
  Log:
  Fix BITS value to make things work on 32bit architectures too
  
  (Portage version: 2.2.0_alpha166/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.41                 sys-power/iasl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/iasl/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/iasl/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/iasl/ChangeLog?r1=1.40&r2=1.41

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/iasl/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog	31 Jan 2013 09:37:07 -0000	1.40
+++ ChangeLog	5 Mar 2013 04:36:19 -0000	1.41
@@ -1,6 +1,12 @@
 # ChangeLog for sys-power/iasl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/iasl/ChangeLog,v 1.40 2013/01/31 09:37:07 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/iasl/ChangeLog,v 1.41 2013/03/05 04:36:19 patrick Exp $
+
+*iasl-20130117-r1 (05 Mar 2013)
+
+  05 Mar 2013; Patrick Lauer <patrick@g.o> +iasl-20130117-r1.ebuild,
+  -iasl-20130117.ebuild:
+  Fix BITS value to make things work on 32bit architectures too
 
 *iasl-20130117 (31 Jan 2013)
 *iasl-20121018 (31 Jan 2013)



1.1                  sys-power/iasl/iasl-20130117-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/iasl/iasl-20130117-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/iasl/iasl-20130117-r1.ebuild?rev=1.1&content-type=text/plain

Index: iasl-20130117-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/iasl/iasl-20130117-r1.ebuild,v 1.1 2013/03/05 04:36:19 patrick Exp $

EAPI=4

inherit toolchain-funcs flag-o-matic eutils

MY_PN=acpica-unix
MY_P=${MY_PN}-${PV}
MY_TESTS_P=${MY_PN/ca/tests}-${PV}
DESCRIPTION="Intel ACPI Source Language (ASL) compiler"
HOMEPAGE="https://www.acpica.org/downloads/index.php"
SRC_URI="http://www.acpica.org/download/${MY_P}.tar.gz
	test? ( http://www.acpica.org/download/${MY_TESTS_P}.tar.gz )"

LICENSE="iASL"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="test"

DEPEND="sys-devel/bison
	sys-devel/flex"
RDEPEND=""

S=${WORKDIR}/${MY_P}

pkg_setup() {
	if use test && has test ${FEATURES}; then
		ewarn 'You have selected USE="test". This will install the test results'
		ewarn "into /usr/share/${PF}/, compressed as a tarball."
		ewarn 'The tests themselves will only rarely die, but the test results'
		ewarn 'are interesting for arch testing. The tests may take quite some'
		ewarn 'time to complete.'
	fi
}

src_prepare() {
	#epatch "${FILESDIR}/${PN}-20110922-as-needed.patch"
	epatch "${FILESDIR}/${PN}-20120816-locale.patch"
	# Upstream has changed the buildsystem a lot, not sure if these are still
	# needed
	#epatch "${FILESDIR}/${PN}-20120816-parallelmake-001.patch"
	#epatch "${FILESDIR}/${PN}-20110922-parallelmake-002.patch"
	#epatch "${FILESDIR}/${PN}-20110922-parallelmake-003.patch"

	find "${S}" -type f -name 'Makefile*' -print0 | \
		xargs -0 -I '{}' \
		sed -r -e 's:-\<Werror\>::g' -i '{}' \
		|| die

	# BITS is tied to ARCH - please set appropriately if you add new keywords
	if [[ $ARCH == @(amd64|amd64-fbsd) ]] ; then
		export BITS=64
	else
		export BITS=32
	fi
}

src_configure() {
	:
}

src_compile() {
	cd acpica/generate/unix
	emake BITS=${BITS}
}

src_test() {
	aslts_test
	#aapits_test
	#The aapits test currently fails, missing include probably.
}

src_install() {
	cd acpica/generate/unix
	emake install DESTDIR="${D}" BITS=${BITS}
	default_src_install
	#local bin
	#for bin in $(<"${T}"/binlist) ; do
	#	dobin "${T}"/${bin}
	#done
	dodoc "${S}"/changes.txt
	newdoc "${S}"/source/compiler/readme.txt compiler-readme.txt
	newdoc "${S}"/generate/unix/readme.txt unix-readme.txt
	newdoc "${S}"/generate/lint/readme.txt lint-readme.txt
	newdoc "${S}"/source/compiler/new_table.txt compiler-new_table.txt

	if use test && has test ${FEATURES}; then
		tb="${T}"/testresults.tar.bz2
		export ASLTSDIR="$(<"${T}"/asltdir)"
		ebegin "Creating Test Tarball"
		tar -cjf "${tb}" -C "${ASLTSDIR}"/tmp/RESULTS .  || die "tar failed"
		eend $?
		dodir /usr/share/${PF}
		insinto /usr/share/${PF}
		doins ${tb} || die "doins testresults.tar.bz2 failed"
	fi

}

aslts_test() {
	export	ASL="${S}"/generate/unix/bin${BITS}/iasl \
		acpiexec="${S}"/generate/unix/bin${BITS}/acpiexec \
		ASLTSDIR="${WORKDIR}/${MY_TESTS_P}"/tests/aslts
	export	PATH="${PATH}:${ASLTSDIR}/bin"
	echo "$ASLTSDIR" >"${T}"/asltdir
	cd "${ASLTSDIR}"
	edos2unix $(find . -type 'f')
	make install || die "make install aslts test failed"
	chmod +x $(find bin/ ! -regex 'ERROR_OPCODES|HOW_TO_USE|README' ) || die "chmod bin +x failed"

	#The below Do commands runs the tests twice and then dies if the results aren't
	#Identical.
	Do 1 || die "failed Do 1"
	Do 2 || die "failed Do 2"
}

aapits_test() {
	mv "${WORKDIR}/${MY_TESTS_P}/tests/aapits" "${S}/tools/" || die "mv failed"
	cd "${S}/tools/aapits" || die "cannot find ${S}/tools/aapits"
	edos2unix $(find . -type 'f')
	chmod +x $(find bin/ | sed  -r -e '/\/[A-Z_]+$/d') || die "chmod bin +x failed"
	make || die "make in aapits failed"
	cd asl || die "cd asl failed"
	make || die "make in asl failed"
	cd ../bin
	./aapitsrun || die "aapitsrun failed"
}