[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-power-manager: ChangeLog gnome-power-manager-2.20.0-r1.ebuild

[Mart Raudsepp (leio)]

leio        07/11/09 08:12:21

  Modified:             ChangeLog
  Added:                gnome-power-manager-2.20.0-r1.ebuild
  Log:
  Fix icon appearing problems, bug 188618. Many thanks to Shogun for pinpointing the problematic codepath - disabled the problematic codepath and I made a patch for the upstream bug that should fix it proper, but as the codepath is not much tested not using here
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.64                 gnome-extra/gnome-power-manager/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	2 Oct 2007 16:41:23 -0000	1.63
+++ ChangeLog	9 Nov 2007 08:12:20 -0000	1.64
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/gnome-power-manager
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.63 2007/10/02 16:41:23 compnerd Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.64 2007/11/09 08:12:20 leio Exp $
+
+*gnome-power-manager-2.20.0-r1 (09 Nov 2007)
+
+  09 Nov 2007; Mart Raudsepp <leio@g.o>
+  +gnome-power-manager-2.20.0-r1.ebuild:
+  Fix icon appearing problems, bug 188618. Many thanks to Shogun for
+  pinpointing the problematic codepath
 
 *gnome-power-manager-2.20.0 (02 Oct 2007)
 



1.1                  gnome-extra/gnome-power-manager/gnome-power-manager-2.20.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.20.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.20.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-power-manager-2.20.0-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.20.0-r1.ebuild,v 1.1 2007/11/09 08:12:20 leio Exp $

inherit gnome2 eutils virtualx

DESCRIPTION="Gnome Power Manager"
HOMEPAGE="http://www.gnome.org/projects/gnome-power-manager/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="doc"

RDEPEND=">=dev-libs/glib-2.6.0
		 >=x11-libs/gtk+-2.11.0
		 >=gnome-base/gnome-keyring-0.6.0
		 >=gnome-base/libgnome-2.14.0
		 >=gnome-base/libgnomeui-2.14.0
		 >=sys-apps/hal-0.5.8
		 >=dev-libs/dbus-glib-0.71
		 >=gnome-base/libglade-2.5.0
		 >=x11-libs/libnotify-0.4.3
		 >=x11-libs/libwnck-2.10.0
		 >=x11-libs/cairo-1.0.0
		 >=gnome-base/gnome-panel-2
		 >=gnome-base/gconf-2
		  =media-libs/gstreamer-0.10*
		   x11-libs/libX11
		   x11-libs/libXext"
DEPEND="${RDEPEND}
		  sys-devel/gettext
		 ~app-text/docbook-xml-dtd-4.3
		>=dev-util/pkgconfig-0.9
		>=dev-util/intltool-0.35
		>=app-text/gnome-doc-utils-0.3.2
		doc?	(
					 app-text/xmlto
					 app-text/docbook-sgml-utils
					~app-text/docbook-xml-dtd-4.4
					~app-text/docbook-sgml-dtd-4.1
					~app-text/docbook-xml-dtd-4.1.2
				)"

# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
# (files under ${S}/man).
# docbook-xml-dtd-4.4 and -4.1.2 are used by the xml files under ${S}/docs.

DOCS="AUTHORS ChangeLog NEWS README TODO"

pkg_setup() {
	# TODO :: policykit should have a pam useflag

	# xevents are disabled only because it only breaks the icon from appearing, and nothing else in version 2.20.0 and older 
	# Reconsider on bump after there is upstream opinion on http://bugzilla.gnome.org/show_bug.cgi?id=413360#c41 (bump might include the necessary patch too)
	G2CONF="$(use_enable doc docbook-docs) \
			--enable-actions-menu --with-dpms-ext --disable-policykit \
			--disable-xevents --enable-applets --enable-keyring"
}

src_unpack() {
	gnome2_src_unpack

	if use doc; then
		# Actually install all html files, not just the index
		sed -i -e 's:\(htmldoc_DATA = \).*:\1$(SPEC_HTML_FILES):' \
			"${S}/docs/Makefile.in"
	else
		# Remove the docbook2man rules here since it's not handled by a proper
		# parameter in configure.in.
		sed -i -e 's:@HAVE_DOCBOOK2MAN_TRUE@.*::' "${S}/man/Makefile.in"
	fi

	# glibc splits this out, whereas other libc's do not tend to
	use elibc_glibc || sed -i -e 's/-lresolv//' configure
}

src_test() {
	Xmake check || die "Test phase failed"
}

pkg_postinst() {
	gnome2_pkg_postinst

	if [[ $(portageq has_version / 'sys-libs/pam') ]] ; then
		einfo "You will need the masked pam_console to be able to"
		einfo "suspend/hibernate, or you will need to:"
		einfo "touch /var/run/console/<USERNAME>"
		einfo "after each boot"
	fi
}



-- 
gentoo-commits@g.o mailing list