[gentoo-commits] gentoo-x86 commit in app-misc/spacenavd: spacenavd-0.5-r3.ebuild ChangeLog

[Sebastian Pipping (sping)]

sping       12/09/30 18:14:05

  Modified:             ChangeLog
  Added:                spacenavd-0.5-r3.ebuild
  Log:
  app-misc/spacenavd: udev rules destination (bug #436658)
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  app-misc/spacenavd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/spacenavd/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/spacenavd/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/spacenavd/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/spacenavd/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	30 Sep 2012 00:39:49 -0000	1.7
+++ ChangeLog	30 Sep 2012 18:14:05 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/spacenavd
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/spacenavd/ChangeLog,v 1.7 2012/09/30 00:39:49 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/spacenavd/ChangeLog,v 1.8 2012/09/30 18:14:05 sping Exp $
+
+*spacenavd-0.5-r3 (30 Sep 2012)
+
+  30 Sep 2012; Sebastian Pipping <sping@g.o> +spacenavd-0.5-r3.ebuild:
+  Put udev rules into /usr/lib/udev/rules.d/ rather than /etc/udev/rules.d (bug
+  #436658)
 
   30 Sep 2012; Anthony G. Basile <blueness@g.o> spacenavd-0.5-r2.ebuild:
   stable ppc64, bug #436576



1.1                  app-misc/spacenavd/spacenavd-0.5-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/spacenavd/spacenavd-0.5-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/spacenavd/spacenavd-0.5-r3.ebuild?rev=1.1&content-type=text/plain

Index: spacenavd-0.5-r3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/spacenavd/spacenavd-0.5-r3.ebuild,v 1.1 2012/09/30 18:14:05 sping Exp $

EAPI="4"

inherit eutils linux-info toolchain-funcs

MY_PN='spacenav'
DESCRIPTION="The spacenavd daemon provides free alternative to the 3dxserv daemon."
HOMEPAGE="http://spacenav.sourceforge.net/"
SRC_URI="mirror://sourceforge/project/${MY_PN}/${MY_PN}%20daemon/${PN}%20${PV}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="X"

RDEPEND="X? ( x11-apps/xdpyinfo )"
DEPEND="${RDEPEND}"

pkg_setup() {
	CONFIG_CHECK="~INPUT_EVDEV"
	ERROR_CFG="Your kernel needs INPUT_EVDEV for the spacenavd to work properly"
	check_extra_config
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-destdir.patch
	epatch "${FILESDIR}"/${P}-custom-flags.patch
	epatch "${FILESDIR}"/${P}-no-x11.patch
}

src_configure() {
	econf \
		--enable-opt --enable-ldopt \
		$(use_enable X x11)
}

src_compile() {
	emake CC=$(tc-getCC)
}

src_install() {
	# Config file
	insinto /etc
	newins "${S}/doc/example-spnavrc" spnavrc.sample || die

	# Init script
	newinitd "${FILESDIR}/spnavd" spacenavd || die

	# Install udev rule but leave activiation to the user
	# since Xorg may be configured to grab the device already
	insinto /usr/lib/udev/rules.d
	newins "${FILESDIR}"/99-space-navigator.rules 99-space-navigator.rules.ignored || die

	# Daemon
	dobin "${S}/spacenavd"
	use X && dobin "${S}/spnavd_ctl"
}

pkg_postinst() {
	elog "To start the Spacenav daemon system-wide by default"
	elog "you should add it to the default runlevel :"
	elog "\`rc-update add spacenavd default\`"
	elog
	if use X; then
		elog "To start generating Spacenav X events by default"
		elog "you should add this command in your user startup"
		elog "scripts such as .gnomerc or .xinitrc :"
		elog "\`spnavd_ctl x11 start\`"
		elog
	fi
	elog "If you want to auto-start the daemon when you plug in"
	elog "a SpaceNavigator device, activate the related udev rule :"
	elog "\`sudo ln -s /usr/lib/udev/rules.d/99-space-navigator.rules.ignored /etc/udev/rules.d/99-space-navigator.rules\`"
	elog
	ewarn "You must restart spnavd \`/etc/init.d/spacenavd restart\` to run"
	ewarn "the new version of the daemon."
}