[gentoo-commits] gentoo-x86 commit in mail-client/claws-mail: ChangeLog claws-mail-3.7.4.ebuild

[Christian Faulhammer (fauli)]

fauli       10/01/08 20:37:11

  Modified:             ChangeLog
  Added:                claws-mail-3.7.4.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.141                mail-client/claws-mail/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/ChangeLog?rev=1.141&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/ChangeLog?rev=1.141&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/ChangeLog?r1=1.140&r2=1.141

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v
retrieving revision 1.140
retrieving revision 1.141
diff -u -r1.140 -r1.141
--- ChangeLog	29 Dec 2009 12:59:21 -0000	1.140
+++ ChangeLog	8 Jan 2010 20:37:11 -0000	1.141
@@ -1,6 +1,64 @@
 # ChangeLog for mail-client/claws-mail
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.140 2009/12/29 12:59:21 fauli Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.141 2010/01/08 20:37:11 fauli Exp $
+
+*claws-mail-3.7.4 (08 Jan 2010)
+
+  08 Jan 2010; Christian Faulhammer <fauli@g.o>
+  +claws-mail-3.7.4.ebuild:
+  *Spell checker: Highlight misspelled words when applying template
+  and 'check while typing' option is on
+  *Spell checker: Highlight misspelled words in text inserted from
+  file(s) or pasted to message body when 'check while typing' option
+  is on
+  *Improve parsing of List-Post header
+  *Add new drag type "claws-mail/msg-path-list" for drag'n'drop of a
+  message selection from the message list into other applications.
+  This enables other applications to back-link to Claws Mail via a
+  "claws-mail --select" call after they received a drop.
+  *Place the cursor in the compose window according to provided
+  input.
+  *If To: is present place cursor in Subject: field and if both To:
+  and Subject: are present place cursor in body. If body: is present
+  insert a new line after text and place cursor there.
+  *QuickSearch: Use all of the available space to view expressions
+  *Updated English and Spanish user manuals.
+  *Updated Brazilian Portuguese, Catalan, Czech, Dutch, French,
+  German, Hungarian, Indonesian, Japanese, Portuguese, Russian, and
+  Slovak translations.
+
+  Bug fixes:
+  o bug 1850, '"Reply All" duplicates "To" user in "CC" if
+  original email had user in "From" and "CC"
+  o bug 1867, 'Changing account does not change BCC address'
+  o bug 1996, 'S/MIME key not selected'
+  o bug 2028, 'Attempts to connect to all accounts on exit'
+  o bug 2040, 'numbers in subject entry marked as misspelled'
+  o bug 2041, 'add autonomical scrolled windows to prefs pages'
+  o bug 2049, 'some icons not copied?'
+  o bug 2053, 'Inconsistent application of Coloration of
+  Message text'
+  o bug 2055, 'duplicate mailing list reply if List-Post +
+  Reply-To present'
+  o bug 2057, 'Claws mail does not keep renamed names of
+  nntp-subscribed groups'
+  o bug 2063, 'glib assertion in GRelation use in imap.c'
+  o bug 2074, 'Remember sending account for sent messages'
+  o bug 2082, 'Wrong color rectangle position when replacing
+  "color" processing rule'
+  o bug 2089, 'URLs ending with an underscore ('_') are not
+  correctly parsed'
+  o fix statusbar in GTK+ 2.19.x
+  o fix crash in some cases when Enchant is enabled but the
+  spell checker is disabled
+  o fix leak and unchecked accesses.
+  o modify cairo clip handling in preview windows, to prevent
+  print preview windows from being blank with GTK+ 2.18
+  o fix core dump when attempting to insert a non-existing file
+  using a mailto: uri
+  o fix LDIF export
+  o fix registering as default client on windows 7
+  o fix win32 build on latest mingw32
 
 *claws-mail-3.7.3-r1 (29 Dec 2009)
 



1.1                  mail-client/claws-mail/claws-mail-3.7.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.4.ebuild?rev=1.1&content-type=text/plain

Index: claws-mail-3.7.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.4.ebuild,v 1.1 2010/01/08 20:37:11 fauli Exp $

inherit eutils multilib

DESCRIPTION="An email client (and news reader) based on GTK+"
HOMEPAGE="http://www.claws-mail.org/"

SRC_URI="mirror://sourceforge/sylpheed-claws/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-3"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bogofilter crypt dbus dillo doc gnome gnutls imap ipv6 ldap nntp pda session smime spamassassin spell ssl startup-notification xface"

