[gentoo-commits] repo/gentoo:master commit in: media-libs/avidemux-plugins/files/, media-libs/avidemux-plugins/

[Andreas Sturmlechner]

commit:     94a63c19f3793c06897092a5713cf951f429fe59
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 27 21:53:47 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jan 28 11:48:47 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94a63c19

media-libs/avidemux-plugins: drop 2.7.8

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-libs/avidemux-plugins/Manifest               |   1 -
 .../avidemux-plugins/avidemux-plugins-2.7.8.ebuild | 164 ---------------------
 .../avidemux-plugins-2.6.20-optional-pulse.patch   |  20 ---
 3 files changed, 185 deletions(-)

diff --git a/media-libs/avidemux-plugins/Manifest b/media-libs/avidemux-plugins/Manifest
index 5e1a60fccafb..49e9b54b3bbf 100644
--- a/media-libs/avidemux-plugins/Manifest
+++ b/media-libs/avidemux-plugins/Manifest
@@ -1,2 +1 @@
-DIST avidemux-2.7.8.tar.gz 22080267 BLAKE2B a1e56856f44d56afac6ea4015f206a3f9301c025b3c8da1528165bd4c139ccc971074ac21aa05b9b3dfd6d514eabcbb375e671c8df9c9e5cae74a0a6597577c4 SHA512 6cd5527ab34517a07bf73e46d01f15b7ff023ff34ed70ee54f1d7dbfb6cf57364a323b4ecb89bb9aadeb9bc05473aacb40d8c4eecc522840a3c1c4b3a8756d82
 DIST avidemux-2.8.1.tar.gz 23207741 BLAKE2B 766ae9b159d2e48a3d14bdfccf9c665b95ed056831b515d53837bf2bae20baf9b01d15d551b62fb96f3c0cf50b0138448a133bc62e6202af744de558e0fbfe4f SHA512 e7105e555e04dd6768336bdb246037e91045de2e1f572ae362d985424def65499c7f25d92d376ea98af09b436d89e9eb4a5424e93b11df14f2d67ac35661a8a3

