[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-config/

[Joonas Niilola]

commit:     466f7fb19d4a560757c41d5ab1737f256e60c503
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 16:39:23 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Apr 18 05:00:34 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=466f7fb1

lxqt-base/lxqt-config: add version 0.17.1

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 lxqt-base/lxqt-config/Manifest                  |  1 +
 lxqt-base/lxqt-config/lxqt-config-0.17.1.ebuild | 72 +++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/lxqt-base/lxqt-config/Manifest b/lxqt-base/lxqt-config/Manifest
index 6cae85a7f41..0c9f5334646 100644
--- a/lxqt-base/lxqt-config/Manifest
+++ b/lxqt-base/lxqt-config/Manifest
@@ -1 +1,2 @@
 DIST lxqt-config-0.16.1.tar.xz 327652 BLAKE2B b242aeea758b8dc2804c9ebd4abd9a0ab98d92e7e6620646c90a78ca60238ef0e62e823eac3e226fdd05ddc431e271551ecf34281467a9db03fe5195a2f3e293 SHA512 3322611b74a945b2c4aa60a179fc1edabd09e474502f44e7a0319478a09762ff7a11fbb7603aa26ec8ea593514bbcdfc98fb475009d0dfa4d387963fcdef7e03
+DIST lxqt-config-0.17.1.tar.xz 339184 BLAKE2B cdb2852801b4af141213dbe680f5d9ccf4bf3738ee6c39e4df7e7915ee74209d4516d4ca2675176f31b4fa7afc4c3907ac71afe1d2a88ce39d8831dfc62946ad SHA512 2173acd18ffa5aeee9d11bd73955d0475b53a335df7d95523a2297b5ef3f9a8e4e135a290e7a720a227a92c84532a64d9fbc7a811de242dd32f9e70d036d3ca6

diff --git a/lxqt-base/lxqt-config/lxqt-config-0.17.1.ebuild b/lxqt-base/lxqt-config/lxqt-config-0.17.1.ebuild
new file mode 100644
index 00000000000..7dc8f7f7264
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-0.17.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt.github.io/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.9.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5
+	=lxqt-base/liblxqt-$(ver_cut 1-2)*
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:5= )
+	touchpad? (
+		virtual/libudev
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXext
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR=$(usex monitor)
+		-DWITH_TOUCHPAD=$(usex touchpad)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}