COMMONDEPEND=">=x11-libs/gtk+-2.6
	pda? ( >=app-pda/jpilot-0.99 )
	ssl? ( >=net-libs/gnutls-2.0.3 )
	ldap? ( >=net-nds/openldap-2.0.7 )
	crypt? ( >=app-crypt/gpgme-0.4.5 )
	dbus? ( >=dev-libs/dbus-glib-0.60 )
	dillo? ( www-client/dillo )
	spell? ( >=app-text/enchant-1.0.0 )
	imap? ( >=net-libs/libetpan-0.57 )
	nntp? ( >=net-libs/libetpan-0.57 )
	gnome? ( >=gnome-base/libgnomeprintui-2.2 )
	gnutls? ( >=net-libs/gnutls-2.0.3 )
	startup-notification? ( x11-libs/startup-notification )
	bogofilter? ( mail-filter/bogofilter )
	session? ( x11-libs/libSM
			x11-libs/libICE )
	smime? ( >=app-crypt/gpgme-0.4.5 )"

DEPEND="${COMMONDEPEND}
	xface? ( >=media-libs/compface-1.4 )
	dev-util/pkgconfig"

RDEPEND="${COMMONDEPEND}
	app-misc/mime-types
	x11-misc/shared-mime-info"

PLUGIN_NAMES="acpi-notifier archive att-remover attachwarner bsfilter cachesaver fancy fetchinfo gtkhtml mailmbox newmail notification perl rssyl spam_report tnef_parse vcalendar"

src_compile() {
	local myconf="--disable-libetpan --disable-gnutls"

	# libetpan is needed if user wants nntp or imap functionality
	use imap && myconf="${myconf} --enable-libetpan"
	use nntp && myconf="${myconf} --enable-libetpan"
	# The usage of openssl was discarded once and USE=ssl is mapped to
	# USE=gnutls now.  Maybe USE=ssl can fade out sometime
	use ssl && myconf="${myconf} --enable-gnutls"
	use gnutls && myconf="${myconf} --enable-gnutls"

	econf \
		$(use_enable gnome gnomeprint) \
		$(use_enable ipv6) \
		$(use_enable ldap) \
		$(use_enable dbus) \
		$(use_enable pda jpilot) \
		$(use_enable spell enchant) \
		$(use_enable xface compface) \
		$(use_enable doc manual) \
		$(use_enable startup-notification) \
		$(use_enable session libsm) \
		$(use_enable crypt pgpmime-plugin) \
		$(use_enable crypt pgpinline-plugin) \
		$(use_enable crypt pgpcore-plugin) \
		$(use_enable dillo dillo-viewer-plugin) \
		$(use_enable spamassassin spamassassin-plugin) \
		$(use_enable bogofilter bogofilter-plugin) \
		$(use_enable smime smime-plugin) \
		--docdir=/usr/share/doc/${PF} \
		--enable-trayicon-plugin \
		--disable-maemo ${myconf} || die

	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Makefile install claws-mail.png in /usr/share/icons/hicolor/48x48/apps
	# => also install it in /usr/share/pixmaps for other desktop envs
	# => also install higher resolution icons in /usr/share/icons/hicolor/...
	insinto /usr/share/pixmaps
	doins ${PN}.png || die
	local res resdir
	for res in 64x64 128x128 ; do
		resdir="/usr/share/icons/hicolor/${res}/apps"
		insinto ${resdir}
		newins ${PN}-${res}.png ${PN}.png || die
	done

	dodoc AUTHORS ChangeLog* INSTALL* NEWS README* TODO*
	docinto tools
	dodoc tools/README*

	insinto /usr/share/applications
	doins ${PN}.desktop

	einfo "Installing extra tools"
	cd "${S}"/tools
	exeinto /usr/$(get_libdir)/${PN}/tools
	doexe *.pl *.py *.conf *.sh || die
	doexe tb2claws-mail update-po uudec uuooffice || die

	# kill useless plugin files
	rm -f "${D}"/usr/lib*/${PN}/plugins/*.{la,a}
}

pkg_postinst() {
	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor

	UPDATE_PLUGINS=""
	RENAME_PLUGINS=""
	for x in ${PLUGIN_NAMES}; do
		has_version mail-client/${PN}-$x && UPDATE_PLUGINS="${UPDATE_PLUGINS} $x"
		has_version mail-client/sylpheed-claws-$x && RENAME_PLUGINS="${RENAME_PLUGINS} $x"
	done
	if [ -n "${RENAME_PLUGINS}" ]; then
		elog
		elog "The following sylpheed-claws plugins were found on your system:"
		elog
		for x in ${RENAME_PLUGINS}; do
			elog "    mail-client/sylpheed-claws-$x"
		done
		elog
		elog "If you want to continue using those you need to merge their "
		elog "renamed counterparts:"
		elog
		for x in ${RENAME_PLUGINS}; do
			elog "    mail-client/${PN}-$x"
		done
		elog
	fi
	if [ -n "${UPDATE_PLUGINS}" ]; then
		elog
		elog "You have to re-emerge or update the following plugins:"
		elog
		for x in ${UPDATE_PLUGINS}; do
			elog "    mail-client/${PN}-$x"
		done
		elog
	fi
}

pkg_postrm() {
	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor
}