[gentoo-commits] gentoo-x86 commit in app-office/texmacs: ChangeLog texmacs-1.0.7.11.ebuild texmacs-1.0.7.2.ebuild

[Andrey Grozin (grozin)]

grozin      11/09/07 12:57:21

  Modified:             ChangeLog
  Added:                texmacs-1.0.7.11.ebuild
  Removed:              texmacs-1.0.7.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha54/cvs/Linux i686)

Revision  Changes    Path
1.96                 app-office/texmacs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	2 Apr 2011 15:46:11 -0000	1.95
+++ ChangeLog	7 Sep 2011 12:57:21 -0000	1.96
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/texmacs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v 1.95 2011/04/02 15:46:11 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v 1.96 2011/09/07 12:57:21 grozin Exp $
+
+*texmacs-1.0.7.11 (07 Sep 2011)
+
+  07 Sep 2011; Andrey Grozin <grozin@g.o> -texmacs-1.0.7.2.ebuild,
+  +texmacs-1.0.7.11.ebuild:
+  Version bump
 
   02 Apr 2011; Raúl Porcel <armin76@g.o> texmacs-1.0.7.2-r1.ebuild:
   alpha/sparc stable wrt #337532



1.1                  app-office/texmacs/texmacs-1.0.7.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/texmacs-1.0.7.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmacs/texmacs-1.0.7.11.ebuild?rev=1.1&content-type=text/plain

Index: texmacs-1.0.7.11.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/texmacs-1.0.7.11.ebuild,v 1.1 2011/09/07 12:57:21 grozin Exp $
EAPI=2
inherit autotools
MY_P=${P/tex/TeX}-src

DESCRIPTION="Wysiwyg text processor with high-quality maths"
HOMEPAGE="http://www.texmacs.org/"
SRC_URI="
	ftp://ftp.texmacs.org/pub/TeXmacs/targz/${MY_P}.tar.gz
	ftp://ftp.texmacs.org/pub/TeXmacs/targz/TeXmacs-600dpi-fonts.tar.gz"

LICENSE="GPL-3"
SLOT="0"
IUSE="imlib jpeg netpbm qt4 svg spell"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-interix ~amd64-linux ~x86-linux"

RDEPEND="dev-scheme/guile[deprecated]
	virtual/latex-base
	app-text/ghostscript-gpl
	media-libs/freetype
	x11-libs/libXext
	x11-apps/xmodmap
	qt4? ( x11-libs/qt-gui:4 )
	imlib? ( media-libs/imlib2 )
	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
	netpbm? ( media-libs/netpbm )
	spell? ( || ( >=app-text/ispell-3.2 >=app-text/aspell-0.5 ) )"
DEPEND="${RDEPEND}
	x11-proto/xproto"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# don't strip
	epatch "${FILESDIR}"/${PN}-strip.patch

	# respect LDFLAGS, bug #338459
	epatch "${FILESDIR}"/${PN}-ldflags.patch

	# fix LD_LIBRARY_PATH in tm_mupad_help, bug #337532
	epatch "${FILESDIR}"/${PN}-mupad.patch

	eautoreconf
}

src_configure() {
	econf $(use_with imlib imlib2) \
		--enable-optimize="${CXXFLAGS}" \
		$(use_enable qt4 qt)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc TODO || die "dodoc failed"
	domenu "${FILESDIR}"/TeXmacs.desktop || die "domenu failed"

	# now install the fonts
	insinto /usr/share/texmf
	doins -r "${WORKDIR}/fonts" || die "installing fonts failed"
}