[gentoo-commits] gentoo-x86 commit in media-gfx/gmic: gmic-1.5.1.9.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    12/08/31 18:46:14

  Modified:             ChangeLog
  Added:                gmic-1.5.1.9.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 media-gfx/gmic/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gmic/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gmic/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gmic/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	17 Aug 2012 04:54:15 -0000	1.22
+++ ChangeLog	31 Aug 2012 18:46:14 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/gmic
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v 1.22 2012/08/17 04:54:15 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v 1.23 2012/08/31 18:46:14 radhermit Exp $
+
+*gmic-1.5.1.9 (31 Aug 2012)
+
+  31 Aug 2012; Tim Harder <radhermit@g.o> +gmic-1.5.1.9.ebuild:
+  Version bump.
 
   17 Aug 2012; Tim Harder <radhermit@g.o> -gmic-1.5.1.6.ebuild,
   -files/gmic-1.5.1.6-makefile.patch:



1.1                  media-gfx/gmic/gmic-1.5.1.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gmic/gmic-1.5.1.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gmic/gmic-1.5.1.9.ebuild?rev=1.1&content-type=text/plain

Index: gmic-1.5.1.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/gmic-1.5.1.9.ebuild,v 1.1 2012/08/31 18:46:14 radhermit Exp $

EAPI="4"

inherit eutils toolchain-funcs bash-completion-r1 flag-o-matic

DESCRIPTION="GREYC's Magic Image Converter"
HOMEPAGE="http://gmic.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.gz
	doc? ( http://dev.gentoo.org/~radhermit/dist/gmic_reference-${PV}.pdf.xz )"

LICENSE="CeCILL-2 FDL-1.3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc ffmpeg fftw graphicsmagick jpeg opencv openexr png tiff X zlib"

RDEPEND="
	ffmpeg? ( virtual/ffmpeg )
	fftw? ( sci-libs/fftw:3.0 )
	graphicsmagick? ( media-gfx/graphicsmagick )
	jpeg? ( virtual/jpeg )
	opencv? ( >=media-libs/opencv-2.3.1a-r1 )
	openexr? (
		media-libs/ilmbase
		media-libs/openexr
	)
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
	X? (
		x11-libs/libX11
		x11-libs/libXext
	)
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
	doc? ( app-arch/xz-utils )"

S=${WORKDIR}/${P}/src

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.5.1.7-makefile.patch
	epatch "${FILESDIR}"/${PN}-1.5.0.7-ffmpeg.patch

	for i in ffmpeg fftw jpeg opencv png tiff zlib ; do
		use $i || { sed -i -r -e "s/^(${i}_(C|LD)FLAGS =).*/\1/I" Makefile || die ; }
	done

	use graphicsmagick || { sed -i -r -e "s/^(MAGICK_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
	use openexr || { sed -i -r -e "s/^(EXR_(C|LD)FLAGS =).*/\1/" Makefile || die ; }

	if ! use X ; then
		sed -i -r -e "s/^((X11|XSHM)_(C|LD)FLAGS =).*/\1/" Makefile || die

		# Disable display capabilities when X support is disabled
		append-cppflags -Dcimg_display=0
	fi
}

src_compile() {
	emake AR="$(tc-getAR)" CC="$(tc-getCXX)" custom lib
}

src_install() {
	dobin gmic
	newlib.so libgmic.so libgmic.so.1

	insinto /usr/include
	doins gmic.h

	doman ../man/gmic.1.gz
	dodoc ../README

	use doc && dodoc "${WORKDIR}"/gmic_reference-${PV}.pdf

	newbashcomp gmic_bashcompletion.sh ${PN}
}