[gentoo-commits] repo/gentoo:master commit in: games-action/minetest/

[Aaron Swenson]

commit:     9a14533e0a70318885b30dd89e877af4b87a3335
Author:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 12 17:23:57 2017 +0000
Commit:     Aaron Swenson <titanofold <AT> gentoo <DOT> org>
CommitDate: Sun Nov 12 17:26:28 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a14533e

games-action/minetest: Add PgSQL dependency

Add USE flag to control dependency on PostgreSQL.

Bug: https://bugs.gentoo.org/637134

Package-Manager: Portage-2.3.8, Repoman-2.3.3

 games-action/minetest/metadata.xml              |   1 +
 games-action/minetest/minetest-0.4.16-r1.ebuild | 134 ++++++++++++++++++++++++
 2 files changed, 135 insertions(+)

diff --git a/games-action/minetest/metadata.xml b/games-action/minetest/metadata.xml
index 4eeaf53fc44..8f6cd18b445 100644
--- a/games-action/minetest/metadata.xml
+++ b/games-action/minetest/metadata.xml
@@ -36,6 +36,7 @@
 			Use <pkg>dev-lang/luajit</pkg>
 			instead of <pkg>dev-lang/lua</pkg>
 		</flag>
+		<flag name="postgres">Optionally use PostgreSQL as map backend</flag>
 		<flag name="redis">Enable redis backend via
 			<pkg>dev-libs/hiredis</pkg>
 		</flag>

diff --git a/games-action/minetest/minetest-0.4.16-r1.ebuild b/games-action/minetest/minetest-0.4.16-r1.ebuild
new file mode 100644
index 00000000000..9e0ab06fdaa
--- /dev/null
+++ b/games-action/minetest/minetest-0.4.16-r1.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils gnome2-utils user vcs-snapshot
+
+DESCRIPTION="An InfiniMiner/Minecraft inspired game"
+HOMEPAGE="http://minetest.net/"
+SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+curl dedicated doc +leveldb luajit ncurses nls postgres redis +server +sound spatial +truetype"
+
+RDEPEND="dev-db/sqlite:3
+	sys-libs/zlib
+	curl? ( net-misc/curl )
+	!dedicated? (
+		app-arch/bzip2
+		>=dev-games/irrlicht-1.8-r2
+		dev-libs/gmp:0=
+		media-libs/libpng:0=
+		virtual/jpeg:0
+		virtual/opengl
+		x11-libs/libX11
+		x11-libs/libXxf86vm
+		sound? (
+			media-libs/libogg:=
+			media-libs/libvorbis:=
+			media-libs/openal:=
+		)
+		truetype? ( media-libs/freetype:2 )
+	)
+	leveldb? ( dev-libs/leveldb )
+	luajit? ( dev-lang/luajit:2 )
+	ncurses? ( sys-libs/ncurses:0= )
+	nls? ( virtual/libintl )
+	postgres? ( >=dev-db/postgresql-9.5:= )
+	redis? ( dev-libs/hiredis )
+	spatial? ( sci-libs/libspatialindex )"
+DEPEND="${RDEPEND}
+	>=dev-games/irrlicht-1.8-r2
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	if use server || use dedicated ; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# set paths
+	sed \
+		-e "s#@BINDIR@#${EPREFIX}/usr/bin#g" \
+		-e "s#@GROUP@#${PN}#g" \
+		"${FILESDIR}"/minetestserver.confd > "${T}"/minetestserver.confd || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex !dedicated)
+		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
+		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
+		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
+		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_FREETYPE=$(usex truetype)
+		-DENABLE_GETTEXT=$(usex nls)
+		-DENABLE_GLES=0
+		-DENABLE_LEVELDB=$(usex leveldb)
+		-DENABLE_POSTGRESQL=$(usex postgres)
+		-DENABLE_REDIS=$(usex redis)
+		-DENABLE_SPATIAL=$(usex spatial)
+		-DENABLE_SOUND=$(usex sound)
+		-DENABLE_LUAJIT=$(usex luajit)
+		-DENABLE_CURSES=$(usex ncurses)
+		-DRUN_IN_PLACE=0
+	)
+
+	use dedicated && mycmakeargs+=(
+		-DIRRLICHT_INCLUDE_DIR="${EPREFIX}/usr/include/irrlicht"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc ; then
+		cmake-utils_src_compile doc
+		HTML_DOCS=( "${CMAKE_BUILD_DIR}"/doc/html/. )
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use server || use dedicated ; then
+		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
+		newconfd "${T}"/minetestserver.confd minetest-server
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+
+	if ! use dedicated ; then
+		elog
+		elog "optional dependencies:"
+		elog "	games-action/minetest_game (official mod)"
+		elog
+	fi
+
+	if use server || use dedicated ; then
+		elog
+		elog "Configure your server via /etc/conf.d/minetest-server"
+		elog "The user \"minetest\" is created with /var/lib/${PN} homedir."
+		elog "Default logfile is ~/minetest-server.log"
+		elog
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}