[gentoo-commits] gentoo-x86 commit in dev-java/miglayout: miglayout-4.0.ebuild metadata.xml ChangeLog

[Ralph Sennhauser (sera)]

sera        11/12/28 16:24:33

  Added:                miglayout-4.0.ebuild metadata.xml ChangeLog
  Log:
  New package. Thanks to Johannes Rauh <jarauh@×××××××.com> #301493
  
  (Portage version: 2.1.10.43/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-java/miglayout/miglayout-4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/miglayout/miglayout-4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/miglayout/miglayout-4.0.ebuild?rev=1.1&content-type=text/plain

Index: miglayout-4.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/miglayout/miglayout-4.0.ebuild,v 1.1 2011/12/28 16:24:33 sera Exp $

EAPI="4"

JAVA_PKG_IUSE="doc examples source"

inherit java-pkg-2

DESCRIPTION="Easy to use yet very powerful Java Swing layout manager"
HOMEPAGE="http://www.miglayout.com/"
SRC_URI="http://www.migcalendar.com/miglayout/versions/${PV}/${P}-sources.jar"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="swt"

COMMON_DEP="
	swt? ( dev-java/swt:3.7 )"
RDEPEND="${COMMON_DEP}
	>=virtual/jre-1.5"
DEPEND="${COMMON_DEP}
	>=virtual/jdk-1.5
	app-arch/unzip"

S="${WORKDIR}"

java_prepare() {
	mv net/miginfocom/{demo,examples} . || die
	mv demo/* examples || die

	if ! use swt; then
		rm -r net/miginfocom/swt || die
	fi

	find net -name '*.java' > sources.lst
}

src_compile() {
	local classpath
	use swt && classpath=( -classpath "$(java-pkg_getjars swt-3.7)" )

	mkdir classes || die
	ejavac "${classpath[@]}" -d classes @sources.lst || die
	jar -cf ${PN}.jar -C classes . || die

	if use doc; then
		javadoc "${classpath[@]}" -author -version -d api @sources.lst || die
	fi
}

src_install() {
	java-pkg_dojar ${PN}.jar

	use doc && java-pkg_dojavadoc api
	use examples && java-pkg_doexamples examples
	use source && java-pkg_dosrc net
}



1.1                  dev-java/miglayout/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/miglayout/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/miglayout/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>java</herd>
  <longdescription lang="en">
For Java developers writing GUI layouts by hand that wants simplicity, power and automatic per platform fidelity, that are dissatisfied with the current layout managers in Swing, JavaFX and SWT, MigLayout solves your layout problems. User interfaces created with MigLayout is easy to maintain, you will understand how the layout will look like just by looking at the source code.
  </longdescription>
  <use>
    <flag name="swt">Add support for the SWT toolkit.</flag>
  </use>
</pkgmetadata>



1.1                  dev-java/miglayout/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/miglayout/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/miglayout/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-java/miglayout
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/miglayout/ChangeLog,v 1.1 2011/12/28 16:24:33 sera Exp $

*miglayout-4.0 (28 Dec 2011)

  27 Dec 2011; Ralph Sennhauser <sera@g.o> +miglayout-4.0.ebuild,
  +metadata.xml:
  New package. Thanks to Johannes Rauh <jarauh@×××××××.com> #301493