[gentoo-commits] repo/gentoo:master commit in: media-libs/speex/

[Miroslav Šulc]

commit:     9ca1ee15663a0a1b92c9f34dc120cc2465fe4cbc
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 25 09:17:08 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 09:17:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ca1ee15

media-libs/speex: bump to 1.2.1, eapi8

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-libs/speex/Manifest           |  1 +
 media-libs/speex/speex-1.2.1.ebuild | 71 +++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/media-libs/speex/Manifest b/media-libs/speex/Manifest
index 2f4a54298789..ddba3d957b9c 100644
--- a/media-libs/speex/Manifest
+++ b/media-libs/speex/Manifest
@@ -1 +1,2 @@
 DIST speex-1.2.0.tar.gz 1047080 BLAKE2B 928e044e1195d4d977497cd1275a07323df233ee85e3ec188f362720f96303c2fc2002c1147c2ac93ca03570ff98428d983eb7d00439c9cdbe131041d9aa2697 SHA512 7fe10838c7d1bafcbe42295b82b79262420dba793b8a4388e2f73a3007850b5572face1b5308d9f4e8d7dfc9cb1c016cbad88cd65b2892667986107ed946836b
+DIST speex-1.2.1.tar.gz 1043278 BLAKE2B 60afa7eb9ff87ebb1b69e2716b7fa6727b49f6c06ed6eb6fe81236c65dc4128769618dd1f4df31af56a00e9b766c4050c1b3e415c8f972d64d1fb9e7a537a650 SHA512 52e00300df82e1c7fb527b245af02b99a1f37faef74d004b7cd981052f1aa22a412cb18f5c7a5618df4c958f727c97eb7385beec99d68548d5b02e76192d4e0a

diff --git a/media-libs/speex/speex-1.2.1.ebuild b/media-libs/speex/speex-1.2.1.ebuild
new file mode 100644
index 000000000000..c8a727c5743d
--- /dev/null
+++ b/media-libs/speex/speex-1.2.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic multilib-minimal
+
+MY_P=${P/_}
+MY_P=${MY_P/_p/.}
+
+DESCRIPTION="Audio compression format designed for speech"
+HOMEPAGE="https://www.speex.org/"
+SRC_URI="https://downloads.xiph.org/releases/speex/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="cpu_flags_arm_v4 cpu_flags_arm_v5 cpu_flags_arm_v6 cpu_flags_x86_sse utils +vbr"
+
+RDEPEND="
+	utils? (
+		media-libs/libogg:=
+		media-libs/speexdsp[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.2.0-configure.patch )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's:noinst_PROGRAMS:check_PROGRAMS:' \
+		libspeex/Makefile.am || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	append-lfs-flags
+
+	local FIXED_ARG="--disable-fixed-point"
+	local ARM4_ARG="--disable-arm4-asm"
+	local ARM5_ARG="--disable-arm5e-asm"
+
+	if use arm && ! use cpu_flags_arm_v6; then
+		FIXED_ARG="--enable-fixed-point"
+
+		if use cpu_flags_arm_v5; then
+			ARM5_ARG="--enable-arm5e-asm"
+		elif use cpu_flags_arm_v4; then
+			ARM4_ARG="--enable-arm4-asm"
+		fi
+	fi
+
+	ECONF_SOURCE="${S}" econf \
+		--disable-static \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable vbr) \
+		$(use_with utils speexdsp) \
+		$(use_enable utils binaries) \
+		${FIXED_ARG} ${ARM4_ARG} ${ARM5_ARG}
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -type f -delete || die
+}