[gentoo-commits] repo/gentoo:master commit in: games-arcade/oshu/

[Joonas Niilola]

commit:     ff220499be5e804428adc83035a13c25ad9e73a6
Author:     Haelwenn (lanodan) Monnier <contact <AT> hacktivis <DOT> me>
AuthorDate: Tue Mar 31 08:28:35 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Mar 31 08:38:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff220499

games-arcade/oshu: Add live ebuild

Signed-off-by: Haelwenn (lanodan) Monnier <contact <AT> hacktivis.me>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 games-arcade/oshu/oshu-9999.ebuild | 55 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/games-arcade/oshu/oshu-9999.ebuild b/games-arcade/oshu/oshu-9999.ebuild
new file mode 100644
index 00000000000..84d415b3c11
--- /dev/null
+++ b/games-arcade/oshu/oshu-9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Lightweight osu! port"
+HOMEPAGE="https://github.com/fmang/oshu"
+
+if [[ $PV = *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fmang/oshu.git"
+	SRC_URI="osu-skin? ( https://www.mg0.fr/oshu/skins/osu-v1.tar.gz -> ${PN}-skin-v1.tar.gz )"
+else
+	SRC_URI="https://github.com/fmang/oshu/archive/${PV}.tar.gz -> oshu-${PV}.tar.gz
+		osu-skin? ( https://www.mg0.fr/oshu/skins/osu-v1.tar.gz -> ${PN}-skin-v1.tar.gz )"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3 CC-BY-NC-4.0"
+SLOT="0"
+IUSE="osu-skin"
+
+RDEPEND="
+	media-libs/libsdl2
+	media-libs/sdl2-image
+	x11-libs/cairo
+	x11-libs/pango
+	media-video/ffmpeg:=
+"
+
+DEPEND="${RDEPEND}"
+
+# Doesn't build executable needed for the test
+# https://github.com/fmang/oshu/issues/87
+RESTRICT="test"
+
+src_prepare() {
+	if use osu-skin; then
+		eapply "${FILESDIR}/oshu-2.0.0-use_unpacked_osu-skin.patch"
+		mv "${WORKDIR}/osu" share/skins/ || die "Failed to move osu-skin"
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		'-DOSHU_DEFAULT_SKIN='$(usex osu-skin 'osu' 'minimal')
+		'-DOSHU_SKINS=minimal'$(usex osu-skin ';osu' '')
+	)
+
+	cmake_src_configure
+}