[gentoo-commits] gentoo-x86 commit in mail-client/mail-notification: mail-notification-5.4-r7.ebuild ChangeLog mail-notification-5.4-r5.ebuild

[Pacho Ramos (pacho)]

pacho       13/07/31 20:29:36

  Modified:             ChangeLog
  Added:                mail-notification-5.4-r7.ebuild
  Removed:              mail-notification-5.4-r5.ebuild
  Log:
  Revision bump: uses updated snapshot, also applies fedora patches, drops -Werror completely (#450468 by flameeyes and #479108 by Juergen Rose), rekeyword again on sparc as it was dropped until evo-3 was keyworded (that is already the case, bug #437372). Drop old
  
  (Portage version: 2.1.13.2/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.115                mail-client/mail-notification/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/mail-notification/ChangeLog?rev=1.115&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/mail-notification/ChangeLog?rev=1.115&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/mail-notification/ChangeLog?r1=1.114&r2=1.115

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/mail-notification/ChangeLog,v
retrieving revision 1.114
retrieving revision 1.115
diff -u -r1.114 -r1.115
--- ChangeLog	6 Oct 2012 15:12:51 -0000	1.114
+++ ChangeLog	31 Jul 2013 20:29:36 -0000	1.115
@@ -1,6 +1,17 @@
 # ChangeLog for mail-client/mail-notification
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/mail-notification/ChangeLog,v 1.114 2012/10/06 15:12:51 blueness Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/mail-notification/ChangeLog,v 1.115 2013/07/31 20:29:36 pacho Exp $
+
+*mail-notification-5.4-r7 (31 Jul 2013)
+
+  31 Jul 2013; Pacho Ramos <pacho@g.o>
+  +files/mail-notification-aarch64.patch,
+  +files/mail-notification-jb-gcc-format.patch,
+  +mail-notification-5.4-r7.ebuild, -mail-notification-5.4-r5.ebuild:
+  Revision bump: uses updated snapshot, also applies fedora patches, drops
+  -Werror completely (#450468 by flameeyes and #479108 by Juergen Rose),
+  rekeyword again on sparc as it was dropped until evo-3 was keyworded (that is
+  already the case, bug #437372). Drop old
 
   06 Oct 2012; Anthony G. Basile <blueness@g.o>
   mail-notification-5.4-r6.ebuild:



1.1                  mail-client/mail-notification/mail-notification-5.4-r7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/mail-notification/mail-notification-5.4-r7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/mail-notification/mail-notification-5.4-r7.ebuild?rev=1.1&content-type=text/plain

Index: mail-notification-5.4-r7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/mail-notification/mail-notification-5.4-r7.ebuild,v 1.1 2013/07/31 20:29:36 pacho Exp $

EAPI=5
GCONF_DEBUG="no"

inherit gnome2 multilib flag-o-matic toolchain-funcs eutils

DESCRIPTION="Status icon informing about new mail"
HOMEPAGE="http://www.nongnu.org/mailnotify/ https://github.com/epienbroek/mail-notification"

GIT_REVISION="eab5c13" # Same as Fedora
SRC_URI="https://github.com/epienbroek/${PN}/tarball/${GIT_REVISION} -> ${PN}-${GIT_REVISION}.tar.gz"
S="${WORKDIR}/epienbroek-${PN}-${GIT_REVISION}"

KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-linux"
SLOT="0"
LICENSE="GPL-3"
IUSE="evo +gnome-keyring sasl +sound ssl sylpheed"

LANGS="bg ca cs de es fr ja nl pl pt pt_BR ru sr sr@Latn sv"
for lang in ${LANGS}; do
	IUSE+=" linguas_${lang}"
done

# gmime is actually optional, but it's used by so much of the package
# it's pointless making it optional. gnome-keyring is required for
# several specific access methods, and thus linked to those USE flags
# instead of adding a keyring USE flag.
RDEPEND="
	x11-libs/gtk+:3
	>=dev-libs/glib-2.14:2
	>=gnome-base/gconf-2.6
	>=gnome-base/libgnomeui-2.14
	dev-libs/dbus-glib
	dev-libs/gmime:2.6
	>=x11-libs/libnotify-0.4.1
	gnome-keyring? ( gnome-base/libgnome-keyring )
	ssl? ( >=dev-libs/openssl-0.9.6 )
	sasl? ( >=dev-libs/cyrus-sasl-2 )
	sound? ( media-libs/gstreamer:0.10 )
	evo? ( >=mail-client/evolution-3 )
	sylpheed? ( mail-client/sylpheed )
"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	dev-util/gob
	sys-devel/gettext
	virtual/pkgconfig
	>=dev-util/intltool-0.35.0
"
# this now uses JB (the Jean-Yves Lefort's Build System) as a build system
# instead of autotools, this is a little helper function that basically does
# the same thing as use_enable
use_var() {
	echo "${2:-$1}=$(usex $1)"
}

src_prepare() {
	sed -i	-e '/jb_rule_set_install_message/d' \
		-e '/jb_rule_add_install_command/d' \
		jbsrc/jb.c || die

	# Ensure we never append -Werror
	sed -i -e 's/ -Werror//' jb jbsrc/jb.c || die

	# We are not Ubuntu, and this could be the cause of #215281
	epatch "${FILESDIR}/${P}-remove-ubuntu-special-case.patch"

	# Apply Fedora patches
	# Fix gcc warning
	epatch "${FILESDIR}/${PN}-jb-gcc-format.patch"
	# Support aarch64
	epatch "${FILESDIR}/${PN}-aarch64.patch"
}

src_configure() {
	set -- \
	./jb configure destdir="${D}" prefix="${EPREFIX}/usr" libdir="${EPREFIX}/usr/$(get_libdir)" \
		sysconfdir="${EPREFIX}/etc" localstatedir="${EPREFIX}/var" cc="$(tc-getCC)" \
		cflags="${CFLAGS}" cppflags="${CXXFLAGS}" ldflags="${LDFLAGS}" \
		scrollkeeper-dir="${EPREFIX}/var/lib/scrollkeeper" \
		$(use_var evo evolution) \
		$(use_var gnome-keyring gmail) \
		$(use_var gnome-keyring imap) \
		$(use_var gnome-keyring pop3) \
		$(use_var sasl) \
		$(use_var ssl) \
		$(use_var sylpheed)
	echo "$@"
	"$@" || die
}

src_compile() {
	./jb build || die
}

src_install() {
	GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL="1" ./jb install || die
	dodoc NEWS README AUTHORS TODO TRANSLATING
	rm -rf "${ED}/var/lib/scrollkeeper"

	einfo "Cleaning up locales..."
	for lang in ${LANGS}; do
		use "linguas_${lang}" && {
			einfo "- keeping ${lang}"
			continue
		}
		rm -Rf "${D}"/usr/share/locale/"${lang}" || die
	done
}