[gentoo-commits] repo/gentoo:master commit in: app-i18n/tomoe/

[Andreas Sturmlechner]

commit:     838214d13e6868434543459f6ebc30c087a14388
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 30 10:54:10 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Apr 30 18:18:57 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=838214d1

app-i18n/tomoe: Drop USE python

Bug: https://bugs.gentoo.org/695012
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-i18n/tomoe/tomoe-0.6.0-r6.ebuild | 78 ++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/app-i18n/tomoe/tomoe-0.6.0-r6.ebuild b/app-i18n/tomoe/tomoe-0.6.0-r6.ebuild
new file mode 100644
index 00000000000..4be2663f575
--- /dev/null
+++ b/app-i18n/tomoe/tomoe-0.6.0-r6.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+USE_RUBY="ruby25 ruby26 ruby27"
+inherit autotools ruby-utils
+
+DESCRIPTION="Japanese handwriting recognition engine"
+HOMEPAGE="http://tomoe.osdn.jp/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="hyperestraier mysql ruby ${USE_RUBY//ruby/ruby_targets_ruby} static-libs subversion"
+REQUIRED_USE="ruby? ( ^^ ( ${USE_RUBY//ruby/ruby_targets_ruby} ) )"
+
+RESTRICT="test"
+
+RDEPEND="dev-libs/glib:2
+	hyperestraier? ( app-text/hyperestraier )
+	mysql? ( dev-db/mysql-connector-c:= )
+	ruby? (
+		$(for ruby in ${USE_RUBY}; do
+			echo "ruby_targets_${ruby}? (
+				$(_ruby_implementation_depend "${ruby}")
+				dev-ruby/ruby-glib2[ruby_targets_${ruby}]
+			)"
+		done)
+	)
+	subversion? ( dev-vcs/subversion )"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-gentoo.patch
+	"${FILESDIR}"/${PN}-export-symbols.patch
+	"${FILESDIR}"/${PN}-glib-2.32.patch
+	"${FILESDIR}"/${PN}-ruby19.patch
+)
+
+src_prepare() {
+	sed -i \
+		-e "s/use_est=yes/use_est=$(usex hyperestraier)/" \
+		-e "s/use_mysql=yes/use_mysql=$(usex mysql)/" \
+		configure.ac
+
+	sed -i "s/use_svn=yes/use_svn=$(usex subversion)/" macros/svn.m4
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local ruby
+	for ruby in ${USE_RUBY}; do
+		if use ruby_targets_${ruby}; then
+			break
+		fi
+	done
+
+	econf \
+		$(use_enable ruby dict-ruby) \
+		$(use_enable static-libs static) \
+		--without-python \
+		$(use_with ruby ruby "$(type -P ${ruby})") \
+		--with-svn-include="${EPREFIX}"/usr/include \
+		--with-svn-lib="${EPREFIX}"/usr/$(get_libdir)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}