[gentoo-commits] gentoo-x86 commit in net-firewall/firewalld: metadata.xml ChangeLog firewalld-0.2.9.ebuild

[Doug Goldstein (cardoe)]

cardoe      12/11/02 22:15:21

  Added:                metadata.xml ChangeLog firewalld-0.2.9.ebuild
  Log:
  Initial version of firewalld. Let's see how this works out.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.1                  net-firewall/firewalld/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/firewalld/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/firewalld/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>virtualization</herd>
	<maintainer>
		<email>cardoe@g.o</email>
		<name>Doug Goldstein</name>
	</maintainer>
	<use>
		<flag name='gui'>Builds and installs GUI configurator and GTK+ applet</flag>
	</use>
</pkgmetadata>




1.1                  net-firewall/firewalld/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/firewalld/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/firewalld/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-firewall/firewalld
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/firewalld/ChangeLog,v 1.1 2012/11/02 22:15:21 cardoe Exp $

*firewalld-0.2.9 (02 Nov 2012)

  02 Nov 2012; Doug Goldstein <cardoe@g.o> +firewalld-0.2.9.ebuild,
  +files/firewalld.init, +metadata.xml:
  Initial version of firewalld. Let's see how this works out.




1.1                  net-firewall/firewalld/firewalld-0.2.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/firewalld/firewalld-0.2.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/firewalld/firewalld-0.2.9.ebuild?rev=1.1&content-type=text/plain

Index: firewalld-0.2.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/firewalld/firewalld-0.2.9.ebuild,v 1.1 2012/11/02 22:15:21 cardoe Exp $

EAPI=4
PYTHON_COMPAT=( python{2_6,2_7} )
BACKPORTS=3ab6b297

inherit autotools eutils gnome2-utils python-r1 systemd

DESCRIPTION="A firewall daemon with D-BUS interface providing a dynamic firewall"
HOMEPAGE="http://fedorahosted.org/firewalld"
SRC_URI="https://fedorahosted.org/released/firewalld/${P}.tar.bz2
	${BACKPORTS:+http://dev.gentoo.org/~cardoe/distfiles/${P}-${BACKPORTS}.tar.xz}"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64"
IUSE="gui"

RDEPEND="${PYTHON_DEPS}
	dev-python/dbus-python
	dev-python/decorator
	>=dev-python/python-slip-0.2.7[dbus]
	dev-python/pygobject:3
	net-firewall/ebtables
	net-firewall/iptables[ipv6]
	gui? (
		dev-python/pygtk:2
		>=x11-libs/gtk+-2.6:2
		x11-libs/gtk+:3
	)"
DEPEND="${RDEPEND}
	dev-libs/glib:2
	>=dev-util/intltool-0.35
	sys-devel/gettext"

src_prepare() {
	[[ -n ${BACKPORTS} ]] && \
		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
			epatch

	epatch_user
	eautoreconf
}

src_configure() {
	python_export_best

	econf \
		--enable-systemd
		"$(systemd_with_unitdir 'systemd-unitdir')"
}

src_install() {
	python_foreach_impl \
		emake DESTDIR="${ED}" pythondir="$(python_get_sitedir)" install

	# Get rid of junk
	rm -f "${ED}/etc/rc.d/init.d/firewalld"
	rm -f "${ED}/etc/sysconfig/firewalld"
	rm -rf "${ED}/etc/rc.d/"
	rm -rf "${ED}/etc/sysconfig/"

	# For non-gui installs we need to remove GUI bits
	if ! use gui; then
		rm -f "${ED}/usr/bin/firewall-applet"
		rm -f "${ED}/usr/bin/firewall-config"
		rm -rf "${ED}/usr/share/icons"
		rm -rf "${ED}/usr/share/applications"
	fi

	newinitd "${FILESDIR}"/firewalld.init firewalld
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}