[gentoo-commits] gentoo-x86 commit in dev-python/snakeoil: snakeoil-0.4.3.ebuild ChangeLog

[Brian Harring (ferringb)]

ferringb    11/09/28 03:54:22

  Modified:             ChangeLog
  Added:                snakeoil-0.4.3.ebuild
  Log:
  snakeoil 0.4.3
  
  (Portage version: 2.1.10.19/cvs/Linux x86_64)

Revision  Changes    Path
1.46                 dev-python/snakeoil/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/snakeoil/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/snakeoil/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/snakeoil/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/snakeoil/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	3 Sep 2011 08:12:05 -0000	1.45
+++ ChangeLog	28 Sep 2011 03:54:22 -0000	1.46
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/snakeoil
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/snakeoil/ChangeLog,v 1.45 2011/09/03 08:12:05 ferringb Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/snakeoil/ChangeLog,v 1.46 2011/09/28 03:54:22 ferringb Exp $
+
+*snakeoil-0.4.3 (28 Sep 2011)
+
+  28 Sep 2011; Brian Harring <ferringb@g.o> +snakeoil-0.4.3.ebuild:
+  parallelization work alongside bugfixes
 
 *snakeoil-0.4.2-r1 (03 Sep 2011)
 



1.1                  dev-python/snakeoil/snakeoil-0.4.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/snakeoil/snakeoil-0.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/snakeoil/snakeoil-0.4.3.ebuild?rev=1.1&content-type=text/plain

Index: snakeoil-0.4.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/snakeoil/snakeoil-0.4.3.ebuild,v 1.1 2011/09/28 03:54:22 ferringb Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

inherit distutils

DESCRIPTION="Miscellaneous python utility code."
HOMEPAGE="http://snakeoil.googlecode.com/"
SRC_URI="http://snakeoil.googlecode.com/files/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE=""

DEPEND="!<sys-apps/pkgcore-0.4.7.8"
RDEPEND=${DEPEND}

DOCS="AUTHORS NEWS"

pkg_setup() {
	# disable snakeoil 2to3 caching
	unset PY2TO3_CACHEDIR
	python_pkg_setup

	# A hack to install for all versions of Python in the system.
	# pkgcore needs it to support upgrading to a different Python slot.
	PYTHON_ABIS=""
	local python_interpreter
	for python_interpreter in /usr/bin/python{2.[4-9],3.[1-9]}; do
		if [[ -x "${python_interpreter}" ]]; then
			PYTHON_ABIS+=" ${python_interpreter#/usr/bin/python}"
		fi
	done
	export PYTHON_ABIS="${PYTHON_ABIS# }"
}

src_test() {
	testing() {
		local tempdir
		tempdir="${T}/tests/python-${PYTHON_ABI}"
		mkdir -p "${tempdir}" || die "tempdir creation failed"
		cp -r "${S}" "${tempdir}" || die "test copy failed"
		cd "${tempdir}/${P}"
		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib*)" "$(PYTHON)" setup.py build -b "build-${PYTHON_ABI}" test
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install
}