[gentoo-commits] repo/gentoo:master commit in: dev-ruby/sass/

[Hans de Graaff]

commit:     337b294addf6cb6e3dff57f9c5ce845a4f18f12b
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 26 09:54:10 2022 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sat Mar 26 14:29:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=337b294a

dev-ruby/sass: add ruby30; EAPI 8

Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/sass/sass-3.7.4-r1.ebuild | 46 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-ruby/sass/sass-3.7.4-r1.ebuild b/dev-ruby/sass/sass-3.7.4-r1.ebuild
new file mode 100644
index 000000000000..cbc5c9d39c72
--- /dev/null
+++ b/dev-ruby/sass/sass-3.7.4-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="rails init.rb VERSION VERSION_NAME"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An extension of CSS3, adding nested rules, variables, mixins, and more"
+HOMEPAGE="https://sass-lang.com/"
+SRC_URI="https://github.com/sass/ruby-sass/archive/${PV}.tar.gz -> ${P}.tar.gz"
+RUBY_S="ruby-sass-${PV}"
+
+LICENSE="MIT"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux"
+SLOT="$(ver_cut 1-2)"
+IUSE=""
+
+ruby_add_bdepend "doc? ( >=dev-ruby/yard-0.5.3 )"
+
+ruby_add_rdepend "
+	!!<dev-ruby/sass-3.4.25-r1:3.4
+	!!<dev-ruby/sass-3.5.7-r1:3.5
+	dev-ruby/sass-listen:4"
+
+# tests could use `less` if we had it
+
+all_ruby_prepare() {
+	# Don't require maruku as markdown provider but let yard decide.
+	sed -i -e '/maruku/d' .yardopts || die
+
+	# Keep VERSION_DATE around since we don't create a new package
+	sed -i -e '/at_exit/,/end/ s:^:#:' Rakefile || die
+}
+
+each_ruby_test() {
+	RUBOCOP=false ${RUBY} -S rake test:ruby || die
+}