[gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-modules: metadata.xml ChangeLog virtualbox-modules-3.2.2.ebuild virtualbox-modules-3.1.6.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    10/06/03 10:55:47

  Modified:             metadata.xml ChangeLog
  Added:                virtualbox-modules-3.2.2.ebuild
  Removed:              virtualbox-modules-3.1.6.ebuild
  Log:
  Version bump. Removed old.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  app-emulation/virtualbox-modules/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	28 Jan 2010 11:58:23 -0000	1.2
+++ metadata.xml	3 Jun 2010 10:55:47 -0000	1.3
@@ -10,4 +10,8 @@
   <email>swapon@×××××.com</email>
   <name>Alessio Cassibba</name>
 </maintainer>
+  <maintainer>
+    <email>polynomial-c@g.o</email>
+    <name>Lars Wendler</name>
+  </maintainer>
 </pkgmetadata>



1.62                 app-emulation/virtualbox-modules/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	20 May 2010 12:58:17 -0000	1.61
+++ ChangeLog	3 Jun 2010 10:55:47 -0000	1.62
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/virtualbox-modules
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.61 2010/05/20 12:58:17 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/ChangeLog,v 1.62 2010/06/03 10:55:47 polynomial-c Exp $
+
+*virtualbox-modules-3.2.2 (03 Jun 2010)
+
+  03 Jun 2010; Lars Wendler <polynomial-c@g.o>
+  -virtualbox-modules-3.1.6.ebuild, +virtualbox-modules-3.2.2.ebuild,
+  metadata.xml:
+  Version bump. Removed old.
 
 *virtualbox-modules-3.2.0 (20 May 2010)
 



1.1                  app-emulation/virtualbox-modules/virtualbox-modules-3.2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-3.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-3.2.2.ebuild?rev=1.1&content-type=text/plain

Index: virtualbox-modules-3.2.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-modules/virtualbox-modules-3.2.2.ebuild,v 1.1 2010/06/03 10:55:47 polynomial-c Exp $

# XXX: the tarball here is just the kernel modules split out of the binary
#      package that comes from virtualbox-bin

EAPI=2

inherit eutils linux-mod

MY_P=vbox-kernel-module-src-${PV}
DESCRIPTION="Kernel Modules for Virtualbox"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://dev.gentoo.org/~polynomial-c/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="!=app-emulation/virtualbox-ose-9999"

S=${WORKDIR}

BUILD_TARGETS="all"
BUILD_TARGET_ARCH="${ARCH}"
MODULE_NAMES="vboxdrv(misc:${S}) vboxnetflt(misc:${S}) vboxnetadp(misc:${S})"

pkg_setup() {
	linux-mod_pkg_setup
	BUILD_PARAMS="KERN_DIR=${KV_DIR} KERNOUT=${KV_OUT_DIR}"
	enewgroup vboxusers
}

src_prepare() {
	if kernel_is -ge 2 6 33 ; then
		# evil patch for new kernels - header moved
		grep -lR linux/autoconf.h *  | xargs sed -i -e 's:<linux/autoconf.h>:<generated/autoconf.h>:'
	fi
}

src_install() {
	linux-mod_src_install

	# udev rule for vboxdrv
	dodir /etc/udev/rules.d
	echo '#SUBSYSTEM=="usb_device", GROUP="vboxusers", MODE="0644"' \
	> "${D}/etc/udev/rules.d/10-virtualbox.rules"
	echo '#SUBSYSTEM=="usb", ENV{DEVTYPE}=="usb_device", GROUP="vboxusers", MODE="0644"' \
	>> "${D}/etc/udev/rules.d/10-virtualbox.rules"
}

pkg_postinst() {
	linux-mod_pkg_postinst
	elog "Starting with the 3.x release new kernel modules were added,"
	elog "be sure to load all the needed modules."
	elog ""
	elog "Please add \"vboxdrv\", \"vboxnetflt\" and \"vboxnetadp\" to:"
	if has_version sys-apps/openrc; then
		elog "/etc/conf.d/modules"
	else
		elog "/etc/modules.autoload.d/kernel-${KV_MAJOR}.${KV_MINOR}"
	fi
	elog ""
	elog "If you are experiencing problems on your guests"
	elog "with USB support and app-emulation/virtualbox-bin,"
	elog "uncomment the udev rules placed in:"
	elog ""
	elog "/etc/udev/rules.d/10-virtualbox.rules"
	elog ""
}