[gentoo-commits] gentoo-x86 commit in dev-vcs/gitolite-gentoo: gitolite-gentoo-1.5.6.ebuild ChangeLog metadata.xml

[Christian Ruppert (idl0r)]

idl0r       10/11/02 21:08:07

  Added:                gitolite-gentoo-1.5.6.ebuild ChangeLog metadata.xml
  Log:
  Initial import of dev-vcs/gitolite-gentoo-1.5.6.
  
  (Portage version: 2.2.0_alpha3/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.6.ebuild?rev=1.1&content-type=text/plain

Index: gitolite-gentoo-1.5.6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.6.ebuild,v 1.1 2010/11/02 21:08:07 idl0r Exp $

EAPI=3

inherit eutils perl-module

DESCRIPTION="Highly flexible server for git directory version tracker"
HOMEPAGE="http://github.com/sitaramc/gitolite"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="contrib vim-syntax"

DEPEND="dev-lang/perl
	>=dev-vcs/git-1.6.2"
RDEPEND="${DEPEND}
	!dev-vcs/gitolite
	vim-syntax? ( app-vim/gitolite-syntax )"

pkg_setup() {
	enewgroup git
	enewuser git -1 /bin/bash /var/lib/gitolite git
}

src_prepare() {
	epatch "${FILESDIR}/gitolite-require.patch"

	rm -rf Makefile doc/COPYING contrib/{autotoc,gitweb,vim}

	echo "${PF}" > conf/VERSION
}

src_install() {
	dodir /usr/share/gitolite/{conf,hooks} /usr/bin || die

	./src/gl-system-install "${D}"/usr/bin \
		"${D}"/usr/share/gitolite/conf "${D}"/usr/share/gitolite/hooks || die
	dosed "s:${D}::g" usr/bin/gl-setup \
		usr/share/gitolite/conf/example.gitolite.rc || die

	rm "${D}/usr/bin/gitolite.pm"
	insinto "${VENDOR_LIB}"
	doins src/gitolite.pm || die

	dodoc README.mkd doc/*

	if use contrib; then
		insinto /usr/share/doc/${PF}
		doins -r contrib/ || die
	fi

	keepdir /var/lib/gitolite
	fowners git:git /var/lib/gitolite
	fperms 750 /var/lib/gitolite
}



1.1                  dev-vcs/gitolite-gentoo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-vcs/gitolite-gentoo
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog,v 1.1 2010/11/02 21:08:07 idl0r Exp $

*gitolite-gentoo-1.5.6 (02 Nov 2010)

  02 Nov 2010; Christian Ruppert <idl0r@g.o>
  +gitolite-gentoo-1.5.6.ebuild, +files/gitolite-require.patch, +metadata.xml:
  Initial import of dev-vcs/gitolite-gentoo-1.5.6.




1.1                  dev-vcs/gitolite-gentoo/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>idl0r@g.o</email>
		<name>Christian Ruppert</name>
	</maintainer>
	<use>
		<flag name="contrib">Install user-contributed files</flag>
	</use>
</pkgmetadata>