[gentoo-commits] gentoo-x86 commit in media-libs/tiff: tiff-3.9.5-r2.ebuild ChangeLog tiff-4.0.1-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/04/06 17:39:21

  Modified:             ChangeLog
  Added:                tiff-3.9.5-r2.ebuild tiff-4.0.1-r1.ebuild
  Log:
  Upstream patch for CVE-2012-1173 wrt #410931 by Agostino Sarubbo
  
  (Portage version: 2.2.0_alpha99/cvs/Linux x86_64)

Revision  Changes    Path
1.186                media-libs/tiff/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/ChangeLog?rev=1.186&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/ChangeLog?rev=1.186&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/ChangeLog?r1=1.185&r2=1.186

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/tiff/ChangeLog,v
retrieving revision 1.185
retrieving revision 1.186
diff -u -r1.185 -r1.186
--- ChangeLog	2 Mar 2012 17:21:27 -0000	1.185
+++ ChangeLog	6 Apr 2012 17:39:21 -0000	1.186
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/tiff
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/ChangeLog,v 1.185 2012/03/02 17:21:27 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/ChangeLog,v 1.186 2012/04/06 17:39:21 ssuominen Exp $
+
+*tiff-4.0.1-r1 (06 Apr 2012)
+*tiff-3.9.5-r2 (06 Apr 2012)
+
+  06 Apr 2012; Samuli Suominen <ssuominen@g.o> +tiff-3.9.5-r2.ebuild,
+  +files/tiff-3.9.5-CVE-2012-1173.patch, +tiff-4.0.1-r1.ebuild,
+  +files/tiff-4.0.1-CVE-2012-1173.patch:
+  Upstream patch for CVE-2012-1173 wrt #410931 by Agostino Sarubbo
 
 *tiff-4.0.1 (02 Mar 2012)
 



1.1                  media-libs/tiff/tiff-3.9.5-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/tiff-3.9.5-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/tiff-3.9.5-r2.ebuild?rev=1.1&content-type=text/plain

Index: tiff-3.9.5-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/tiff-3.9.5-r2.ebuild,v 1.1 2012/04/06 17:39:21 ssuominen Exp $

# this ebuild is only for the libtiff.so.3 and libtiffxx.so.3 SONAME for ABI compat

EAPI=4
inherit eutils libtool multilib

DESCRIPTION="Library for manipulation of TIFF (Tag Image File Format) images"
HOMEPAGE="http://www.remotesensing.org/libtiff/"
SRC_URI="ftp://ftp.remotesensing.org/pub/libtiff/${P}.tar.gz"

LICENSE="as-is"
SLOT="3"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+cxx jbig jpeg zlib"

RDEPEND="jpeg? ( virtual/jpeg )
	jbig? ( media-libs/jbigkit )
	zlib? ( sys-libs/zlib )
	!media-libs/tiff-compat
	!=media-libs/tiff-3*:0"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-CVE-*.patch
	elibtoolize
}

src_configure() {
	econf \
		--libdir=/libdir \
		--disable-static \
		$(use_enable cxx) \
		$(use_enable zlib) \
		$(use_enable jpeg) \
		$(use_enable jbig) \
		--without-x
}

src_install() {
	# Let `make install` and libtool handle insecure runpath(s)
	dodir tmp
	emake DESTDIR="${D}/tmp" install

	exeinto /usr/$(get_libdir)
	doexe "${ED}"/tmp/libdir/libtiff$(get_libname 3)
	use cxx && doexe "${ED}"/tmp/libdir/libtiffxx$(get_libname 3)

	rm -rf "${ED}"/tmp
}



1.1                  media-libs/tiff/tiff-4.0.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/tiff-4.0.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/tiff/tiff-4.0.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: tiff-4.0.1-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/tiff-4.0.1-r1.ebuild,v 1.1 2012/04/06 17:39:21 ssuominen Exp $

EAPI=4
inherit eutils libtool

DESCRIPTION="Tag Image File Format (TIFF) library"
HOMEPAGE="http://www.remotesensing.org/libtiff/"
SRC_URI="http://download.osgeo.org/libtiff/${P}.tar.gz
	ftp://ftp.remotesensing.org/pub/libtiff/${P}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+cxx jbig jpeg lzma static-libs zlib"

RDEPEND="jpeg? ( virtual/jpeg )
	jbig? ( media-libs/jbigkit )
	lzma? ( app-arch/xz-utils )
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-CVE-*.patch
	elibtoolize
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(use_enable zlib) \
		$(use_enable jpeg) \
		$(use_enable jbig) \
		$(use_enable lzma) \
		$(use_enable cxx) \
		--without-x \
		--with-docdir="${EPREFIX}"/usr/share/doc/${PF}
}

src_install() {
	default

	rm -f \
		"${ED}"/usr/lib*/libtiff*.la \
		"${ED}"/usr/share/doc/${PF}/{COPYRIGHT,README*,RELEASE-DATE,TODO,VERSION}
}