[gentoo-commits] gentoo-x86 commit in www-plugins/google-talkplugin: google-talkplugin-3.14.17.0-r1.ebuild google-talkplugin-9999.ebuild ChangeLog google-talkplugin-3.14.17.0.ebuild

[Christoph Junghans (ottxor)]

ottxor      13/02/27 23:38:26

  Modified:             google-talkplugin-9999.ebuild ChangeLog
  Added:                google-talkplugin-3.14.17.0-r1.ebuild
  Removed:              google-talkplugin-3.14.17.0.ebuild
  Log:
  install additional datafiles to make plugins work (bug #438198)
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key C2000586)

Revision  Changes    Path
1.12                 www-plugins/google-talkplugin/google-talkplugin-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-9999.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-9999.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-9999.ebuild?r1=1.11&r2=1.12

Index: google-talkplugin-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-9999.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- google-talkplugin-9999.ebuild	9 Jan 2013 03:22:25 -0000	1.11
+++ google-talkplugin-9999.ebuild	27 Feb 2013 23:38:26 -0000	1.12
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-9999.ebuild,v 1.11 2013/01/09 03:22:25 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-9999.ebuild,v 1.12 2013/02/27 23:38:26 ottxor Exp $
 
 EAPI=4
 
@@ -55,13 +55,7 @@
 
 INSTALL_BASE="opt/google/talkplugin"
 
-QA_EXECSTACK="${INSTALL_BASE}/GoogleTalkPlugin"
-
-QA_TEXTRELS="${INSTALL_BASE}/lib*.so"
-
-QA_FLAGS_IGNORED="${INSTALL_BASE}/lib.*so
-	${INSTALL_BASE}/lib/libCg.*so
-	${INSTALL_BASE}/GoogleTalkPlugin"
+QA_PREBUILT="${INSTALL_BASE}/*"
 
 S="${WORKDIR}"
 
@@ -104,6 +98,8 @@
 	#install screen-sharing stuff - bug #397463
 	insinto "/${INSTALL_BASE}"
 	doins "${INSTALL_BASE}"/windowpicker.glade
+	doins "${INSTALL_BASE}"/remoting24x24.png
+	doins -r "${INSTALL_BASE}"/data
 
 	strip-linguas ${LANGS}
 	for l in ${LINGUAS}; do



