[gentoo-commits] repo/gentoo:master commit in: dev-libs/xmlsec/

[Sam James]

commit:     67d5efe5f3650878f52fc1ab593ec9f170bec774
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 31 01:54:50 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Dec 31 02:00:01 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67d5efe5

dev-libs/xmlsec: bump to 1.2.31

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/xmlsec/Manifest             |  1 +
 dev-libs/xmlsec/xmlsec-1.2.31.ebuild | 60 ++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/xmlsec/Manifest b/dev-libs/xmlsec/Manifest
index 939cd9fd1f5..7f5e8c5f173 100644
--- a/dev-libs/xmlsec/Manifest
+++ b/dev-libs/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST xmlsec1-1.2.30.tar.gz 1989670 BLAKE2B b363d1661ba5fdf968725948598954c7d514ad92c4ad05b490aa3ac9ffb6be861ee81d660be30d37e26ae1cb327cdecd1c76d60055ec5aa900e390a4083099b3 SHA512 07152470a9fe5d077f8a358608ca1d8a79ee0d2777660f61ed5717dc640714a3adfe66843e6a4023898eb0f5ed79771d70c41132571f3a1aeda82c1894b69c98
+DIST xmlsec1-1.2.31.tar.gz 1989144 BLAKE2B ddc55e34867d5870fa434c739825ceaa68500a11fb2eabb482945901ad7fa0ba0d5fce7cd6c5f1b49c24d5bc07cee2875ff21833f09c0ec2ffeaf63875f5b001 SHA512 7a0e3d6f66746a22cf6468eb4d0691879c7468e4bef71fd8720e6a56b420f076a1d8a3094c35e721471dd029a643f5c4a553ef5788be5509f2786a419da1b7af

diff --git a/dev-libs/xmlsec/xmlsec-1.2.31.ebuild b/dev-libs/xmlsec/xmlsec-1.2.31.ebuild
new file mode 100644
index 00000000000..2da2a8e15d6
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.31.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="https://www.aleksey.com/xmlsec"
+SRC_URI="https://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+S="${WORKDIR}/${PN}1-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gcrypt gnutls libressl nss +openssl static-libs test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+	gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4:=
+	>=dev-libs/libxslt-1.0.20:=
+	gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0= )
+	gnutls? ( >=net-libs/gnutls-2.8.0:= )
+	nss? (
+		>=dev-libs/nspr-4.4.1:=
+		>=dev-libs/nss-3.9:=
+	)
+	openssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	test? (
+		nss? (
+			>=dev-libs/nss-3.9[utils]
+		)
+	)"
+
+src_configure() {
+	# Bash because of bug #721128
+	CONFIG_SHELL=${BASH} econf \
+		$(use_enable doc docs) \
+		$(use_enable static-libs static) \
+		$(use_with gcrypt) \
+		$(use_with gnutls) \
+		$(use_with nss nspr) \
+		$(use_with nss) \
+		$(use_with openssl) \
+		--enable-mans \
+		--enable-pkgconfig
+}
+
+src_test() {
+	SHELL=${BASH} emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}