[gentoo-commits] proj/gnome:master commit in: gnome-base/gvfs/

[Mart Raudsepp]

commit:     08d01538d99083c12b31d6a7fedd29130c45f0db
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 14 08:18:38 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Sep 14 08:18:38 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=08d01538

gnome-base/gvfs: remove, available with elogind support in ::gentoo

This version here lost the elogind and daemon deadlock fix patches, main
tree now has them (in a revbump as a courtesy to overlay users due to the
deadlock patch).
Also remove 9999 for now, as it's hopelessly outdated and not useful as
a base to update from.

 gnome-base/gvfs/gvfs-1.34.2.1.ebuild | 127 --------------------------------
 gnome-base/gvfs/gvfs-9999.ebuild     | 137 -----------------------------------
 gnome-base/gvfs/metadata.xml         |  27 -------
 3 files changed, 291 deletions(-)

diff --git a/gnome-base/gvfs/gvfs-1.34.2.1.ebuild b/gnome-base/gvfs/gvfs-1.34.2.1.ebuild
deleted file mode 100644
index 369ef3ff..00000000
--- a/gnome-base/gvfs/gvfs-1.34.2.1.ebuild
+++ /dev/null
@@ -1,127 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-GNOME2_LA_PUNT="yes"
-GNOME2_EAUTORECONF="yes"
-
-inherit gnome2 systemd
-
-DESCRIPTION="Virtual filesystem implementation for gio"
-HOMEPAGE="https://wiki.gnome.org/Projects/gvfs"
-
-LICENSE="LGPL-2+"
-SLOT="0"
-
-IUSE="afp archive bluray cdda elogind fuse google gnome-keyring gnome-online-accounts gphoto2 +http ios mtp nfs policykit samba systemd test +udev udisks zeroconf"
-REQUIRED_USE="
-	cdda? ( udev )
-	elogind? ( !systemd udisks )
-	google? ( gnome-online-accounts )
-	mtp? ( udev )
-	udisks? ( udev )
-	systemd? ( !elogind udisks )
-"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
-
-RDEPEND="
-	app-crypt/gcr:=
-	>=dev-libs/glib-2.51:2
-	dev-libs/libxml2:2
-	net-misc/openssh
-	afp? ( >=dev-libs/libgcrypt-1.2.2:0= )
-	archive? ( app-arch/libarchive:= )
-	bluray? ( media-libs/libbluray:= )
-	elogind? ( >=sys-auth/elogind-229:0= )
-	fuse? ( >=sys-fs/fuse-2.8.0:0 )
-	gnome-keyring? ( app-crypt/libsecret )
-	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1:= )
-	google? (
-		>=dev-libs/libgdata-0.17.9:=[crypt,gnome-online-accounts]
-		>=net-libs/gnome-online-accounts-3.17.1:= )
-	gphoto2? ( >=media-libs/libgphoto2-2.5.0:= )
-	http? ( >=net-libs/libsoup-2.42:2.4 )
-	ios? (
-		>=app-pda/libimobiledevice-1.2:=
-		>=app-pda/libplist-1:= )
-	mtp? (
-		>=dev-libs/libusb-1.0.21
-		>=media-libs/libmtp-1.1.12 )
-	nfs? ( >=net-fs/libnfs-1.9.8 )
-	policykit? (
-		sys-auth/polkit
-		sys-libs/libcap )
-	samba? ( >=net-fs/samba-4[client] )
-	systemd? ( >=sys-apps/systemd-206:0= )
-	udev? (
-		cdda? ( dev-libs/libcdio-paranoia )
-		>=virtual/libgudev-147:=
-		virtual/libudev:= )
-	udisks? ( >=sys-fs/udisks-1.97:2 )
-	zeroconf? ( >=net-dns/avahi-0.6 )
-"
-DEPEND="${RDEPEND}
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
-	>=sys-devel/gettext-0.19.4
-	virtual/pkgconfig
-	dev-util/gdbus-codegen
-	dev-util/gtk-doc-am
-	test? (
-		>=dev-python/twisted-16
-		|| (
-			net-analyzer/netcat
-			net-analyzer/netcat6 ) )
-	!udev? ( >=dev-libs/libgcrypt-1.2.2:0 )
-"
-# libgcrypt.m4, provided by libgcrypt, needed for eautoreconf, bug #399043
-# test dependencies needed per https://bugzilla.gnome.org/700162
-
-# FIXME
-# Tests with multiple failures, this is being handled upstream at:
-# https://bugzilla.gnome.org/700162
-RESTRICT="test"
-
-src_prepare() {
-	if ! use udev; then
-		sed -e 's/gvfsd-burn/ /' \
-			-e 's/burn.mount.in/ /' \
-			-e 's/burn.mount/ /' \
-			-i daemon/Makefile.am || die
-	fi
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# --enable-documentation installs man pages
-	# --disable-obexftp, upstream bug #729945
-	gnome2_src_configure \
-		--disable-gdu \
-		--enable-documentation \
-		--enable-gcr \
-		--with-dbus-service-dir="${EPREFIX}"/usr/share/dbus-1/services \
-		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
-		$(use_enable afp) \
-		$(use_enable archive) \
-		$(use_enable bluray) \
-		$(use_enable cdda) \
-		$(use_enable elogind libelogind) \
-		$(use_enable fuse) \
-		$(use_enable gnome-keyring keyring) \
-		$(use_enable gnome-online-accounts goa) \
-		$(use_enable google) \
-		$(use_enable gphoto2) \
-		$(use_enable http) \
-		$(use_enable ios afc) \
-		$(use_enable mtp libmtp) \
-		$(use_enable mtp libusb) \
-		$(use_enable nfs) \
-		$(use_enable policykit admin) \
-		$(use_enable samba) \
-		$(use_enable systemd libsystemd-login) \
-		$(use_enable udev gudev) \
-		$(use_enable udev) \
-		$(use_enable udisks udisks2) \
-		$(use_enable zeroconf avahi)
-}