1.44                 www-plugins/google-talkplugin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	26 Feb 2013 02:58:56 -0000	1.43
+++ ChangeLog	27 Feb 2013 23:38:26 -0000	1.44
@@ -1,6 +1,13 @@
 # ChangeLog for www-plugins/google-talkplugin
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/ChangeLog,v 1.43 2013/02/26 02:58:56 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/ChangeLog,v 1.44 2013/02/27 23:38:26 ottxor Exp $
+
+*google-talkplugin-3.14.17.0-r1 (27 Feb 2013)
+
+  27 Feb 2013; Christoph Junghans <ottxor@g.o>
+  +google-talkplugin-3.14.17.0-r1.ebuild, -google-talkplugin-3.14.17.0.ebuild,
+  google-talkplugin-9999.ebuild:
+  install additional datafiles to make plugins work (bug #438198)
 
 *google-talkplugin-3.14.17.0 (26 Feb 2013)
 



1.1                  www-plugins/google-talkplugin/google-talkplugin-3.14.17.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-3.14.17.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-3.14.17.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: google-talkplugin-3.14.17.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/google-talkplugin/google-talkplugin-3.14.17.0-r1.ebuild,v 1.1 2013/02/27 23:38:26 ottxor Exp $

EAPI=4

inherit eutils nsplugins unpacker

if [ "${PV}" != "9999" ]; then
	DEB_PATCH="1"
	#http://dl.google.com/linux/talkplugin/deb/dists/stable/main/binary-i386/Packages
	MY_URL="http://dl.google.com/linux/talkplugin/deb/pool/main/${P:0:1}/${PN}"
	MY_PKG="${PN}_${PV}-${DEB_PATCH}_i386.deb"
	SRC_URI="x86? ( ${MY_URL}/${MY_PKG} )
		amd64? ( ${MY_URL}/${MY_PKG/i386/amd64} )"
else
	MY_URL="http://dl.google.com/linux/direct"
	MY_PKG="${PN}_current_i386.deb"
	SRC_URI=""
fi

DESCRIPTION="Video chat browser plug-in for Google Talk"

HOMEPAGE="http://www.google.com/chat/video"
IUSE="libnotify +system-libCg video_cards_fglrx video_cards_radeon"
SLOT="0"

KEYWORDS="-* ~amd64 ~x86"
#GoogleTalkPlugin binary contains openssl and celt
LICENSE="Google-TOS openssl BSD"
RESTRICT="strip mirror"

RDEPEND="|| ( media-sound/pulseaudio media-libs/alsa-lib )
	dev-libs/glib:2
	system-libCg? ( media-gfx/nvidia-cg-toolkit )
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/libpng:1.2
	sys-libs/glibc
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXt
	x11-libs/pango
	sys-apps/lsb-release
	virtual/opengl
	libnotify? ( x11-libs/libnotify )"

DEPEND=""

INSTALL_BASE="opt/google/talkplugin"

QA_PREBUILT="${INSTALL_BASE}/*"

S="${WORKDIR}"

LANGS="ar cs en et fr hu lt ms pl ru sv tl vi bg da fa gu id ja lv nl
sk ta tr bn de es fi hi is kn ml no sl te uk ca el fil hr it ko mr or
ro sr th ur"

for X in ${LANGS} ; do
	IUSE="${IUSE} linguas_${X}"
done

# nofetch means upstream bumped and thus needs version bump
pkg_nofetch() {
	einfo "This version is no longer available from Google."
	einfo "Note that Gentoo cannot mirror the distfiles due to license reasons, so we have to follow the bump."
	einfo "Please file a version bump bug on http://bugs.gentoo.org (search	existing bugs for ${PN} first!)."
}

src_unpack() {
	local pkg="${A:=${MY_PKG}}"
	if [ "${PV}" = "9999" ]; then
		use amd64 && pkg="${pkg/i386/amd64}"
		einfo "Fetching ${pkg}"
		wget "${MY_URL}/${pkg}" || die
	fi
	unpacker ${pkg}
}

src_install() {
	unpacker usr/share/doc/google-talkplugin/changelog.Debian.gz
	dodoc changelog.Debian

	exeinto "/${INSTALL_BASE}"
	doexe "${INSTALL_BASE}"/GoogleTalkPlugin
	for i in "${INSTALL_BASE}"/lib*.so; do
		doexe "${i}"
		[[ ${i##*/} = libnp* ]] && inst_plugin "/${i}"
	done

	#install screen-sharing stuff - bug #397463
	insinto "/${INSTALL_BASE}"
	doins "${INSTALL_BASE}"/windowpicker.glade
	doins "${INSTALL_BASE}"/remoting24x24.png
	doins -r "${INSTALL_BASE}"/data

	strip-linguas ${LANGS}
	for l in ${LINGUAS}; do
		insinto "/${INSTALL_BASE}"/locale/$l/LC_MESSAGES/
		doins "${INSTALL_BASE}"/locale/$l/LC_MESSAGES/windowpicker.mo
	done

	#install bundled libCg
	if use video_cards_radeon || use video_cards_fglrx; then
		#hack from #402401
		exeinto "/${INSTALL_BASE}"/lib
		doexe "${INSTALL_BASE}"/lib/libCg*.so
		if use system-libCg; then
			ewarn "There seems to be a problem with ati cards and USE='-system-libCG,"
			ewarn "so we install the bundled version of libCG anyway. (bug #402401)"
		fi
		echo "O3D_OVERRIDE_RENDER_MODE=2D" > "${ED}/opt/google/talkplugin/envvars"
		ewarn "We have set O3D_OVERRIDE_RENDER_MODE=2D in ${EROOT}opt/google/talkplugin/envvars"
		ewarn "please report your experience, good or bad, with this workaround on bug #402401"
	elif ! use system-libCg; then
		exeinto "/${INSTALL_BASE}"/lib
		doexe "${INSTALL_BASE}"/lib/libCg*.so
	fi
}