[gentoo-commits] proj/gnome:master commit in: net-wireless/gnome-bluetooth/

[Gilles Dartiguelongue]

commit:     0363926643066f227fd9290214992942e1447dff
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 10 13:31:48 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Mon Sep 10 14:02:12 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=03639266

net-wireless/gnome-bluetooth: 3.20.1 → 3.26.1

Package-Manager: Portage-2.3.49, Repoman-2.3.10
Manifest-Sign-Key: 0x5A56C8CD0C13248A

 .../gnome-bluetooth/gnome-bluetooth-3.26.1.ebuild  | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-3.26.1.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-3.26.1.ebuild
new file mode 100644
index 00000000..afc6b43a
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-3.26.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome-meson udev user
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="2/13" # subslot = libgnome-bluetooth soname version
+IUSE="debug +introspection"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.38:2
+	media-libs/libcanberra[gtk3]
+	>=x11-libs/gtk+-3.12:3[introspection?]
+	x11-libs/libnotify
+	virtual/udev
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=net-wireless/bluez-5
+"
+DEPEND="${COMMON_DEPEND}
+	!net-wireless/bluez-gnome
+	app-text/docbook-xml-dtd:4.1.2
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.40.0
+	dev-util/itstool
+	virtual/libudev
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+pkg_setup() {
+	enewgroup plugdev
+}
+
+src_configure() {
+	gnome-meson_src_configure \
+		-Denable-gtk-doc=false \
+		-Denable-icon-update=false \
+		$(meson_enable introspection)
+}
+
+src_install() {
+	gnome-meson_src_install
+	udev_dorules "${FILESDIR}"/61-${PN}.rules
+}
+
+pkg_postinst() {
+	gnome-meson_pkg_postinst
+	if ! has_version sys-auth/consolekit[acl] && ! has_version sys-apps/systemd[acl] ; then
+		elog "Don't forget to add yourself to the plugdev group "
+		elog "if you want to be able to control bluetooth transmitter."
+	fi
+}