[gentoo-commits] gentoo-x86 commit in dev-lang/tk: ChangeLog tk-8.4.19.ebuild tk-8.4.18-r1.ebuild

[Federico Ferri (mescalinum)]

mescalinum    08/10/27 20:27:07

  Modified:             ChangeLog tk-8.4.19.ebuild
  Added:                tk-8.4.18-r1.ebuild
  Log:
  adding patch 8.4-lastevent, fixes bug #225999
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.112                dev-lang/tk/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	26 Oct 2008 11:21:33 -0000	1.111
+++ ChangeLog	27 Oct 2008 20:27:07 -0000	1.112
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/tk
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.111 2008/10/26 11:21:33 mescalinum Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.112 2008/10/27 20:27:07 mescalinum Exp $
+
+*tk-8.4.18-r1 (27 Oct 2008)
+
+  27 Oct 2008; Federico Ferri <mescalinum@g.o>
+  +files/tk-8.4-lastevent.patch, +tk-8.4.18-r1.ebuild, tk-8.4.19.ebuild:
+  adding patch 8.4-lastevent, fixes bug #225999
 
 *tk-8.4.19 (26 Oct 2008)
 



1.2                  dev-lang/tk/tk-8.4.19.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/tk-8.4.19.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/tk-8.4.19.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/tk-8.4.19.ebuild?r1=1.1&r2=1.2

Index: tk-8.4.19.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.19.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- tk-8.4.19.ebuild	26 Oct 2008 11:21:33 -0000	1.1
+++ tk-8.4.19.ebuild	27 Oct 2008 20:27:07 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.19.ebuild,v 1.1 2008/10/26 11:21:33 mescalinum Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.19.ebuild,v 1.2 2008/10/27 20:27:07 mescalinum Exp $
 
 WANT_AUTOCONF=latest
 WANT_AUTOMAKE=latest
@@ -20,7 +20,7 @@
 	~dev-lang/tcl-${PV}"
 DEPEND="${RDEPEND}
 	x11-libs/libXt
-	x11-proto/xproto"
+	>=x11-proto/xproto-7.0.3"
 
 S=${WORKDIR}/${PN}${PV}
 
@@ -47,6 +47,9 @@
 	# Bug 125971
 	epatch "${FILESDIR}"/${PN}-8.4.15-tclm4-soname.patch
 
+	# Bug 225999
+	epatch "${FILESDIR}"/${PN}-8.4-lastevent.patch
+
 	local d
 	for d in */configure ; do
 		cd "${S}"/${d%%/*}



1.1                  dev-lang/tk/tk-8.4.18-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/tk-8.4.18-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/tk/tk-8.4.18-r1.ebuild?rev=1.1&content-type=text/plain

Index: tk-8.4.18-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.4.18-r1.ebuild,v 1.1 2008/10/27 20:27:07 mescalinum Exp $

WANT_AUTOCONF=latest
WANT_AUTOMAKE=latest

inherit autotools eutils multilib toolchain-funcs

DESCRIPTION="Tk Widget Set"
HOMEPAGE="http://dev.scriptics.com/software/tcltk/"
SRC_URI="mirror://sourceforge/tcl/${PN}${PV}-src.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug threads"

RDEPEND="x11-libs/libX11
	~dev-lang/tcl-${PV}"
DEPEND="${RDEPEND}
	x11-libs/libXt
	>=x11-proto/xproto-7.0.13"

S=${WORKDIR}/${PN}${PV}

pkg_setup() {
	if use threads ; then
		ewarn ""
		ewarn "PLEASE NOTE: You are compiling ${P} with"
		ewarn "threading enabled."
		ewarn "Threading is not supported by all applications"
		ewarn "that compile against tcl. You use threading at"
		ewarn "your own discretion."
		ewarn ""
		epause 5
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/remove-control-v-8.4.9.diff
	epatch "${FILESDIR}"/${PN}-8.4.9-man.patch
	epatch "${FILESDIR}"/${PN}-8.4.11-multilib.patch

	# Bug 125971
	epatch "${FILESDIR}"/${PN}-8.4.15-tclm4-soname.patch

	# Bug 225999
	epatch "${FILESDIR}"/${PN}-8.4-lastevent.patch

	local d
	for d in */configure ; do
		cd "${S}"/${d%%/*}
		EPATCH_SINGLE_MSG="Patching nls cruft in ${d}" \
		epatch "${FILESDIR}"/tk-configure-LANG.patch
	done

	cd "${S}"/unix
	eautoreconf
}

src_compile() {
	tc-export CC
	cd "${S}"/unix

	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}

	econf \
		--with-tcl=/usr/${mylibdir} \
		$(use_enable threads) \
		$(use_enable debug symbols) || die

	emake || die
}

src_install() {
	#short version number
	local v1
	v1=${PV%.*}

	cd "${S}"/unix
	make DESTDIR="${D}" install || die

	# fix the tkConfig.sh to eliminate refs to the build directory
	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
	sed -i \
		-e "s,^\(TK_BUILD_LIB_SPEC='-L\)${S}/unix,\1/usr/${mylibdir}," \
		-e "s,^\(TK_SRC_DIR='\)${S}',\1/usr/${mylibdir}/tk${v1}/include'," \
		-e "s,^\(TK_BUILD_STUB_LIB_SPEC='-L\)${S}/unix,\1/usr/${mylibdir}," \
		-e "s,^\(TK_BUILD_STUB_LIB_PATH='\)${S}/unix,\1/usr/${mylibdir}," \
		-e "s,^\(TK_CC_SEARCH_FLAGS='.*\)',\1:/usr/${mylibdir}'," \
		-e "s,^\(TK_LD_SEARCH_FLAGS='.*\)',\1:/usr/${mylibdir}'," \
		"${D}"/usr/${mylibdir}/tkConfig.sh || die

	# install private headers
	insinto /usr/${mylibdir}/tk${v1}/include/unix
	doins "${S}"/unix/*.h || die
	insinto /usr/${mylibdir}/tk${v1}/include/generic
	doins "${S}"/generic/*.h || die
	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tk.h
	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tkDecls.h
	rm -f "${D}"/usr/${mylibdir}/tk${v1}/include/generic/tkPlatDecls.h

	# install symlink for libraries
	#dosym libtk${v1}.a /usr/${mylibdir}/libtk.a
	if use debug ; then
		dosym libtk${v1}g.so /usr/${mylibdir}/libtk${v1}.so
		dosym libtkstub${v1}g.a /usr/${mylibdir}/libtkstub${v1}.a
		dosym ../tk${v1}g/pkgIndex.tcl /usr/${mylibdir}/tk${v1}/pkgIndex.tcl
	fi
	dosym libtk${v1}.so /usr/${mylibdir}/libtk.so
	dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a

	dosym wish${v1} /usr/bin/wish

	cd "${S}"
	dodoc ChangeLog README changes license.terms
}