[gentoo-commits] repo/gentoo:master commit in: dev-util/intel-graphics-system-controller/

[Conrad Kostecki]

commit:     d5594f1d2eee3c037a60097ac7703095b288a824
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 31 03:30:39 2023 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Tue Jan 31 15:15:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d5594f1d

dev-util/intel-graphics-system-controller: add 0.8.7

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-util/intel-graphics-system-controller/Manifest |  1 +
 .../intel-graphics-system-controller-0.8.7.ebuild  | 50 ++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/dev-util/intel-graphics-system-controller/Manifest b/dev-util/intel-graphics-system-controller/Manifest
index c0e95de0a64e..82a293bada7b 100644
--- a/dev-util/intel-graphics-system-controller/Manifest
+++ b/dev-util/intel-graphics-system-controller/Manifest
@@ -1 +1,2 @@
 DIST intel-graphics-system-controller-0.8.6.tar.gz 179906 BLAKE2B cadbcb559418f5e6164002cdff1dea2b8a0cec946fd0128c4f374f9b58d5086e9aba3cc97a05641be0255d848e8acf3429df16ca7d70debfff3a282445a7ca3f SHA512 40b89f54754fba3a5cf43c4cc822ec5ea0506cd854b0a85bb29e03370cbb25638ab67b8a568fe6f4d7dd2e41e7f302c550e6d4955b6e6fbf4df0d512a3afe64b
+DIST intel-graphics-system-controller-0.8.7.tar.gz 181536 BLAKE2B 663ec335acdf96edd0c084d2c703687925233caa602e30ac1b189342d1e2a2d370975933fc34171703d3161b4c0f1637bb735fdc89bcd7ed6e5a41b49f946271 SHA512 cc0eabb67fed0c40ab1b0f9501bba87b56c1e97e66242df360036256a18d26912525e78e339c6d09c8d9cf557d00aac60cfb354961304ca41e746f4964705900

diff --git a/dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.8.7.ebuild b/dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.8.7.ebuild
new file mode 100644
index 000000000000..49ca2234ca1b
--- /dev/null
+++ b/dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.8.7.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="igsc"
+MY_P="${MY_PN}-${PV}"
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="Intel graphics system controller firmware update library"
+HOMEPAGE="https://github.com/intel/igsc"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/V${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="+cli doc"
+
+RDEPEND="dev-libs/metee:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		app-doc/doxygen
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CLI="$(usex cli)"
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_PERF="OFF"
+		-DENABLE_WERROR="OFF"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DENABLE_TESTS="OFF"
+	)
+
+	cmake_src_configure
+}