[gentoo-commits] repo/gentoo:master commit in: media-sound/aqualung/

[Daniel Pielmeier]

commit:     5b17d5e27e9f5f208238e39e866cafa436603d03
Author:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 25 22:05:14 2020 +0000
Commit:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
CommitDate: Fri Sep 25 22:05:14 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b17d5e2

media-sound/aqualung: Version bump to aqualung-1.1.

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Daniel Pielmeier <billie <AT> gentoo.org>

 media-sound/aqualung/Manifest            |  1 +
 media-sound/aqualung/aqualung-1.1.ebuild | 92 ++++++++++++++++++++++++++++++++
 2 files changed, 93 insertions(+)

diff --git a/media-sound/aqualung/Manifest b/media-sound/aqualung/Manifest
index f9e22d06195..e2cdd8f4efc 100644
--- a/media-sound/aqualung/Manifest
+++ b/media-sound/aqualung/Manifest
@@ -1 +1,2 @@
 DIST aqualung-1.0.tar.gz 2014854 BLAKE2B bee5f8424f8a7f657e2adaacacd2b95f6d08153e2be54e3dd79e9097e7042bc9dfaae88df337c14e4bb8d0c2b2a0a5eef34aedf3c5756eb826dddff4b6cac9ad SHA512 d18fbc26c2f1445a0ef570216f54f1d00b05b25467b6ad857437e4ac628ac07c21435ce073cf92b3f147de4f1ada45a8a84770783d1c58e67451f94ac3de483a
+DIST aqualung-1.1.tar.gz 1986368 BLAKE2B 2dd367aefe55c1b9243bd5faee2e2d082825f1077326ad05cfe4c2b088ba2f055f5d9af7d14a032bac3603c8e333cffb53357a73e29f22f417e89ad91548eece SHA512 77f6350c1c6c9160da4c6280273812964d58e01227495a87e03e0bee0a2aaf5589d309b9ce7e08421845a357b35dbd08c5de5ecd495ae5ba7877a67d01e4ad01

diff --git a/media-sound/aqualung/aqualung-1.1.ebuild b/media-sound/aqualung/aqualung-1.1.ebuild
new file mode 100644
index 00000000000..ea7f3d62f5a
--- /dev/null
+++ b/media-sound/aqualung/aqualung-1.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg
+
+DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
+HOMEPAGE="http://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
+SRC_URI="https://github.com/jeremyevans/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate
+	lua mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
+	vorbis wavpack"
+
+BDEPEND="
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+RDEPEND="
+	app-arch/bzip2
+	dev-libs/libxml2
+	sys-libs/zlib
+	x11-libs/gtk+:2
+	alsa? ( media-libs/alsa-lib )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cddb? ( media-libs/libcddb )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( media-libs/flac )
+	ifp? ( media-libs/libifp )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lame? ( media-sound/lame )
+	libsamplerate? ( media-libs/libsamplerate )
+	lua? ( dev-lang/lua:0= )
+	mac? ( media-sound/mac )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
+	vorbis? ( media-libs/libvorbis media-libs/libogg )
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	econf \
+		--disable-rpath \
+		--enable-loop \
+		--enable-nls \
+		--enable-transcoding \
+		$(use_enable debug) \
+		$(use_enable podcast) \
+		$(use_enable systray) \
+		$(use_enable jack jack-mgmt) \
+		$(use_with alsa) \
+		$(use_with cdda) \
+		$(use_with cddb) \
+		$(use_with ffmpeg lavc) \
+		$(use_with flac) \
+		$(use_with ifp) \
+		$(use_with jack) \
+		$(use_with ladspa) \
+		$(use_with lame) \
+		$(use_with libsamplerate src) \
+		$(use_with lua) \
+		$(use_with mac) \
+		$(use_with modplug mod) \
+		$(use_with mp3 mpeg) \
+		$(use_with musepack mpc) \
+		$(use_with oss) \
+		$(use_with pulseaudio pulse) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with vorbis vorbis) \
+		$(use_with vorbis vorbisenc) \
+		$(use_with wavpack)
+}
+
+src_install() {
+	default
+
+	newicon src/img/icon_64.png aqualung.png
+	make_desktop_entry aqualung Aqualung
+}