diff --git a/gnome-base/gvfs/gvfs-9999.ebuild b/gnome-base/gvfs/gvfs-9999.ebuild
deleted file mode 100644
index 7616302e..00000000
--- a/gnome-base/gvfs/gvfs-9999.ebuild
+++ /dev/null
@@ -1,137 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="5"
-GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
-
-inherit autotools bash-completion-r1 eutils gnome2
-if [[ ${PV} = 9999 ]]; then
-	inherit gnome2-live
-fi
-
-DESCRIPTION="Virtual filesystem implementation for gio"
-HOMEPAGE="https://git.gnome.org/browse/gvfs"
-
-LICENSE="LGPL-2+"
-SLOT="0"
-
-IUSE="afp archive bluray cdda fuse +gcr gnome-online-accounts google gphoto2 gtk +http ios libsecret mtp nfs samba systemd test +udev udisks zeroconf"
-REQUIRED_USE="
-	cdda? ( udev )
-	mtp? ( udev )
-	udisks? ( udev )
-	systemd? ( udisks )
-"
-
-if [[ ${PV} = 9999 ]]; then
-	KEYWORDS=""
-	DOCS=""
-	IUSE="${IUSE} doc"
-else
-	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
-fi
-
-# Can use libgphoto-2.5.0 as well. Automagic detection.
-RDEPEND="
-	>=dev-libs/glib-2.45.7:2
-	sys-apps/dbus
-	dev-libs/libxml2:2
-	net-misc/openssh
-	afp? ( >=dev-libs/libgcrypt-1.2.2:0= )
-	archive? ( app-arch/libarchive:= )
-	bluray? ( media-libs/libbluray )
-	fuse? ( >=sys-fs/fuse-2.8.0 )
-	gcr? ( app-crypt/gcr )
-	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1 )
-	google? (
-		>=net-libs/gnome-online-accounts-3.17.1
-		dev-libs/libgdata
-	)
-	gphoto2? ( >=media-libs/libgphoto2-2.4.7:= )
-	gtk? ( >=x11-libs/gtk+-3.0:3 )
-	http? ( >=net-libs/libsoup-2.42:2.4 )
-	ios? (
-		>=app-pda/libimobiledevice-1.1.5:=
-		>=app-pda/libplist-1:= )
-	libsecret? ( app-crypt/libsecret )
-	mtp? ( >=media-libs/libmtp-1.1.6 )
-	nfs? ( >=net-fs/libnfs-1.9.7 )
-	samba? ( || ( >=net-fs/samba-3.4.6[smbclient] >=net-fs/samba-4[client] ) )
-	systemd? ( sys-apps/systemd:0= )
-	udev? (
-		cdda? ( dev-libs/libcdio-paranoia )
-		virtual/libgudev:=
-		virtual/libudev:= )
-	udisks? ( >=sys-fs/udisks-1.97:2 )
-	zeroconf? ( >=net-dns/avahi-0.6 )
-"
-DEPEND="${RDEPEND}
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
-	>=dev-util/intltool-0.40
-	virtual/pkgconfig
-	dev-util/gdbus-codegen
-	dev-util/gtk-doc-am
-	test? (
-		>=dev-python/twisted-core-12.3.0
-		|| (
-			net-analyzer/netcat
-			net-analyzer/netcat6 ) )
-	!udev? ( >=dev-libs/libgcrypt-1.2.2:0 )
-"
-# libgcrypt.m4, provided by libgcrypt, needed for eautoreconf, bug #399043
-# test dependencies needed per https://bugzilla.gnome.org/700162
-
-if [[ ${PV} = 9999 ]]; then
-	DEPEND="${DEPEND}
-		doc? ( >=dev-util/gtk-doc-1 )"
-fi
-
-src_prepare() {
-	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README TODO" # ChangeLog.pre-1.2 README.commits
-
-	if ! use udev; then
-		sed -e 's/gvfsd-burn/ /' \
-			-e 's/burn.mount.in/ /' \
-			-e 's/burn.mount/ /' \
-			-i daemon/Makefile.am || die
-
-		[[ ${PV} = 9999 ]] || eautoreconf
-	fi
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# --enable-documentation installs man pages
-	# --disable-obexftp, upstream bug #729945
-	gnome2_src_configure \
-		--enable-bash-completion \
-		--with-bash-completion-dir="$(get_bashcompdir)" \
-		--disable-gdu \
-		--disable-hal \
-		--with-dbus-service-dir="${EPREFIX}"/usr/share/dbus-1/services \
-		--enable-documentation \
-		$(use_enable afp) \
-		$(use_enable archive) \
-		$(use_enable bluray) \
-		$(use_enable cdda) \
-		$(use_enable fuse) \
-		$(use_enable gcr gcr) \
-		$(use_enable gnome-online-accounts goa) \
-		$(use_enable google google) \
-		$(use_enable gphoto2) \
-		$(use_enable gtk) \
-		$(use_enable ios afc) \
-		$(use_enable mtp libmtp) \
-		$(use_enable nfs) \
-		$(use_enable udev) \
-		$(use_enable udev gudev) \
-		$(use_enable http) \
-		$(use_enable libsecret keyring) \
-		$(use_enable samba) \
-		$(use_enable systemd libsystemd-login) \
-		$(use_enable udisks udisks2) \
-		$(use_enable zeroconf avahi)
-}

