[gentoo-commits] repo/gentoo:master commit in: dev-python/graph-tool/

[David Seifert]

commit:     a5fc806f817916d29ad0e2edc44718a52eb6513f
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 27 11:29:17 2016 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Tue Dec 27 11:46:17 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a5fc806f

dev-python/graph-tool: Version bump to 2.19

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 dev-python/graph-tool/Manifest               |  1 +
 dev-python/graph-tool/graph-tool-2.19.ebuild | 85 ++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index a2e253e..db40cc5 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1,2 +1,3 @@
 DIST graph-tool-2.16.tar.bz2 15116613 SHA256 3784d4a15b6b5d0e6dab5e3941d24c1e3fee509f7abf9008f64fef2760bd610d SHA512 336dddcd7a3faf56eff06a902f4cf5ac462bc4fd807566c473675eed665dba720e0b275b9233f73e657976e7ebdda75804eaa81ebf617dcde1beb299f45138e2 WHIRLPOOL 74b0ebc84c9a16b61182f296f93e366d09708fe0746c35a961173cfda259083ade97da2ecedbef4b9c19494aab621597c1f7863501d6a0e59c026aa197d39cb1
+DIST graph-tool-2.19.tar.bz2 15147961 SHA256 eba1090f94b0434890beedaf0c100dd0fc77e41ebfe29b4725d76cadb82099af SHA512 dc0bd93ccf21bb6616035dbfe33b0d9406eb894791e615795d486dc8f9d9991a6b93cf835cf4e59197005c14faedf105f3384cccd42db544104840cf857b2a84 WHIRLPOOL 3a398c98487a1e29952fea4c3ff8671e5aaf3d4f9e8df26aae9f6a856e61c290954f4c662e48ae424cbe0b916833a8f3bc7a6eefe6c6c3a08540de58ed6b9de0
 DIST graph-tool-2.2.44.tar.bz2 15044171 SHA256 42b97c24c155ddd95c79a16b4e3cb034cb3139e912c37aed66e6493e4ff20566 SHA512 312f3baf80a3c66d75f1ad458a2eb4b51300925beeac494e724e73589c06e93ce467a64da0cb26809b706cf69b398ab8ad1750d5e2b952f92b3bc00bd2e42467 WHIRLPOOL 79e04d4b4efb28bd99f45b64eb4297c408e35f1bdf78f6d756d52f44895cc9ae35f3c9c4450ca2a6f9232ebc0c4f57bc261495db7ec4ae2b542424a15777284d

diff --git a/dev-python/graph-tool/graph-tool-2.19.ebuild b/dev-python/graph-tool/graph-tool-2.19.ebuild
new file mode 100644
index 00000000..4c2f617
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.19.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal
+	cairo? (
+		dev-cpp/cairomm
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	)
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash
+	virtual/pkgconfig"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	local threads
+	has_version dev-libs/boost[threads] && threads="-mt"
+
+	configure() {
+		econf \
+			--disable-static \
+			--disable-optimization \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="${EPYTHON: -3}${threads}"
+	}
+	python_foreach_impl run_in_build_dir configure
+}
+
+src_compile() {
+	# most machines don't have enough ram for parallel builds
+	python_foreach_impl run_in_build_dir emake -j1
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	find "${D}" -name '*.la' -delete || die
+}