[gentoo-commits] gentoo-x86 commit in media-plugins/audacious-plugins: audacious-plugins-2.4.4.ebuild ChangeLog

[Tony Vroon (chainsaw)]

chainsaw    11/02/28 00:09:19

  Modified:             ChangeLog
  Added:                audacious-plugins-2.4.4.ebuild
  Log:
  Version bump. Use emake like on 2.5-alpha ebuild.
  
  (Portage version: 2.1.9.41/cvs/Linux x86_64)

Revision  Changes    Path
1.195                media-plugins/audacious-plugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.195&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.195&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?r1=1.194&r2=1.195

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v
retrieving revision 1.194
retrieving revision 1.195
diff -u -r1.194 -r1.195
--- ChangeLog	6 Feb 2011 17:48:09 -0000	1.194
+++ ChangeLog	28 Feb 2011 00:09:19 -0000	1.195
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/audacious-plugins
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.194 2011/02/06 17:48:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.195 2011/02/28 00:09:19 chainsaw Exp $
+
+*audacious-plugins-2.4.4 (28 Feb 2011)
+
+  28 Feb 2011; Tony Vroon <chainsaw@g.o>
+  +audacious-plugins-2.4.4.ebuild:
+  Version bump. Use emake like on 2.5-alpha ebuild.
 
   06 Feb 2011; Samuli Suominen <ssuominen@g.o>
   +files/2.4.3-libnotify-0.7.patch, audacious-plugins-2.4.3-r1.ebuild,



1.1                  media-plugins/audacious-plugins/audacious-plugins-2.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.4.4.ebuild?rev=1.1&content-type=text/plain

Index: audacious-plugins-2.4.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.4.4.ebuild,v 1.1 2011/02/28 00:09:19 chainsaw Exp $

inherit eutils flag-o-matic

MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="http://audacious-media-player.org/"
SRC_URI="http://distfiles.atheme.org/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
IUSE="aac adplug alsa aqua bs2b cdda cue ffmpeg flac fluidsynth gnome ipv6 jack
lame lirc midi mp3 mtp nls oss pulseaudio scrobbler sdl sid sndfile sse2 vorbis wavpack"

RDEPEND="app-arch/unzip
	>=dev-libs/dbus-glib-0.60
	dev-libs/libxml2
	>=media-sound/audacious-2.4.4
	>=net-libs/neon-0.26.4
	>=x11-libs/gtk+-2.14
	aac? ( >=media-libs/faad2-2.7 )
	adplug? ( >=dev-cpp/libbinio-1.4 )
	alsa? ( >=media-libs/alsa-lib-1.0.16 )
	bs2b? ( media-libs/libbs2b )
	cdda? ( >=media-libs/libcddb-1.2.1
		>=dev-libs/libcdio-0.79-r1 )
	cue? ( media-libs/libcue )
	ffmpeg? ( media-video/ffmpeg )
	flac? ( >=media-libs/libvorbis-1.0
		>=media-libs/flac-1.2.1-r1 )
	fluidsynth? ( media-sound/fluidsynth )
	jack? ( >=media-libs/bio2jack-0.4
		media-sound/jack-audio-connection-kit )
	lame? ( media-sound/lame )
	lirc? ( app-misc/lirc )
	mp3? ( >=media-sound/mpg123-1.12.1 )
	mtp? ( media-libs/libmtp )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
	scrobbler? ( net-misc/curl )
	sdl? (  >=media-libs/libsdl-1.2.5 )
	sid? ( >=media-libs/libsidplay-2.1.1-r2 )
	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
	vorbis? ( >=media-libs/libvorbis-1.2.0
		  >=media-libs/libogg-1.1.3 )
	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"

DEPEND="${RDEPEND}
	nls? ( dev-util/intltool )
	>=dev-util/pkgconfig-0.9.0"

mp3_warning() {
	if ! use mp3 ; then
		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
	fi
}

src_compile() {
	mp3_warning

	econf \
		--enable-chardet \
		--enable-dbus \
		--enable-modplug \
		--enable-neon \
		--disable-projectm \
		--disable-projectm-1.0 \
		$(use_enable adplug) \
		$(use_enable aac) \
		$(use_enable alsa) \
		$(use_enable alsa bluetooth) \
		$(use_enable alsa amidiplug-alsa) \
		$(use_enable aqua coreaudio) \
		$(use_enable aqua dockalbumart) \
		$(use_enable bs2b) \
		$(use_enable cdda cdaudio) \
		$(use_enable cue) \
		$(use_enable ffmpeg ffaudio) \
		$(use_enable flac flacng) \
		$(use_enable fluidsynth amidiplug-flsyn) \
		$(use_enable flac filewriter_flac) \
		$(use_enable ipv6) \
		$(use_enable jack) \
		$(use_enable gnome gnomeshortcuts) \
		$(use_enable lame filewriter_mp3) \
		$(use_enable lirc) \
		$(use_enable mp3) \
		$(use_enable midi amidiplug) \
		$(use_enable mtp mtp_up) \
		$(use_enable nls) \
		$(use_enable oss) \
		$(use_enable pulseaudio pulse) \
		$(use_enable scrobbler) \
		$(use_enable sdl paranormal) \
		$(use_enable sid) \
		$(use_enable sndfile) \
		$(use_enable sse2) \
		$(use_enable vorbis) \
		$(use_enable vorbis filewriter_vorbis) \
		$(use_enable wavpack)

	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS
}