diff --git a/gnome-base/gvfs/metadata.xml b/gnome-base/gvfs/metadata.xml
deleted file mode 100644
index d26195bc..00000000
--- a/gnome-base/gvfs/metadata.xml
+++ /dev/null
@@ -1,27 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-<maintainer type="project">
-	<email>gnome@g.o</email>
-	<name>Gentoo GNOME Desktop</name>
-</maintainer>
-<longdescription lang="en">
-gvfs is a userspace virtual filesystem designed to work with the i/o
-abstractions of gio (a library availible in glib &gt;= 2.15.1). It
-installs several modules that are automatically used by applications
-using the APIs of libgio. There is also fuse support that allows
-applications not using gio to access the gvfs filesystems.
-</longdescription>
-<use>
-	<flag name="afp">Enables support for accessing AFP (Apple Filing Protocol) network shares</flag>
-	<flag name="archive">Enables support for accessing files in archives transparently via <pkg>app-arch/libarchive</pkg></flag>
-	<flag name="bluray">Enable playback of Blu-ray filesystems using <pkg>media-libs/libbluray</pkg></flag>
-	<flag name="elogind">Use <pkg>sys-auth/elogind</pkg> for session tracking.</flag>
-	<flag name="fuse">Enables fuse mount points in $HOME/.gvfs for legacy application access</flag>
-	<flag name="gnome-online-accounts">Enable configuration panel for <pkg>net-libs/gnome-online-accounts</pkg> accounts</flag>
-	<flag name="google">Enables support for accessing Google accounts via <pkg>dev-libs/libgdata</pkg></flag>
-	<flag name="http">Enable the HTTP/DAV backend using <pkg>net-libs/libsoup</pkg></flag>
-	<flag name="nfs">Enable NFS client support via <pkg>net-fs/libnfs</pkg>.</flag>
-	<flag name="udev">Enable udev base replacement code for cdda feature</flag>
-</use>
-</pkgmetadata>