[gentoo-commits] gentoo-x86 commit in sci-astronomy/wcstools: ChangeLog wcstools-3.8.1.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    10/01/29 06:51:39

  Modified:             ChangeLog
  Added:                wcstools-3.8.1.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 sci-astronomy/wcstools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-astronomy/wcstools/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-astronomy/wcstools/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-astronomy/wcstools/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-astronomy/wcstools/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	9 Sep 2009 16:06:30 -0000	1.16
+++ ChangeLog	29 Jan 2010 06:51:38 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for sci-astronomy/wcstools
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/wcstools/ChangeLog,v 1.16 2009/09/09 16:06:30 bicatali Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/wcstools/ChangeLog,v 1.17 2010/01/29 06:51:38 bicatali Exp $
+
+*wcstools-3.8.1 (29 Jan 2010)
+
+  29 Jan 2010; Sébastien Fabbro <bicatali@g.o>
+  +wcstools-3.8.1.ebuild:
+  Version bump
 
   09 Sep 2009; Sébastien Fabbro <bicatali@g.o>
   wcstools-3.7.7.ebuild:



1.1                  sci-astronomy/wcstools/wcstools-3.8.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-astronomy/wcstools/wcstools-3.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-astronomy/wcstools/wcstools-3.8.1.ebuild?rev=1.1&content-type=text/plain

Index: wcstools-3.8.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/wcstools/wcstools-3.8.1.ebuild,v 1.1 2010/01/29 06:51:38 bicatali Exp $

EAPI=2
inherit eutils autotools

DESCRIPTION="World Coordinate System library for astronomical FITS images"
HOMEPAGE="http://tdc-www.harvard.edu/software/wcstools"
SRC_URI="http://tdc-www.harvard.edu/software/${PN}/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.7-autotools.patch
	# avoid colliding with fixdos, getdate and remap from other packages
	sed -i \
		-e 's/getdate/wcsgetdate/' \
		-e 's/crlf/wcscrlf/' \
		-e 's/remap/wcsremap/' \
		wcstools Makefile.am || die
	sed -i -e "s/3.7.x/${PV}/" "${S}"/configure.ac || die "sed failed"
	eautoreconf
}

src_test() {
	einfo "Testing various wcstools programs"
	./newfits -a 10 -j 248 41 -p 0.15 test.fits || die "test newfits failed"
	./sethead test.fits A=1 B=1 ||  die "test sethead failed"
	[[ "$(./gethead test.fits RA)" == "16:32:00.000" ]] \
		|| die "test gethead failed"
	rm -f test.fits
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	doman Man/man1/* || die "doman failed"
	dodoc Readme Programs NEWS libned/NED_client || die "dodoc failed"
	newdoc libwcs/Readme Readme.libwcs || die "newdoc failed"
	newdoc libwcs/NEWS NEWS.libwcs || die "newdoc failed"
}

pkg_postinst() {
	elog "The following execs have been renamed to avoid colliding"
	elog "with other packages:"
	elog " getdate -> wcsgetdate"
	elog " crlf    -> wcscrlf"
	elog " remap   -> wcsremap"
}