diff --git a/media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild b/media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild
deleted file mode 100644
index 78b9cd9f9345..000000000000
--- a/media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild
+++ /dev/null
@@ -1,164 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-PYTHON_COMPAT=( python3_{9..10} )
-
-inherit cmake flag-o-matic python-single-r1
-
-DESCRIPTION="Plugins for the video editor media-video/avidemux"
-HOMEPAGE="http://fixounet.free.fr/avidemux"
-SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> avidemux-${PV}.tar.gz"
-
-# Multiple licenses because of all the bundled stuff.
-LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
-SLOT="2.7"
-IUSE="a52 aac aften alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx opengl opus oss pulseaudio qt5 truetype twolame vdpau vorbis vpx x264 x265 xv xvid"
-KEYWORDS="~amd64 ~x86"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-# dev-lang/spidermonkey is not required anymore
-# see https://github.com/mean00/avidemux2/blob/master/avidemux_plugins/ADM_scriptEngines/CMakeLists.txt
-COMMON_DEPEND="
-	${PYTHON_DEPS}
-	~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
-	~media-video/avidemux-${PV}:${SLOT}[opengl?,qt5?]
-	dev-libs/libxml2:2
-	media-libs/a52dec
-	media-libs/libass:0=
-	media-libs/libmad
-	media-libs/libmp4v2
-	media-libs/libpng:0=
-	virtual/libiconv
-	aac? (
-		media-libs/faac
-		media-libs/faad2
-	)
-	aften? ( media-libs/aften )
-	alsa? ( media-libs/alsa-lib )
-	amr? ( media-libs/opencore-amr )
-	dcaenc? ( media-sound/dcaenc )
-	dts? ( media-libs/libdca )
-	fdk? ( media-libs/fdk-aac:0= )
-	fontconfig? ( media-libs/fontconfig:1.0 )
-	fribidi? ( dev-libs/fribidi )
-	jack? (
-		virtual/jack
-		libsamplerate? ( media-libs/libsamplerate )
-	)
-	lame? ( media-sound/lame )
-	opus? ( media-libs/opus )
-	pulseaudio? ( media-sound/pulseaudio )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-	)
-	truetype? ( media-libs/freetype:2 )
-	twolame? ( media-sound/twolame )
-	vorbis? ( media-libs/libvorbis )
-	vpx? ( media-libs/libvpx:0= )
-	x264? ( media-libs/x264:0= )
-	x265? ( media-libs/x265:0= )
-	xv? (
-		x11-libs/libX11
-		x11-libs/libXext
-		x11-libs/libXv
-	)
-	xvid? ( media-libs/xvid )
-"
-DEPEND="
-	${COMMON_DEPEND}
-	oss? ( virtual/os-headers )
-"
-RDEPEND="
-	${COMMON_DEPEND}
-	!<media-libs/avidemux-plugins-${PV}
-"
-
-S="${WORKDIR}/avidemux2-${PV}"
-
-PATCHES=( "${FILESDIR}/${PN}-2.6.20-optional-pulse.patch" )
-
-src_prepare() {
-	default
-
-	# Don't reapply PATCHES during cmake_src_prepare
-	unset PATCHES
-
-	processes="buildPluginsCommon:avidemux_plugins
-		buildPluginsCLI:avidemux_plugins"
-	use qt5 && processes+=" buildPluginsQt4:avidemux_plugins"
-
-	for process in ${processes} ; do
-		CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
-	done
-}
-
-src_configure() {
-	# See bug 432322.
-	use x86 && replace-flags -O0 -O1
-
-	for process in ${processes} ; do
-		local build="${WORKDIR}/${P}_build/${process%%:*}"
-
-		local mycmakeargs=(
-			-DAVIDEMUX_SOURCE_DIR='${S}'
-			-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
-			-DFAAC="$(usex aac)"
-			-DFAAD="$(usex aac)"
-			-DALSA="$(usex alsa)"
-			-DAFTEN="$(usex aften)"
-			-DDCAENC="$(usex dcaenc)"
-			-DFDK_AAC="$(usex fdk)"
-			-DOPENCORE_AMRWB="$(usex amr)"
-			-DOPENCORE_AMRNB="$(usex amr)"
-			-DLIBDCA="$(usex dts)"
-			-DFONTCONFIG="$(usex fontconfig)"
-			-DJACK="$(usex jack)"
-			-DLAME="$(usex lame)"
-			-DNVENC=no
-			-DOPENGL="$(usex opengl)"
-			-DOPUS="$(usex opus)"
-			-DOSS="$(usex oss)"
-			-DPULSEAUDIOSIMPLE="$(usex pulseaudio)"
-			-DQT4=OFF
-			-DFREETYPE2="$(usex truetype)"
-			-DTWOLAME="$(usex twolame)"
-			-DX264="$(usex x264)"
-			-DX265="$(usex x265)"
-			-DXVIDEO="$(usex xv)"
-			-DXVID="$(usex xvid)"
-			-DVDPAU="$(usex vdpau)"
-			-DVORBIS="$(usex vorbis)"
-			-DLIBVORBIS="$(usex vorbis)"
-			-DVPXDEC="$(usex vpx)"
-			-DUSE_EXTERNAL_LIBA52=yes
-			-DUSE_EXTERNAL_LIBASS=yes
-			-DUSE_EXTERNAL_LIBMAD=yes
-			-DUSE_EXTERNAL_LIBMP4V2=yes
-		)
-
-		use qt5 && mycmakeargs+=( -DENABLE_QT5=True )
-		use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
-
-		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
-	done
-}
-
-src_compile() {
-	for process in ${processes} ; do
-		local build="${WORKDIR}/${P}_build/${process%%:*}"
-		BUILD_DIR="${build}" cmake_src_compile
-	done
-}
-
-src_install() {
-	for process in ${processes} ; do
-		local build="${WORKDIR}/${P}_build/${process%%:*}"
-		BUILD_DIR="${build}" cmake_src_install
-	done
-}

diff --git a/media-libs/avidemux-plugins/files/avidemux-plugins-2.6.20-optional-pulse.patch b/media-libs/avidemux-plugins/files/avidemux-plugins-2.6.20-optional-pulse.patch
deleted file mode 100644
index a75f12952353..000000000000
--- a/media-libs/avidemux-plugins/files/avidemux-plugins-2.6.20-optional-pulse.patch
+++ /dev/null
@@ -1,20 +0,0 @@
---- a/cmake/admCheckAudioDeviceLibs.cmake
-+++ b/cmake/admCheckAudioDeviceLibs.cmake
-@@ -158,6 +158,7 @@
- 
- 	MESSAGE(STATUS "Checking for PULSEAUDIOSIMPLE")
- 	MESSAGE(STATUS "*****************************")
-+	IF (PULSEAUDIOSIMPLE)
-         IF (PULSEAUDIOSIMPLE_INCLUDE_DIR AND PULSEAUDIOSIMPLE_LIBRARIES)
-         # in cache already
-          SET(PULSEAUDIOSIMPLE_FIND_QUIETLY TRUE)
-@@ -191,6 +192,9 @@
-         MARK_AS_ADVANCED(PULSEAUDIOSIMPLE_INCLUDE_DIR PULSEAUDIOSIMPLE_LIBRARIES)
- 
- 		APPEND_SUMMARY_LIST("Audio Device" "PulseAudio" "${USE_PULSE_SIMPLE}")
-+	ELSE (PULSEAUDIOSIMPLE)
-+		MESSAGE("${MSG_DISABLE_OPTION}")
-+	ENDIF (PULSEAUDIOSIMPLE)
- ELSE (UNIX AND NOT APPLE)
- 	SET(PULSEAUDIOSIMPLE_CAPABLE FALSE)
- ENDIF (UNIX AND NOT APPLE)