[gentoo-commits] repo/gentoo:master commit in: media-libs/libpng/

[Mike Gilbert]

commit:     165c7b9eb2611554ba69f46d889cbb2db15f6f87
Author:     David Michael <fedora.dm0 <AT> gmail <DOT> com>
AuthorDate: Fri Sep  4 21:24:21 2020 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Mon Sep  7 20:44:02 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=165c7b9e

media-libs/libpng: EAPI 7 and CPU_FLAGS_ARM

Closes: https://bugs.gentoo.org/694076
Closes: https://bugs.gentoo.org/740414
Package-Manager: Portage-3.0.4, Repoman-2.3.23
Signed-off-by: David Michael <fedora.dm0 <AT> gmail.com>
Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/17398

 media-libs/libpng/libpng-1.6.37-r1.ebuild | 44 +++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/media-libs/libpng/libpng-1.6.37-r1.ebuild b/media-libs/libpng/libpng-1.6.37-r1.ebuild
new file mode 100644
index 00000000000..c5ed306e8a8
--- /dev/null
+++ b/media-libs/libpng/libpng-1.6.37-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
+
+LICENSE="libpng2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng cpu_flags_arm_neon cpu_flags_x86_sse static-libs"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	if use apng; then
+		eapply -p0 "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable cpu_flags_x86_sse intel-sse)
+		$(use_enable static-libs static)
+		--enable-arm-neon=$(usex cpu_flags_arm_neon)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+	einstalldocs
+	find "${ED}" -name '*.la' -type f -delete || die
+}